PCI网卡上扩展ROM编程 8.附件

最新推荐文章于 2020-09-15 16:27:23 发布
最新推荐文章于 2020-09-15 16:27:23 发布
阅读量3.1k 收藏 3
点赞数
文章标签： 编程 扩展 command class structure header
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/misterliwei/article/details/1777440
版权

附件1.PCI.ASM

.386
DATA SEGMENT USE16
     BUS       DB  0
     DEVICENO  DB  0
     FUNC      DB  0
     VENDOR    DW  0
     DEVICE    DW  0
     CLASS     DD  0
     IRQ       DB  0
     DEVICETYPE DB  0
     ROMBASE   DD  0
     BASE0     DD  0
     COMMAND   DW  0
     MSG DB 'BUS# DEVICE# FUNC#  VENDOR  DEVICE CLASS BASE0     IRQ   ROM COMMAND', 0
DATA ENDS

STACK SEGMENT USE16
      DB  256 DUP (0)
      STACKLEN = $
STACK ENDS

CODE SEGMENT USE16
     ASSUME DS:DATA, CS:CODE, SS:STACK

START:
     MOV AX, DATA
     MOV DS, AX

     CLI
     MOV AX, STACK
     MOV SS, AX
     MOV SP, STACKLEN
     STI

;显存地址
     MOV AX, 0B800H
     MOV ES, AX

     MOV SI, OFFSET MSG
     MOV DI, 80 * 8
     CLD
NEXTCHAR:
     LODSB
     OR AL, AL
     JZ OVERCHAR
     MOV AH, 7
     STOSW
     JMP NEXTCHAR

OVERCHAR:
     MOV SI, 80 * 10

     MOV BUS, 0
     MOV DEVICENO,0
     MOV FUNC, 0

PCI0:
    MOV ROMBASE, 0
     XOR EAX, EAX

     MOV AL, BUS
     MOV CL, 5
     SHL EAX, CL
     OR  AL, DEVICENO
     MOV CL, 3
     SHL EAX, CL
     OR  AL, FUNC
     MOV CL, 8
     SHL EAX, CL
     OR  EAX, 80000000H

     MOV DX, 0CF8H
     OUT DX, EAX
     MOV DX, 0CFCH
     IN  EAX, DX
     CMP AX, 0FFFFH
     JZ  NEXTPCI

;GET CONFIG SPACE
     MOV VENDOR, AX
     MOV CL, 16
     SHR EAX, CL
     MOV DEVICE, AX

     XOR EAX, EAX
     MOV AL, BUS
     MOV CL, 5
     SHL EAX, CL
     OR  AL, DEVICENO
     MOV CL, 3
     SHL EAX, CL
     OR  AL, FUNC
     MOV CL, 8
     SHL EAX, CL
     OR  EAX, 80000008H

     MOV DX, 0CF8H
     OUT DX, EAX
     MOV DX, 0CFCH
     IN  EAX, DX
     MOV CLASS, EAX

     XOR EAX, EAX
     MOV AL, BUS
     MOV CL, 5
     SHL EAX, CL
     OR  AL, DEVICENO
     MOV CL, 3
     SHL EAX, CL
     OR  AL, FUNC
     MOV CL, 8
     SHL EAX, CL
     OR  EAX, 8000003CH

     MOV DX, 0CF8H
     OUT DX, EAX
     MOV DX, 0CFCH
     IN  EAX, DX
     MOV IRQ, AL

     XOR EAX, EAX
     MOV AL, BUS
     MOV CL, 5
     SHL EAX, CL
     OR  AL, DEVICENO
     MOV CL, 3
     SHL EAX, CL
     OR  AL, FUNC
     MOV CL, 8
     SHL EAX, CL
     OR  EAX, 80000004H

     MOV DX, 0CF8H
     OUT DX, EAX
     MOV DX, 0CFCH
     IN  EAX, DX
     MOV COMMAND, AX

     XOR EAX, EAX
     MOV AL, BUS
     MOV CL, 5
     SHL EAX, CL
     OR  AL, DEVICENO
     MOV CL, 3
     SHL EAX, CL
     OR  AL, FUNC
     MOV CL, 8
     SHL EAX, CL
     OR  EAX, 8000000CH

     MOV DX, 0CF8H
     OUT DX, EAX
     MOV DX, 0CFCH
     IN  EAX, DX
     MOV CL, 16
     SHR EAX, CL
     MOV DEVICETYPE, AL

     XOR EAX, EAX
     MOV AL, BUS
     MOV CL, 5
     SHL EAX, CL
     OR  AL, DEVICENO
     MOV CL, 3
     SHL EAX, CL
     OR  AL, FUNC
     MOV CL, 8
     SHL EAX, CL
     OR  EAX, 80000030H

     MOV DX, 0CF8H
     OUT DX, EAX
     MOV EBX, EAX
     MOV DX, 0CFCH
     MOV EAX, 0FFFFFFFEH
     OUT DX, EAX

     MOV EAX, EBX
     MOV DX, 0CF8H
     OUT DX, EAX
     MOV DX, 0CFCH
     IN  EAX, DX
     MOV ROMBASE, EAX

     XOR EAX, EAX
     MOV AL, BUS
     MOV CL, 5
     SHL EAX, CL
     OR  AL, DEVICENO
     MOV CL, 3
     SHL EAX, CL
     OR  AL, FUNC
     MOV CL, 8
     SHL EAX, CL
     OR  EAX, 80000010H
     MOV DX, 0CF8H
     OUT DX, EAX
     MOV DX, 0CFCH
     IN  EAX, DX
     MOV BASE0, EAX

     ;SIMPLE  0??????
