基础系列（1）-傻瓜模拟【寻宝】（基础+）

前言：

有时候，我们会认为，模拟嘛，超级简单！但是有一些高难度的比赛，往往方法简单，代码超烦人，一时之间，细节漏了，就全错，下面这道题就是其中一道。（希望不看题解能自己先打一遍代码）

                                                   寻宝（treasure.pas）

{
题目：一栋神秘的藏宝楼共有 N+1 层，最上面一层是顶层，顶层有一个房间里面藏着宝藏。除了顶层外， 藏宝楼另有 N 层，每层 M 个房间，这 M 个房间围成一圈并按逆时针方向依次编号为 0，…， M-1。其中一些房间有通往上一层的楼梯，每层楼的楼梯设计可能不同。每个房间里有一个 指示牌，指示牌上有一个数字 x，表示从这个房间开始按逆时针方向选择第 x 个有楼梯的房 间（假定该房间的编号为 k），从该房间上楼，上楼后到达上一层的 k 号房间。比如当前房 间的指示牌上写着 2，则按逆时针方向开始尝试，找到第 2 个有楼梯的房间，从该房间上楼。 如果当前房间本身就有楼梯通向上层，该房间作为第一个有楼梯的房间。 
而墙上用红色大号字体写着：“寻宝须知：帮助你找到每层上楼房间的指示 牌上的数字（即每层第一个进入的房间内指示牌上的数字）总和为打开宝箱的密钥”。 
请你编程算出这个打开宝箱的密钥。 
【输入】
第一行 2 个整数 N 和 M，之间用一个空格隔开。N 表示除了顶层外藏宝楼共 N 层楼， M 表示除顶层外每层楼有 M 个房间。 
接下来 N*M 行，每行两个整数，之间用一个空格隔开，每行描述一个房间内的情况， 其中第(i-1)*M+j 行表示第 i 层 j-1 号房间的情况（i=1, 2, …, N；j=1, 2, … ,M）。第一个整数 表示该房间是否有楼梯通往上一层（0 表示没有，1 表示有），第二个整数表示指示牌上的数 字。注意，从 j 号房间的楼梯爬到上一层到达的房间一定也是 j 号房间。 
最后一行，一个整数，表示从藏宝楼底层的几号房间进入开始寻宝（注：房间编号 从 0 开始）。
【输出】
输出只有一行，一个整数，表示打开宝箱的密钥，这个数可能会很大，请输出对 20123 取模的结果即可
解题思路：一道纯模拟，非常烦人，代码并没有特殊算法，

只需要注意：%可以代替暴力纯模拟（逆时针）。

注意！！！取模可以（k-1）%m+1，不会有0的情况，题解中此处可以优化。
}
type jl=record
  bool:longint;//是否有楼梯
  t:longint;//题目中的X
end;
var
  n,m,i,j,root,c,dq,wz,xb,v,ans:longint;
  x1,x2:array[0..105] of longint;
  a:array[0..10050,0..105] of jl;//i代表层，j代表第I层房间的编号
begin
  readln(n,m);
  for i:=1 to n do
    for j:=0 to m-1 do
    readln(a[i,j].bool,a[i,j].t);
  readln(wz);
  dq:=a[1,wz].t;
  c:=1;//从第一层开始
  while c<=n do
  begin
    ans:=(ans+dq) mod 20123;//注意先加dq
    while a[c,wz].bool<>1 do
    begin
      inc(wz);
      if wz=m then
        wz:=0;
    end;//暴力、模拟---走
    xb:=0;
    for j:=0 to m-1 do
      if a[c,j].bool=1 then
      begin
        inc(xb);
        x1[xb]:=j;
        x2[j]:=xb;
      end;//把所有的有楼梯的房间的实际编号和定义编号记录
    v:=(dq-1+x2[wz]) mod xb;//巧妙找逆时针，别忘了加上初始位置
    if v=0 then v:=xb;//特判也别忘记
    dq:=a[c+1,x1[v]].t;
    wz:=x1[v];
    inc(c);//上楼。。。
  end;
  writeln(ans);
end.