Delphi中实现智能指针

在C++中可以利用栈实现智能指针，可是在Delphi中由于所有的对象都是堆对象，无法利用栈对象。虽然在Delphi2007版本中已经有类似的栈结构，但是仍然不能实现完全意义上的指针。但是Delphi中可以利用另外一样东西实现智能指针--接口。附上源码：

1. unit AutoPtr;
3. interface
5. uses
6.   SysUtils, SyncObjs;
8. type
10.   { TAutoPtrObject - 智能指针对象 }
12.   TAutoPtrObject = class(TInterfacedObject)
13.   private
14.     FObject: TObject;
15.   public
16.     constructor Create(AObject: TObject); virtual;
17.     destructor Destroy; override;
18.   end;
20.   { TAutoLockObject - 智能线程锁 }
22.   TAutoLockObject = class(TInterfacedObject)
23.   private
24.     FSection: TCriticalSection;
25.   public
26.     constructor Create(ASection: TCriticalSection); virtual;
27.     destructor Destroy; override;
28.   end;
30. function AutoFree(AObject: TObject): IInterface;
31. function AutoLock(ASection: TCriticalSection): IInterface;
33. implementation
35. //------------------------------------------------------------------------------
36. // 自动释放对象函数(对象必须由外部创建, 离开栈作用域释放)
37. //------------------------------------------------------------------------------
38. function AutoFree(AObject: TObject): IInterface;
39. begin
40.   Result := TAutoPtrObject.Create(AObject);
41. end;
43. //------------------------------------------------------------------------------
44. // 自动释放线程锁(对象必须由外部创建，离开栈作用域释放)
45. //------------------------------------------------------------------------------
46. function AutoLock(ASection: TCriticalSection): IInterface;
47. begin
48.   Result := TAutoLockObject.Create(ASection);
49. end;
52. { TAutoPtrObject }
54. constructor TAutoPtrObject.Create(AObject: TObject);
55. begin
56.   FObject := AObject;
57. end;
59. destructor TAutoPtrObject.Destroy;
60. begin
61.   // 智能指针在方法退出时销毁，同时销毁所管理的堆对象
62.   try FreeAndNil(FObject); except end;
63.   inherited;
64. end;
66. { TAutoLockObject }
68. constructor TAutoLockObject.Create(ASection: TCriticalSection);
69. begin
70.   inherited Create;
71.   Assert(ASection <> nil);
72.   FSection := ASection;
74.   FSection.Enter;
75. end;
77. destructor TAutoLockObject.Destroy;
78. begin
79.   FSection.Leave;
80.   inherited;
81. end;
83. end.

不过利用接口实现的智能指针经过本人测试，会比较正常Try Finally 要多用一倍的时间。

（出处： http://blog.csdn.net/missmecn/article/details/3016297）