MYSQl 5.7相关配置

一、安装配置：

1.下载地址：mysql-5.7.25-winx64.zip
https://dev.mysql.com/downloads/mysql/5.7.html

2.解压:

在mysql-5.7.25-winx64目录下：

1)新建my-default.ini：

[mysql]
default-character-set=utf8 

[mysqld]
port = 3306
# 最大连接数
max_connections=200
# 编码方式
character-set-server=utf8
# 数据库默认使用引擎
default-storage-engine=INNODB

# 数据缓冲区buffer pool大小，建议使用物理内存的50%-70%
innodb_buffer_pool_size = 1G

# 指定在一个日志组中，每个log的大小
innodb_log_file_size=256M

# 1(默认值),0或者2 (性能更好，但稳定性更差)
innodb_flush_log_at_trx_commit = 1

 

2）新建config.sql：

use mysql
update user set host='%',authentication_string=password('root') where user='root'; 
quit

 

3）新建install.bat：

@echo off

rem 停止mysql57服务（如果存在）
net stop mysql57 >nul

rem 切换到当前盘符
%~d0

rem 进入当前路径
cd %~dp0

rem 设置变量延迟,使用变量延迟后，相关变量用！！包围，这样程序才能正确识别
setlocal enabledelayedexpansion

rem 复制 my-default.ini文件
copy my-default.ini my.ini

rem 设置添加到my.ini文件中的数据库路径和数据路径
set mypath=%~dp0
set datadir=datadir = %mypath%data 
set basedir=basedir = %mypath:~0,-1%  

rem 设置my.ini的标记位
set tag=[mysqld]

echo # SET basedir>>my.ini
echo !basedir!>>my.ini
echo # SET datadir>>my.ini
echo !datadir!>>my.ini 

rem 删除mysql服务
.\bin\mysqld.exe remove mysql57

rem 删除数据文件 （如果存在）
rd data /s/q >nul

rem 安装mysql服务
.\bin\mysqld.exe -install mysql57
 

rem 进行MySQL的初始化
.\bin\mysqld.exe --initialize-insecure --user=mysql

rem 更改用户root登录密码为root密码
net start mysql57   
.\bin\mysql -u root <.\config.sql
 
 
rem 启动mysql服务
net stop mysql57 >nul 
net start mysql57
pause  

以上操作完成后，以管理员身份运行 install.bat，处理完成。

二、删除配置  uninstall.bat

@echo off
rem 停止mysql服务
net stop mysql57

rem 切换到当前盘符
%~d0

rem 进入当前路径
cd %~dp0

rem 删除mysql服务
.\bin\mysqld.exe remove mysql57
 
 
rem 清理注册表mysql57
rem 清理注册表 若存在[-HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\EventLog\Application\mysql57]
REG DELETE  HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\EventLog\Application\mysql57 /f

rem 清理注册表 若存在 [-HKEY_LOCAL_MACHINE\SYSTEM\ControlSet002\Services\EventLog\Application\mysql57]
REG DELETE  HKEY_LOCAL_MACHINE\SYSTEM\ControlSet002\Services\EventLog\Application\mysql57 /f

rem 清理注册表 若存在 [-HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\EventLog\Application\mysql57]
REG DELETE  HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\EventLog\Application\mysql57 /f

pause

以上操作完成后，以管理员身份运行 uninstall.bat，处理完成。

三、数据文件更改路径

1.停止服务：net stop mysql57

2.更改 my.ini ：

datadir = 更改后文件路径

注意 ：保存 my.ini  以utf-8无bom格式编码 

3.启动服务：net start mysql57