;     MOV AL, DEVICETYPE
;     AND AL, 07FH
;     CMP AL, 0
;     JNZ NEXTPCI

     ;DISPLAY SOMTHING.........
     MOV DI, SI

     ;SHOW BUS#....
     MOV AL, BUS
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 10

     ;SHOW DEVICE#....
     MOV AL, DEVICENO
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 16

     ;SHOW FUNC#....
     MOV AL, FUNC
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 14

     ;SHOW VENDOR ....
     MOV AX, VENDOR
     MOV CL, 8
     ROL AX, CL
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4
     ROL AX, CL
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 12

     ;SHOW DEVICE ....
     MOV AX, DEVICE
     MOV CL, 8
     ROL AX, CL
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4
     ROL AX, CL
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 10

     ;SHOW CLASS.....
     MOV EAX, CLASS
     MOV CL, 8
     ROL EAX, CL
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4
     ROL EAX, CL
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4
     ROL EAX, CL
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 8

     ;SHOW BASE0........
     MOV EAX, BASE0
     MOV CL, 8
     ROL EAX, CL
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4
     ROL EAX, CL
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4
     ROL EAX, CL
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4
     ROL EAX, CL
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 10

     ;SHOW  IRQ....
     MOV AL, IRQ
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI,8

     ;SHOW ROMBASE.........
     MOV EAX, ROMBASE
     MOV CL, 8
     ROL EAX, CL
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4
     ROL EAX, CL
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4
     ROL EAX, CL
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4
     ROL EAX, CL
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 12

     ;SHOW DEVICETYPE.........
     MOV AL, DEVICETYPE
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4

     ;SHOW COMAMND.....
     MOV AX, COMMAND
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4
     MOV AL, AH
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 8

     ADD SI, 80 * 2
NEXTPCI:
     CMP FUNC, 7
     JNZ  PCI1
     MOV FUNC, 0

     CMP DEVICENO, 31
     JNZ PCI2
     MOV DEVICENO, 0

     CMP BUS, 255
     JZ  OVER
     INC BUS
     JMP PCI0

PCI1:
     INC FUNC
     JMP PCI0

PCI2:
     INC DEVICENO
     JMP PCI0

     ;;;;
OVER:
     MOV AH, 4CH
     INT 21H

;AL->EDX
TOASCII PROC NEAR
    PUSH AX
    PUSH BX
    PUSH CX

    XOR EDX, EDX
    MOV BL, AL
    AND AL, 0FH
    CMP AL, 9
    JA TO1
    ADD AL, '0'
    JMP TO2
TO1:
    SUB AL, 10
    ADD AL, 'A'
TO2:
    MOV AH, 7
    MOV DX, AX
    MOV CL, 16
    SHL EDX, CL

    MOV CL, 4
    SHR BL, CL
    CMP BL, 9
    JA   TO3
    ADD BL, '0'
    JMP TO4
TO3:
    SUB BL, 10
    ADD BL, 'A'
TO4:
    MOV BH, 7
    MOV DX, BX

    POP CX
    POP BX
    POP AX

    RET
TOASCII ENDP

CODE ENDS
     END START

附件2.R256.ASM

.386
STACK SEGMENT USE16
      DB  256 DUP (0)
      STACKLEN = $
STACK ENDS

CODE SEGMENT USE16
     ASSUME CS:CODE, SS:STACK
START:
     CLI
     MOV AX, STACK
     MOV SS, AX
     MOV SP, STACKLEN
     STI

     MOV AX, 0B800H
     MOV ES, AX
     MOV DI, 80 * 10

     MOV EBX, 00060000H
     MOV CX, 100

