【ABAQUS二次开发手册】【6.1】【Abaqus内置GUI案例的调用工具】

1 效果图

1.1 beamAPP案例

2 源代码 runAbaqusDemoAPPs.bat

@echo off
color 0a
:begin
cls
if defined sel (echo 请选择操作[%sel%]:) else echo 请选择操作:
echo   [a] 提取GUI文件
echo   [s] 删除GUI文件
echo   [d] 清理临时文件
echo   [f] 运行prototypeApp示例
echo   [q] 运行widgetApp示例
echo   [w] 运行beamApp示例
echo   [e] 运行block插件示例
echo   [r] 退出
set /p sel=">>>"
if "%sel%" == "a" goto getGUI
if "%sel%" == "s" goto delGUI
if "%sel%" == "d" goto deltmp
if "%sel%" == "f" goto prototypeApp
if "%sel%" == "q" goto widgetApp
if "%sel%" == "w" goto beamApp
if "%sel%" == "e" goto abaqus
if "%sel%" == "r" exit
goto begin

:abaqus
call abaqus cae -noStartup
pause
goto begin

:getGUI
call abaqus fetch job=*_ans.py
if not exist abaqus_plugins (mkdir abaqus_plugins)
copy block_plugin_ans.py abaqus_plugins\block_plugin.py /y
copy blockDB_ans.py abaqus_plugins\blockDB_ans.py /y
copy blockModule_ans.py abaqus_plugins\blockModule_ans.py /y
pause
goto begin

:delGUI
del *_ans.py* >nul
pause
goto begin

:deltmp
del *.rpy*;*.dmp;*.log;*.guiState*;*.rec >nul
del *.com;*.dat;*.inp;*.ipm;*.log;*.msg;*.odb;*.prt;*.sim;*.sta >nul
pause
goto begin

:prototypeApp
if not exist prototypeApp_ans.py ((echo 无GUI文件) & pause & goto begin)
call abaqus cae -custom prototypeApp_ans -noStartup
pause
goto begin

:widgetApp
if not exist widgetApp_ans.py ((echo 无GUI文件) & pause & goto begin)
call abaqus cae -custom widgetApp_ans -noStartup
pause
goto begin

:beamApp
if not exist beamApp_ans.py ((echo 无GUI文件) & pause & goto begin)
call abaqus cae -custom beamApp_ans -noStartup
pause
goto begin

3 用法

前提：已安装Abaqus

1. 双击运行runAbaqusDemoAPPs.bat
2. 先选【a】提取GUI文件
3. 可选【f】【q】【w】【e】运行指定的GUI案例
4. 最后选【s】【d】清理临时文件及GUI文件，还原干净整洁的状态！