Nz 函数

Nz 函数

当 Variant （Variant 数据类型：变量的默认数据类型，如果 Def type 语句没有生效，则该数据类型没有类型声明字符。Variant 可以存储数值、字符串、日期/时间、Null 或 Empty 数据。） 类型的值为 Null （Null：可以在字段中输入或用于表达式和查询，以标明丢失或未知的数据。在 Visual Basic 中，Null 关键字表示 Null 值。有些字段（如主键字段）不可以包含 Null 值。） 时，可以使用 Nz 函数返回零、零长度字符串 （零长度字符串：不含字符的字符串。可以使用零长度字符串来表明您知道该字段没有值。输入零长度字符串的方法是键入两个彼此之间没有空格的双引号 (" ")。） (" ") 或其他指定值。例如，可以使用此函数将 Null 值转换为其他值，并防止它通过表达式传播。

语法

Nz(variant [, valueifnull ] )

Nz 函数的语法包含以下参数：

参数	说明
variant	必选。数据类型 （数据类型：决定字段可拥有的数据类型的字段特征。数据类型包括 Boolean、Integer、Long、Currency、Single、Double、Date、String 和 Variant（默认）。）为 Variant 的变量。
valueifnull	可选（除非用于查询中）。如果 variant 参数为 Null，则此参数是可提供返回值的 Variant 型参数。此参数允许您返回零或零长度字符串以外的值。  注释   如果在查询表达式中使用 Nz 函数而不使用 valueifnull 参数，则在包含空值的字段中结果将是零长度字符串。

 

如果 variant 参数的值为 Null，则 Nz 函数返回数值零或零长度字符串（用在查询表达式中时始终返回零长度字符串），具体取决于上下文是否对该值应该是数值还是字符串做出了指示。如果包括可选的 valueifnull 参数，则当 variant 参数为 Null 时，Nz 函数将返回该参数指定的值。用在查询表达式中时，NZ 函数应始终包含 valueifnull 参数。

如果 variant 的值不为 Null，则 Nz 函数将返回 variant 的值。

注解

Nz 函数对于可能包括 Null 值的表达式很有用。要强制表达式计算出非 Null 值（即使它包含 Null 值），请使用 Nz 函数来返回零、零长度字符串或自定义返回值。

例如，当 Variant varX 为 Null 时，表达式 2 + varX 将始终返回 Null 值。但 2 + Nz(varX) 返回 2。

通常可以使用 Nz 函数作为 IIf 函数的备选方案。例如，在下面的代码中，为了返回期望的结果，必须使用包括 IIf 函数的两个表达式。第一个包括 IIf 函数的表达式用于检查变量的值并在它为 Null 时将其转换为零。

varTemp = IIf(IsNull(varFreight), 0, varFreight)
varResult = IIf(varTemp > 50, "High", "Low")
		

在下一个示例中，Nz 函数可与第一个表达式提供相同的功能，并且只需一步而非两步便可获得期望的结果。

varResult = IIf(Nz(varFreight) > 50, "High", "Low")
		

如果为可选的参数 valueifnull 提供一个值，则当 variant 为 Null 时将返回该值。通过包括此可选参数，可以避免使用包含 IIf 函数的表达式。例如，如果 varFreight 的值为 Null，下面的表达式将使用 IIf 函数返回一个字符串。

varResult = IIf(IsNull(varFreight), _
    "No Freight Charge", varFreight)
		

在下一个示例中，Nz 函数的可选参数提供了 varFreight 为 Null 时将返回的字符串。

varResult = Nz(varFreight, "No Freight Charge")
		

示例

 注释   以下示例演示了此功能在 Visual Basic for Applications (VBA) 模块中的使用。有关使用 VBA 的详细信息，请在“搜索”旁边的下拉列表中选择“开发人员参考”，然后在搜索框中输入一个或多个词条。

下面的示例对窗体上的一个控件进行计算，并根据该控件的值返回两个字符串之一。如果该控件的值为 Null，该过程将使用 Nz 函数将 Null 值转换为零长度字符串。

Public Sub CheckValue()

    Dim frm As Form
    Dim ctl As Control
    Dim varResult As Variant

    ' Return Form object variable 
    ' pointing to Orders form.
    Set frm = Forms!Orders

    ' Return Control object variable 
    ' pointing to ShipRegion.
    Set ctl = frm!ShipRegion

    ' Choose result based on value of control.
    varResult = IIf(Nz(ctl.Value) = vbNullString, _
        "No value.", "Value is " & ctl.Value & ".")

    ' Display result.
    MsgBox varResult, vbExclamation

End Sub