NEXTBYTE:
     MOV EAX, EBX
     MOV DX, 0ECD4H
     OUT DX, EAX

     PUSH CX
     MOV CX, 0FFFFH
     LOOP $
     POP CX

     MOV DX, 0ECD7H
     IN AL, DX

     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 8
     INC EBX
    
     LOOP NEXTBYTE


     MOV AH, 4CH
     INT 21H

;AL->EDX
TOASCII PROC NEAR
    PUSH AX
    PUSH BX
    PUSH CX

    XOR EDX, EDX
    MOV BL, AL
    AND AL, 0FH
    CMP AL, 9
    JA TO1
    ADD AL, '0'
    JMP TO2
TO1:
    SUB AL, 10
    ADD AL, 'A'
TO2:
    MOV AH, 7
    MOV DX, AX
    MOV CL, 16
    SHL EDX, CL

    MOV CL, 4
    SHR BL, CL
    CMP BL, 9
    JA   TO3
    ADD BL, '0'
    JMP TO4
TO3:
    SUB BL, 10
    ADD BL, 'A'
TO4:
    MOV BH, 7
    MOV DX, BX

    POP CX
    POP BX
    POP AX

    RET
TOASCII ENDP

CODE ENDS
     END START

附件3.ReadROM.ASM

.386P
DESC STRUC
     LIMIT  DW  0
     BASEL  DW  0
     BASEM  DB  0
     ATTR   DW  0
     BASEH  DB  0
DESC ENDS

GDTR STRUC
     LIMIT  DW   0
     BASE   DD   0
GDTR ENDS

DATA SEGMENT USE16
    GDTNULL  DESC <0, 0, 0, 0, 0>
    GDTNULLSEL = 0

    GDTDATA  DESC <0FFFFH, 0, 0, 92H, 0>
    GDTDATASEL = OFFSET GDTDATA - OFFSET GDTNULL

    GDTCODE DESC <0FFFFH, 0, 0, 98H, 0>
    GDTCODESEL = OFFSET GDTCODE - OFFSET GDTNULL

    GDTSTACK DESC <0FFFFH, 0, 0, 92H, 0>
    GDTSTACKSEL = OFFSET GDTSTACK - OFFSET GDTNULL

    GDTDISP DESC <0FFFFH, 8000H, 0BH, 92H, 0>
    GDTDISPSEL = OFFSET GDTDISP - OFFSET GDTNULL

    GDTREAD  DESC <0FFFFH, 0, 00H, 92H, 0FH>
    GDTREADSEL = OFFSET GDTREAD - OFFSET GDTNULL

    NEWGDTR GDTR <OFFSET NEWGDTR - OFFSET GDTNULL, 0>
DATA ENDS

STACK SEGMENT USE16
      DB  256 DUP (0)
      STACKLEN = $
STACK ENDS

CODE SEGMENT USE16
     ASSUME DS:DATA, CS:CODE, SS:STACK
START:
     MOV AX, DATA
     MOV DS, AX
     CLI
     MOV AX, STACK
     MOV SS, AX
     MOV SP, STACKLEN
     STI

     MOV BH, 1  ;PCI总线号为1
     MOV BL, 7H ;PCI设备号为7
     MOV CH, 0  ;PCI功能号为0

     XOR EAX, EAX
     MOV AL, BH
     MOV CL, 5
     SHL EAX, CL
     OR  AL, BL
     MOV CL, 3
     SHL EAX, CL
     OR  AL, CH
     MOV CL, 8
     SHL EAX, CL
     MOV EBX ,EAX
     OR EAX, 80000030H

     MOV DX, 0CF8H
     OUT DX, EAX

     MOV EAX, 0F000001H   ;设置ROM基地址为0F000000H，并且ROM使能。
;     MOV EAX, 0FFFFFFFFH  ;可以通过向ROM基地址写入0FFFFFFFH来检查ROM大小
     MOV DX, 0CFCH
     OUT DX, EAX

;下面使命令寄存器中的存储器空间控制使能
     MOV EAX, EBX
     OR EAX, 80000004H
     MOV DX, 0CF8H
     OUT DX, EAX

     MOV DX, 0CFCH
     IN EAX, DX

     OR EAX, 2
     MOV ECX, EAX

     MOV EAX, EBX
     OR EAX, 80000004H
     MOV DX, 0CF8H
     OUT DX, EAX

     MOV DX, 0CFCH
     MOV EAX, ECX
     OUT DX, EAX

