MetaClass 深入研究-5

在对MetaClass有所了解之后，本篇重点看看ExpandoMetaClass 的灵活性。

ExpandoMetaClass是一种MetaClass的实现，缺省情况下，一个自定义的类的MetaClass实现是MetaClassImpl，不过这个实现类并不稳定，见下面的示例。
class A{
  String text
}
def a1= new A(text: 'aBCdefG')
assert a1.metaClass.class == MetaClassImpl //usual MetaClass type

A.metaClass.inSameCase= {-> text.toUpperCase()}
    //A.metaClass自动从MetaClassImpl变成了ExpandoMetaClass
    //并且为类增加了一个 'inUpperCase' 方法

def a2= new A(text: 'hiJKLmnOp')
assert a2.metaClass.getClass() == ExpandoMetaClass
  //MetaClass of A changed for instances created after conversion trigger only

上面这个变化也真是太“随便”了点儿，如果不深入了解，真要被弄迷糊了。

 

assert a2.inSameCase() == 'HIJKLMNOP'

assert a1.metaClass.class == MetaClassImpl //still usual MetaClass type , a1实例没有发生变化
try{ println a1.inSameCase(); assert false }
catch(e){ assert e in MissingMethodException } //new method not available , a1并没有增加方法

A.metaClass.inLowerCase= {-> text.toLowerCase()}
assert a2.inLowerCase() == 'hijklmnop'         //a2的MetaClass由于是ExpandoMetaClass，所以自动支持了相关的方法

//we can replace the method definition with another
A.metaClass.inSameCase= {-> text.toLowerCase()}
assert a2.inSameCase() == 'hijklmnop'   //a2的方法定义，随时都可以被改变

//A.metaClass.inSameCase= null //remove method，这句好像影响不到a2
try{ println a1.inSameCase(); assert false }
catch(e){ assert e in MissingMethodException } //method no longer available ， a1 还是不受影响

//we can add static methods...
A.metaClass.'static'.inSameCase= { it.toLowerCase()}
assert A.inSameCase('qRStuVwXyz') == 'qrstuvwxyz'

 

本文内容理解起来虽然有点儿复杂，不过总结一下，就是ExpandoMetaClass提供了一种非常方便的扩展类的能力的方法。

不用象之前的文章中所描述的那么麻烦，直接通过一个Class的MetaClass来扩展就好了。