013Visual Basic适配器模式之篮球翻译适配器

1.球员类

'球员类
Public MustInherit Class Player
    Protected name As String
    Public Sub New(ByVal n As String)
        Me.name = n
    End Sub
    Public MustOverride Sub Attack()
    Public MustOverride Sub Defence()

End Class
'前锋
Public Class Forwards
    Inherits Player
    Public Sub New(ByVal n As String)
        MyBase.New(n)
    End Sub
    Public Overrides Sub Attack()
        Console.WriteLine("前锋{0}进攻", name)
    End Sub

    Public Overrides Sub Defence()
        Console.WriteLine("前锋{0}防守", name)
    End Sub
End Class
'中锋
Public Class Center
    Inherits Player
    Public Sub New(ByVal n As String)
        MyBase.New(n)
    End Sub
    Public Overrides Sub Attack()
        Console.WriteLine("中锋{0}进攻", name)
    End Sub

    Public Overrides Sub Defence()
        Console.WriteLine("中锋{0}防守", name)
    End Sub
End Class
'后卫
Public Class Guard
    Inherits Player
    Public Sub New(ByVal n As String)
        MyBase.New(n)
    End Sub
    Public Overrides Sub Attack()
        Console.WriteLine("后卫{0}进攻", name)
    End Sub

    Public Overrides Sub Defence()
        Console.WriteLine("后卫{0}防守", name)
    End Sub
End Class

2.外籍中锋

Public Class ForeignCenter
    Private _name As String
    Public Property name As String
        Get
            Return _name
        End Get
        Set(ByVal value As String)
            _name = value
        End Set
    End Property

    Public Sub 进攻()
        Console.WriteLine("外籍中锋{0}进攻", name)
    End Sub

    Public Sub 防守()
        Console.WriteLine("外籍中锋{0}防守", name)
    End Sub
End Class

3.翻译者类

Public Class Translator
    Inherits Player
    Private wjzf As New ForeignCenter
    Public Sub New(ByVal n As String)
        MyBase.New(n)
        wjzf.name = n
    End Sub
    Public Overrides Sub Attack()
        wjzf.进攻()
    End Sub

    Public Overrides Sub Defence()
        wjzf.防守()
    End Sub
End Class

4.客户端

Module Module1

    Sub Main()
        Dim b As New Forwards("巴蒂尔")
        b.Attack()
        Dim m As New Guard("麦克格雷迪")
        m.Attack()
        Dim ym As New Translator("姚明")
        ym.Attack()
        ym.Defence()

        Console.Read()
    End Sub

End Module