;为进入安全模式做准备
     MOV AX, DATA
     MOV BX, 10H
     MUL BX
     MOV GDTDATA.BASEL, AX
     MOV GDTDATA.BASEM, DL
     MOV GDTDATA.BASEH, DH
     ADD AX, OFFSET GDTNULL
     ADC DX, 0
     MOV WORD PTR NEWGDTR.BASE, AX
     MOV WORD PTR NEWGDTR.BASE + 2, DX

     MOV AX, STACK
     MOV BX, 10H
     MUL BX
     MOV GDTSTACK.BASEL, AX
     MOV GDTSTACK.BASEM, DL
     MOV GDTSTACK.BASEH, DH

     MOV AX, CODE
     MOV BX, 10H
     MUL BX
     MOV GDTCODE.BASEL, AX
     MOV GDTCODE.BASEM, DL
     MOV GDTCODE.BASEH, DH

     CLI
     LGDT FWORD PTR NEWGDTR

     MOV EAX, CR0
     OR  EAX, 1
     MOV CR0, EAX

     DB 0EAH
     DW OFFSET PROTECT
     DW GDTCODESEL
PROTECT:
     MOV AX, GDTSTACKSEL
     MOV SS, AX
     MOV SP, STACKLEN

     MOV AX, GDTREADSEL
     MOV FS, AX
     MOV AX, GDTDISPSEL
     MOV ES, AX

;下面开始读数据了。
     MOV SI, 0
     MOV CX, 100H
     MOV DI, 80 * 10
R1:
     MOV AX, FS:[SI]
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4
     MOV AL, AH
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 6
     ADD SI, 2
     LOOP R1

     MOV EAX, CR0
     AND EAX, 0FFFFFFFEH
     MOV CR0, EAX

     DB 0EAH
     DW OFFSET REAL
     DW SEG REAL
REAL:
     MOV AX, DATA
     MOV ES, AX
     MOV FS, AX
     MOV AX, STACK
     MOV SS, AX
     MOV SP, STACKLEN
     STI

     MOV AH, 4CH
     INT 21H
;AL->EDX
TOASCII PROC NEAR
    PUSH AX
    PUSH BX
    PUSH CX

    XOR EDX, EDX
    MOV BL, AL
    AND AL, 0FH
    CMP AL, 9
    JA TO1
    ADD AL, '0'
    JMP TO2
TO1:
    SUB AL, 10
    ADD AL, 'A'
TO2:
    MOV AH, 7
    MOV DX, AX
    MOV CL, 16
    SHL EDX, CL

    MOV CL, 4
    SHR BL, CL
    CMP BL, 9
    JA   TO3
    ADD BL, '0'
    JMP TO4
TO3:
    SUB BL, 10
    ADD BL, 'A'
TO4:
    MOV BH, 7
    MOV DX, BX

    POP CX
    POP BX
    POP AX

    RET
TOASCII ENDP

CODE ENDS
     END START

附件4.ROM.ASM

.386P

STACK SEGMENT USE16
      DB 256 DUP (0)
      STACKLEN = $
STACK ENDS

CODE SEGMENT USE16
     ASSUME DS:CODE, SS:STACK, CS:CODE

ROMSTART:
     ;ROM HEADER
     HDR_SIG   DB  55H, 0AAH
     INITSIZE  DB  (ROMEND - ROMSTART) / 512   
     INIT      DB  0E9H
               DW  CODESTART - $ -2
     RESER1    DB  18  DUP (0)
     PPCIDATA  DW  OFFSET PDS_SIG

     ;PCI DATA STRUCTURE
     PDS_SIG   DB  'PCIR'
     VENDORID  DW  10ECH
     DEVICEID  DW  8139H
     RESER2    DW  0
     PDS_LEN   DW  24
     PDS_VER   DB  0
     CLSSCODE  DB  0, 0, 02H
     IMGLEN    DW  (ROMEND - ROMSTART) / 512
     IMGREV    DW  0
     IMGCLASS  DB  0
     INDICATOR DB  80H
     RESER3    DW  0

;PROCEDURE TOASCII
;AL->EDX
TOASCII PROC NEAR
    PUSH AX
    PUSH BX
    PUSH CX

    XOR EDX, EDX
    MOV BL, AL
    AND AL, 0FH
    CMP AL, 9
    JA TO1
    ADD AL, '0'
    JMP TO2
TO1:
    SUB AL, 10
    ADD AL, 'A'
TO2:
    MOV AH, 7
    MOV DX, AX
    MOV CL, 16
    SHL EDX, CL

    MOV CL, 4
    SHR BL, CL
    CMP BL, 9
    JA   TO3
    ADD BL, '0'
    JMP TO4
TO3:
    SUB BL, 10
    ADD BL, 'A'
TO4:
    MOV BH, 7
    MOV DX, BX

    POP CX
    POP BX
    POP AX

    RET
TOASCII ENDP

;NOW CAL CHECKSUM
;PARAM1  DS:SI--> FROM CAL
;        DS:DI--> TO CAL
;RETURN  AL
CALCS PROC NEAR
     PUSH SI
     PUSH DI
     PUSH CX

     MOV CX, DI
     SUB CX, SI

     MOV AL, 0
