Nginx 快捷启动方式，编写bat文件教程

@echo off
rem @author luwuer
chcp 65001

set NGINX_DIR=D:\nginx-1.17.2\

:INFO
  echo.
  echo --------------------- 进程列表 ---------------------
  tasklist|findstr /i "nginx.exe"
  if errorlevel 1 echo nginx未启动
  echo --------------------- 进程列表 ---------------------

  echo.
  echo. 1. 启动Nginx
  echo. 2. 关闭Nginx
  echo. 3. 重启Nginx
  echo. 4. 退出
  echo.
  echo 请输入功能序号：
  set /p id=
    if "%id%"=="1" goto START
    if "%id%"=="2" goto STOP
    if "%id%"=="3" goto RESTART
    if "%id%"=="4" exit
  pause

:START 
  if exist "%NGINX_DIR%nginx.exe" (
    cd /d %NGINX_DIR%
    start "" nginx.exe
    echo 启动成功
  ) else (
    echo "%NGINX_DIR%nginx.exe不存在"
  )
  goto INFO

:STOP
  taskkill /F /IM nginx.exe > nul
  echo 已关闭所有nginx进程
  goto INFO

:RESTART
  taskkill /F /IM nginx.exe > nul
  if exist "%NGINX_DIR%nginx.exe" (
    cd /d %NGINX_DIR%
    start "" nginx.exe
  ) else (
    echo "%NGINX_DIR%nginx.exe不存在"
  )
  echo 已重启
  goto INFO

goto :eof

1.以上需要注意的几个配置：

1. chcp 65001   //设置运行时，文档为utf-8，防止出现乱码

2. set NGINX_DIR=D:\nginx-1.17.2\    //nginx安装的目录文件，我的目录文件如下图所示：

2.使用方式：

1.新建.text文件，将上面的代码复制到文件中。

2.修改1.2项中的路径配置，为自己的应用路径。

3.另存为.bat后缀的文件格式，到自己目标文件夹。存在哪里都没关系，这只是个快捷使用方式。生成如下所示文件：

4.双击打开，如下图所示：

   

6.输入对应的序号，按 Enter 键，完成相应的指令。

礼成^_^