记录易语言调用Lua DLL的方法

声明DLL函数

.版本 2

.DLL命令 jb_loadstring, 整数型, "Lua5.4x.dll", "@luaL_loadstring"
    .参数 L指针, 整数型
    .参数 脚本文本, 文本型

.DLL命令 jb_loadfilex, 整数型, "Lua5.4x.dll", "@luaL_loadfilex"
    .参数 L指针, 整数型
    .参数 文件名称, 文本型
    .参数 null, 整数型

.DLL命令 jb_newstate, 整数型, "Lua5.4x.dll", "@luaL_newstate"

.DLL命令 jb_setglobal, , "Lua5.4x.dll", "@lua_setglobal"
    .参数 L指针, 整数型
    .参数 var, 文本型

.DLL命令 jb_pcallk, 整数型, "Lua5.4x.dll", "@lua_pcallk"
    .参数 L指针, 整数型
    .参数 n, 整数型
    .参数 r, 整数型
    .参数 f, 整数型
    .参数 ctx, 整数型
    .参数 k, 整数型

.DLL命令 jb_close, , "Lua5.4x.dll", "@lua_close"
    .参数 参数_L, 整数型

.DLL命令 jb_pushstring, 整数型, "Lua5.4x.dll", "@lua_pushstring"
    .参数 参数_L, 整数型
    .参数 参数_字符串, 文本型

.DLL命令 jb_pushcclosure, 整数型, "Lua5.4x.dll", "@lua_pushcclosure"
    .参数 参数_L, 整数型
    .参数 参数_f, 子程序指针
    .参数 参数_n, 整数型

.DLL命令 jb_settable, 整数型, "Lua5.4x.dll", "@lua_settable"
    .参数 参数_L, 整数型
    .参数 参数_f, 整数型

.DLL命令 jb_gettop, 整数型, "Lua5.4x.dll", "@lua_gettop"
    .参数 参数_L, 整数型

.DLL命令 jb_getglobal, , "Lua5.4x.dll", "@lua_getglobal"
    .参数 L指针, 整数型
    .参数 var, 文本型

.DLL命令 jb_tolstring, 文本型, "Lua5.4x.dll", "@lua_tolstring"
    .参数 参数_L, 整数型
    .参数 参数_numArg, 整数型
    .参数 len, 整数型

.DLL命令 jb_tointegerx, 整数型, "Lua5.4x.dll", "@lua_tointegerx"
    .参数 L指针, 整数型
    .参数 idx, 整数型
    .参数 isnum, 整数型

.DLL命令 jb_tonumberx, 双精度小数型, "Lua5.4x.dll", "@lua_tonumberx"
    .参数 参数_L, 整数型
    .参数 参数_idx, 整数型

.DLL命令 jb_pushnumber, , "Lua5.4x.dll", "@lua_pushnumber"
    .参数 参数_L, 整数型
    .参数 参数_idx, 双精度小数型

.DLL命令 jb_openlibs, , "Lua5.4x.dll", "@luaL_openlibs"
    .参数 参数_L, 整数型

Lua环境初始化

.版本 2
.支持库 spec

L_指针 ＝ jb_newstate ()
.如果真 (L_指针 ≤ 0)
    信息框 (“L指针获取失败...”, 0, , )
    返回 ()
.如果真结束

调试输出 (L_指针)
jb_openlibs (L_指针)  //打开Lua所有支持库 例如 os.time()
注册_JBLua函数 (L_指针)

函数的注册

.版本 2

.子程序 JB_register, , , 注册到 Lua 中的任何函数都必须遵循正确的协议来接收参数和返回值
.参数 参数_L指针, 整数型
.参数 参数_函数名称, 文本型
.参数 参数_函数指针, 子程序指针


jb_pushcclosure (参数_L指针, 参数_函数指针, 0)
jb_setglobal (参数_L指针, 参数_函数名称)

.子程序 注册_JBLua函数
.参数 参数_L指针, 整数型

JB_L ＝ 参数_L指针
JB_register (参数_L指针, “输出”, &lua_print)
JB_register (参数_L指针, “test”, &lua_返回测试)


.子程序 jb_dostring, 整数型, 公开
.参数 参数_L, 整数型
.参数 参数_字符串代码, 文本型
.局部变量 局_返回值, 整数型

局_返回值 ＝ jb_loadstring (参数_L, 参数_字符串代码)
.如果真 (局_返回值 ＝ 0)
    局_返回值 ＝ jb_pcallk (参数_L, 0, 0, 0, 0, 0)
.如果真结束
返回 (局_返回值)

.子程序 jb_dofile, 整数型, 公开
.参数 参数_L, 整数型
.参数 参数_文件名, 文本型
.局部变量 局_返回值, 整数型

局_返回值 ＝ jb_loadfilex (参数_L, 参数_文件名, 0)
.如果真 (局_返回值 ＝ 0)
    局_返回值 ＝ jb_pcallk (参数_L, 0, 0, 0, 0, 0)
.如果真结束
返回 (局_返回值)

.子程序 jb_tostring, 文本型
.参数 参数_L, 整数型
.参数 参数_索引, 整数型

返回 (jb_tolstring (参数_L, 参数_索引, 0))

一些调用方法

jb_dostring (L_指针, 编辑框1.内容)
jb_dofile (L_指针, 取运行目录 () ＋ “\test1.lua”)