NB:
     ADD AL, DS:[SI]
     INC SI
     LOOP NB
     NOT AL
     INC AL

     POP CX
     POP DI
     POP SI
     RET
CALCS ENDP

;#################################
TSRSTART:
     PUSHA
     MOV AX, 0B800H
     MOV ES, AX
     MOV AX, CS
     MOV DS, AX

     CALL TT
     TSRMSG  DB  'CAN YOU SEE ME?', 0
TT:
     POP SI
     MOV DI, 80 * 10

     ;DISPLAY ADDRESS
     MOV AX, CS
     MOV AL, AH
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4
     MOV AX, CS
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4

     MOV AH, 7
     MOV AL, ':'
     MOV ES:[DI], AX
     ADD DI, 2

     MOV AX, SI
     MOV AL, AH
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4
     MOV AX, SI
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 6
     ;;

     CLD
NC:
     LODSB
     OR AL, AL
     JZ OVER
     MOV AH, 7
     STOSW
     JMP NC
OVER:
     POPA
     IRET
TSREND  = $
;##################################

;##################################
CODESTART:
     PUSHA

     MOV AX, 0B800H
     MOV ES, AX
     MOV AX, CS
     MOV DS, AX

     CALL  CT
     ;1. DISPLAY SOME MESSAGE
     MSG DB 'HELLO WORLD:)', 0
CT:
     POP SI
     MOV DI, 80 * 10

     ;DISPLAY ADDRESS
     MOV AX, CS
     MOV AL, AH
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4
     MOV AX, CS
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4

     MOV AH, 7
     MOV AL, ':'
     MOV ES:[DI], AX
     ADD DI, 2

     MOV AX, SI
     MOV AL, AH
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 4
     MOV AX, SI
     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 6
     ;;

     CLD
NC1:
     LODSB
     OR AL, AL
     JZ OVER1
     MOV AH, 7
     STOSW
     JMP NC1
OVER1:
     ;2. CHANGE IVT
     MOV AX, 0
     MOV ES, AX
     MOV AX, OFFSET TSRSTART
     MOV ES:[98H * 4],  AX
     MOV AX, CS
     MOV ES:[98H * 4 + 2], AX

     ;3.NOW SET INIT SIZE = 0
     MOV AL,  (TSREND - ROMSTART + 511) / 512
     MOV INITSIZE, AL

     ;4.CAL NEWCHECKSUM
     MOV SI, ROMSTART
     XOR AH, AH
     MOV DI, AX
     MOV CL, 9
     SHL DI, CL
     SUB DI, 2
     ADD DI, SI

     CALL CALCS
     MOV DS:[DI + 1], AL

     POPA
     RETF

     CODEEND = $

     DB (512 - ((CODEEND - ROMSTART) AND 1FFH)) - 1  DUP (0)
     CHECKSUM  DB   0
     ROMEND = $
;#####################################

;#####################################
;MYDATE
     ;********************
     WRITEREG  DW   0ECD4H
     READREG   DW   0ECD7H

     OKMSG  DB 'OK! WRITE SUCCESSFULLY!', 0
     ERRMSG DB 'WRITE ERROR! OVER!', 0
START:
     MOV AX, CODE
     MOV DS, AX
     MOV AX, 0B800H
     MOV ES, AX
     CLI
     MOV AX, STACK
     MOV SS, AX
     MOV SP, STACKLEN
     STI

;     DB 09AH
;     DW 3
;     DW SEG CODE

     MOV SI, ROMSTART
     MOV DI, ROMEND
     CALL CALCS
     MOV CHECKSUM, AL

     ;NOW WRITE TO ROM AND VERIFY ROM*************
     MOV AX, 0B800H
     MOV ES, AX
     MOV BP, 14 * 80
     MOV SI, OFFSET ROMSTART
     MOV DI, 0
     MOV BX, ROMEND
     SUB BX, ROMSTART
NB2:
     MOV AL, DS:[SI]

     ;*********DISPLAY THE BYTE
     CALL TOASCII
     MOV ES:[BP], EDX
     ADD BP, 4
     ;***********

     MOV CL, 24
     SHL EAX, CL      
     MOV AX, DI

     MOV DX, WRITEREG
     OR  EAX, 000A0000H
     OUT DX, EAX
     ;WAIT ....
     MOV CX, 0FFFFH
     LOOP $

     MOV DX, WRITEREG
     MOV EAX, 00040000H
     MOV AX, DI
     OUT DX, EAX
     ;WAIT ....
     MOV CX, 0FFFFH
     LOOP $
     ;.........

     MOV DX, READREG
     IN  AL, DX
     CMP AL, DS:[SI]
     JNZ ERRDISP

     INC SI
     INC DI

     DEC BX
     JNZ NB2

     ;;;;;;;;;FINISHED! DISP OK!
     MOV SI, OFFSET OKMSG
     JMP  DISP
