8086系列（10）：冒泡排序

题目

从键盘上输入任意个数字，存放在数组BUFFER中，编制程序使该数组中的数按照从小到大排序，最终输出结果。

思路

采用冒泡排序，从第一个数开始对相邻的两个数进行比较，如次序对，则不需要任何操作；如果次序不对，则交换两个数的位置。N个数第一轮需要比较(N-1)次，第二轮需要比较(N-2)次，比较(N-1)+（N-2) + … + 1 就可以完成冒泡排序。
程序结构分为三个部分，输入部分、排序部分和输出部分，输入部分将十进制数不加转换地存入内存中，输出只需要将内存中的数以16进制数输出即可，这里并不需要判断A-F，因为输入时不会出现A-F的情况。

代码

datasg segment
    BUFFER dw 20 dup(?)
    num dw ?
    flag dw ?
datasg ends
;----------------
codesg segment
    assume cs:codesg,ds:datasg,es:datasg
main proc far
start:
    push ds
    sub ax,ax
    push ax
    mov ax,datasg
    mov ds,ax
    mov es,ax
;--------------------
;AX 用于DOS调用
;BX 用于记录存了多少个数（每个数2字节16位）
;CX 存放SHL、SHR的移动次数（超过1要放在CL里）
;DX 用于存放得到每个数之前的临时值
;-------写入过程-----------
    mov bx,offset BUFFER
    mov dx,0
    mov ax,0

next:
    ;输入下一个数字
    mov ah,01
    int 21h
    ;对输入的数进行判定，判断是否为空格或者回车
    cmp al,0Dh   ;如果是回车，则输入结束，输入最后一个字符时一定要加上回车
    jz sortstart   ;结束跳到排序部分
    cmp al,' '    ;如果是空格
    jz NNUM       ;如果是空格，则当前输入结束
    mov cl,4
    shl dx,cl
    sub al,30H          ;-30H对应得到的数字
    add dl,al           ;加入这次的个位数
    jmp next

NNUM:                 ;将dx存放buffer中
    mov [bx],dx
    add bx,2
    mov dx,0
    jmp next
;--------------------
;AX 存放交换的第一个数字
;BX 没用到，依旧保留原来的数值，即入读数的数量*2
;CX 内、外循环的次数，内循环完了出栈
;DX 没用到
;--------------排序过程------------
sortstart:
    mov ax,bx
    shr ax,1  ;bx/2,得到数字个数
    mov num,ax
    mov cx,ax ;外层循环
    dec cx    ;N个数，外层循环需i = （N-1）次，内层循环需要 j = i 次
;外层循环
FORI:
    push cx    ;保存外层循环次数
    mov si,0    ;内层循环时取数组内容的指针
;内层循环
FORJ:
    mov ax,[si]  
    cmp ax,[si+2]   ;a[j]与a[j+1]比较
    jbe NextNum     ;a[j]<=a[j+1]时，跳到下一步不交换
    xchg ax,[si+2]  ;交换
    mov [si],ax
NextNum:
    add si,2         ;下一个数
    loop FORJ        ;内层循环 cx--直到为0
    pop cx
    loop FORI        ;外层循环

;--------------显示部分------------
;AX中断调用
;BX输出bx的值
;CX:存放数字的个数，用于外层循环
;DX用于输出
;----------------------------------
    mov cx,num
    lea di,BUFFER
output:
    push cx           ;将cx压入堆栈，用于外层循环
    mov bx,[di]       ;将bx的值输出
    mov ch,4          ;ch用于计数内层循环
    mov flag,0
rotate:
    mov cl,4          ;cl用于每次移4位,rol的操作数不能是立即数
    rol bx,cl         ;循环左移四位，取最高位
    mov ax,bx
    and al,0fh        ;取低四位
    jnz printf    ;不为0肯定输出
    mov dx,flag
    cmp dx,1           ;查看flag是否为1
    jnz nextrotate     ;不是为1，则不输出继续执行下一句
    
printf:
    mov flag,1
    add al,30H   ;一定是数字，故不用判断
    mov dl,al
    mov ah,2     ;调用2号中断输出字符串
    int 21h
nextrotate:
    dec ch       ;ch-1
    jnz rotate   ;如果ch不等于0，继续循环
    mov dl,' '   ;输出空格
    mov ah,2
    int 21h 
    add di,2     ;外层循环
    pop cx
    loop output

;--------------------
exit:
    ret
main endp
codesg ends
end start

调试