ERRDISP:         
     MOV SI, OFFSET ERRMSG

DISP:
     MOV DI, 80 * 12
     CLD
NEXTCHAR0:
     LODSB
     OR AL, AL
     JZ GOOUT
     MOV AH, 7
     STOSW
     JMP NEXTCHAR0

GOOUT:
     MOV AH, 4CH
     INT 21H

CODE ENDS
     END START

附件5.TROM.ASM

.386P
STACK SEGMENT USE16
      DB  256 DUP (0)
STACKLEN = $
STACK ENDS

CODE SEGMENT USE16
     ASSUME CS:CODE, SS:STACK

START:
     CLI
     MOV AX, STACK
     MOV SS, AX
     MOV SP, STACKLEN
     STI

     INT 98H

     MOV AH, 4CH
     INT 21H
CODE ENDS
     END START

附件6.W256.ASM

.386
DATA SEGMENT USE16
     MSG1 DB 'OK!', 0
     MSG2 DB 'ERROR', 0
DATA ENDS

STACK SEGMENT USE16
      DB  256 DUP (0)
      STACKLEN = $
STACK ENDS

CODE SEGMENT USE16
     ASSUME CS:CODE, SS:STACK, DS:DATA
START:
     MOV AX, DATA
     MOV DS, AX
     MOV AX, 0B800H
     MOV ES, AX

     CLI
     MOV AX, STACK
     MOV SS, AX
     MOV SP, STACKLEN
     STI

     MOV ESI, 0CC0A0000H ;将0CCH写入到ROM开头
     MOV BX, 6           ;的几个字节中

NEXTBYTE:
     MOV EAX, ESI
     MOV DX, 0ECD4H
     OUT DX, EAX

     MOV CX, 0FFFFH     ;等待一下，以确保写入。
     LOOP $

     ;下面将写入的数据读出，进行校验。
     AND EAX, 0FFF7FFFFH
     MOV DX, 0ECD4H
     OUT DX, EAX

     MOV CX, 0FFFFH     ;等待一下，以确保写入。
     LOOP $
    
     MOV DX, 0ECD7H
     IN AL, DX
     CMP AL, 0CCH
     JNZ ERROR           ;校验不通过。出错。
    

     INC ESI            ;下一个地址
     DEC BX             ;减少计数器
     JNZ NEXTBYTE
    
     MOV SI, OFFSET MSG1
     JMP DISP
ERROR:
     MOV SI, OFFSET MSG2

DISP:
    MOV DI, 80 * 10
    CLD

NEXTCHAR:
    LODSB
    OR AL, AL
    JZ OVER
    MOV AH, 7
    STOSW
    JMP NEXTCHAR

OVER:
     MOV AH, 4CH
     INT 21H

CODE ENDS
     END START

 附件7：R128.ASM

.386
STACK SEGMENT USE16
      DB  256 DUP (0)
      STACKLEN = $
STACK ENDS

CODE SEGMENT USE16
     ASSUME CS:CODE, SS:STACK
START:
     CLI
     MOV AX, STACK
     MOV SS, AX
     MOV SP, STACKLEN
     STI

     MOV AX, 0B800H
     MOV ES, AX
     MOV DI, 80 * 10

     MOV EBX, 00064000H
     MOV CX, 100

NEXTBYTE:
     MOV EAX, EBX
     MOV DX, 0ECD4H
     OUT DX, EAX

     PUSH CX
     MOV CX, 0FFFFH
     LOOP $
     POP CX

     PUSH CX
     MOV CX, 0FFFFH
     LOOP $
     POP CX

     PUSH CX
     MOV CX, 0FFFFH
     LOOP $
     POP CX

     MOV DX, 0ECD7H
     IN AL, DX

     CALL TOASCII
     MOV ES:[DI], EDX
     ADD DI, 6
     INC EBX
    
     LOOP NEXTBYTE

     MOV AH, 4CH
     INT 21H

;AL->EDX
TOASCII PROC NEAR
    PUSH AX
    PUSH BX
    PUSH CX

    XOR EDX, EDX
    MOV BL, AL
    AND AL, 0FH
    CMP AL, 9
    JA TO1
    ADD AL, '0'
    JMP TO2
TO1:
    SUB AL, 10
    ADD AL, 'A'
TO2:
    MOV AH, 7
    MOV DX, AX
    MOV CL, 16
    SHL EDX, CL

    MOV CL, 4
    SHR BL, CL
    CMP BL, 9
    JA   TO3
    ADD BL, '0'
    JMP TO4
TO3:
    SUB BL, 10
    ADD BL, 'A'
TO4:
    MOV BH, 7
    MOV DX, BX

    POP CX
    POP BX
    POP AX

    RET
TOASCII ENDP

CODE ENDS
     END START

 

 

 

misterliwei
关注
  • 0
    点赞
  • 踩
  • 3
    收藏
    觉得还不错? 一键收藏
  • 4
    评论
Network 之十 BIOS + MBR、UEFI + GPT、GRUB、BOOTMGR、SYSLINUX、Option ROM
技术干货
08-28 3525
一台运行操作系统的设备（PC 或嵌入式 Linux 设备）从上电到出现我们用户可见的操作系统提供的 GUI 或者 CLI 经历了一些列的过程。这个过程在 PC 和 嵌入式设备上稍有不同，但大致的流程仍然基本一致。.......................................................................................
Linux网络驱动源码分析(一)
少帅的天空
04-17 7099
<br />  网络驱动是一种典型的PCI设备驱动，无论在嵌入式平台还是在PC领域，网络相关的项目开发有着比较广阔的前景，因此，分析当前Linux内核中网络设备的驱动，不但能了解网络相关的基本原理，而且可以借鉴Linux内核的先进的技术，将其应用到嵌入式或其他领域。本文以Linux内核中的rtl8139网络驱动为例，对网络驱动的源码进行了简单分析，并对其中涉及的相关概念和技术进行了简单的介绍。<br />一、PCI设备驱动模型<br />       rtl8139是典型的PCI设备，Linux内核的PCI
PCI Option ROM in BIOS
humanof的专栏
07-24 1746
虽然UEFI 出来十几年了，但是legacy 的阴影一直笼罩着我们。今天我们来看看Legacy里面的一个老朋友OpRom。以前很多PCI 设备上面都外挂一颗Rom，用来实现一些特定的功能，比如网络启动，硬盘保护，远程管理等等。后面比较常见的就只有网卡和显卡这两种设备还在用OpRom，独立的板卡有自己的板载Rom IC，板载的为了节约成本，就把OpRom包到BIOS里面。此外，OpRom也可以独立...
PCI网卡上扩展ROM编程 5.PCI扩展ROM
misterliwei的专栏
09-08 4336
PCI扩展ROM   1.     ROM映像 在PCI规范中提供了一种机制，使PCI设备可以带一个扩展ROM。通过执行ROM中存放的代码来完成与设备有关的初始化，同时也有可能完成系统的引导功能。该机制允许扩展ROM包含有几种为不同系统和处理器结构而设计的映像（如图16）。 图16 ROM中可包含不通类型的映像   每个映像必须开始于一个512字节边界并含有P
BIOS之Option ROM详解
热门推荐
huangkangying的专栏
05-15 5万+
1. 何为Option ROM PCI Option ROM又叫PCI Expansion ROM。 它是用于设备初始化和系统boot的code。有的PCI Option ROM被存放在板卡上，而有的则保存在BIOS的binary里面。 2. PCI Option ROM的分类 Option ROM按版本分有2.1的Option ROM和3.0的Option ROM. > 通过查看PCI
PCI 扩展ROM 控制芯片CH364
11-04
CH364 提供容量为64KB 的可电擦写只读存储器Flash-ROM，支持软件模拟兼容I2C 的两线串口进行数据和I/O 扩展，专用于各种带有扩展ROM 的PCI 控制卡，包括系统还原卡、数据保护卡、网络隔离卡、安全控制卡等，由于无需...
VxWorks下PCI网卡驱动程序结构与实现.pdf
02-10
VxWorks下PCI网卡驱动程序结构与实现.pdf
pci网卡的傻瓜式维修.txt
03-15
几种常见故障： 1、“网络电缆被拔出”2“设备安装失败”3 安装网卡后电脑无法启动或启动后无任何反应.......
网卡驱动注册到PCI总线这一过程的分析.rar_pci总线_pci网卡驱动
09-21
pci网卡注册过程及网卡驱动注册到PCI总线这一过程的分析
DSP与PCI网卡接口设计.-论文
05-12
DSP与PCI网卡接口设计.
网卡PXE_ROM写入主板BIOS方法
12-04
网卡PXE_ROM写入主板BIOS方法网卡PXE_ROM写入主板BIOS方法
PCI&PCIE ExpansionOption ROM
Wang20122013的博客
09-15 1472
1、什么是ExpansionOption ROM？ Expansion rom是pci/pcie设备可选的一个外接的eprom芯片，其中用来存储相应pci设备的初始化代码或者系统启动代码(比如pxe或者pci boot)。BIOS在POST(Power-on Self Test)阶段，会扫描pci设备是否有expansion rom，有的话将其拷贝到ram中执行。在PCI规范中称为expansion rom，在BIOS术语里面称为option rom。 例如，我们系统启动阶段可以看到网卡和LSI SAS芯片
修改VMWARE的网卡类型、网卡ROM
weixin_30689307的博客
03-26 422
VMWARE支持三种网卡：AMD PCNet AM79C970A，Intel PRO/1000，VMware PCI Ethernet Adapter。打开要修改的虚拟机VMX文件，在最下面按以下格式增加一行即可：ethernet0.virtualDev = "value"nbios.filename = "biosfile"e1000bios.filename = "biosfile"valu...
如何把网卡PXE_ROM写入主板BIOS
nieshanfeng1的专栏
05-25 2725
独立网卡不加PXE芯片也可无盘启动.在我们做无盘的时候，可能会遇到某些独立网卡由于驱动等方面的问题，不能很好的用来做无盘客户机，这个时候我们就不得不加独立网卡来解决这个问题，但是光有独立网卡还是不够的，我们还要再多买一块PXE芯片，一般情况下是5块钱一块，如果一个网吧有200台机器，那么就要为买这些芯片而多出上千元，这样一来，网吧可能不是很乐意，所以我们在面对这样网吧的时候，可以考虑通过下面的方法
PCI网卡上扩展ROM编程 4.利用8139C网卡读写EPROM
misterliwei的专栏
09-08 7531
利用8139C网卡读写EPROM  最后编辑：2010-5-25（修改错别字）   一．        27C256引脚和模式 只读存储器随着技术的发展，主要经历了ROM、PROM、EPROM、EEPROM等。EPROM的擦除只能借助于长时间暴露于紫外线，使用不太方便，常用于产品开发阶段。常用的EPROM大小有：128K位、256K位、512K位等等。由于我手上只有128K和256K大小
【我所認知的BIOS】—>PCI option rom
肢解BIOS
06-02 4万+
【我所認知的BIOS】—>PCI option romBy LightSeed2009-5-22 在這裡添加一句，畢竟什麽東東都是有相應的組織來定義了spec的，那麼不管做什麽動作我們都必須嚴格按照spec規定的動作來，否則你做出來的信號就只有你自己知道了，或者起碼說不適用於業界，所以處在我現在的這個初級階段我還是想把spec都理解透徹，也鑒於此可能很多我的總結也都是會提到spec裏的
网口扫盲一:网卡初步认识
weixin_33895604的博客
07-18 1093
网络适配器又称网卡或网络接口卡(NIC),英文名Network Interface Card.它是使计算机联网的设备.平常所说的网卡就是将PC机和LAN连接的网络适配器.网卡(NIC) 插在计算机主板插槽中,负责将用户要传递的数据转换为网络上其它设备能够识别的格式,通过网络介质传输.数据在计算机总线中传输是并行方式即数据是肩并肩传输的,而在网络的物理缆线中说数据以串行的比特流方式传输的,网卡承担串...
UEFI driver & Option Rom
wondervictor的博客
04-18 1877
 UEFI driver & Option Rom
pci_express_base_5.
最新发布
10-03
在计算机领域中，PCI Express（Peripheral Component Interconnect Express）被称为PCI-E。它是一种高速数据传输接口标准，用于连接计算机主板和扩展卡。PCI Express接口的版本通常用“PCIe x几”来表示，其中x表示通道的数量，例如PCI Express x1、PCI Express x4等。 而在问题中提到的“PCI Express Base 5.0”，则指的是PCI Express 5.0的基础规范版本。PCI Express 5.0是目前最新的PCIe标准之一，于2019年发布。它在传输速度和带宽方面有重大改进，与上一代标准PCI Express 4.0相比，传输速度翻倍，带宽提升了一倍。 PCI Express 5.0的基础规范包括了通信协议、电气规范、信号调整和物理连接等方面的内容。这个版本的PCIe引入了PAM4编码（四级脉冲振幅变调），通过在每个时钟周期中传输4个不同的信号级别，来提高数据传输速度。 PCI Express 5.0的出现对于现代计算机系统非常重要。它可以提供更高的带宽和更低的延迟，以满足现代应用程序对数据传输速度的需求。许多高性能计算、数据中心和网络设备都可以受益于PCI Express 5.0的使用，以实现更快、更可靠的数据传输。 总之，PCI Express Base 5.0是指PCI Express 5.0的基础规范版本，它是计算机系统中的一种高速数据传输接口标准，通过提供更高的带宽和更低的延迟，满足现代应用程序对数据传输速度的需求。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论 4
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值