自动化脚本之bat管理IP地址

        IP设置自动化，对于Windows来说，使用bat方式是最方便的。但是要像我这个脚本这样全面的bat文件，估计你没见过。不要再用鼠标点来点去，把IP换来换取。其实只要鼠标双击一下，再选择一项就搞定了。该脚本借鉴了网上一些已有的bat文件改进而成。

        对于开启笔记本无线网卡上的无线路由器功能，需要修改本地连接属性，“允许其他网络用户通过此计算机的Internet连接来连接”。

IP.bat文件

@ echo off  
rem ========================================= 
rem    IP config 
rem    Raymond 2011.7.10 
rem    this version is for Window 7 
rem ========================================= 
rem 设置变量  
set Nic=本地连接  
rem 可以根据你的需要更改,  
set Addr1=192.168.1.119  
set Mask1=255.255.255.0  
set Addr0=172.22.127.203   
set Mask0=255.255.255.240  
set Addr2=128.0.0.188  
set Mask2=255.0.0.0  
set Addr3= 
set Mask3= 
set Addr4= 
set Mask4= 
set Addr5= 
set Mask5= 
set Addr6= 
set Mask6= 
set Gway1=192.168.1.1  
set Dns1=203.198.23.208  
set Dns2=218.102.32.208  
  
rem  IP2 
set Addr=20.40.46.61  
set Mask=255.255.255.240   
set Gway2=0.0.0.0  
set Dns3=0.0.0.0  
set Dns4=0.0.0.0 
  
rem 以上依次为IP地址、子网掩码、网关、首选DNS、备用DNS 
  
echo －－－－－－－－－－－－－－－－ 
echo －－－   IP切换批处理     －－－ 
echo －－－－－－－－－－－－－－－－ 
echo     1 设置为内网IP1 
echo     2 设置为内网IP2 
echo     3 设置为动态IP 
echo     4 开启无线路由器 
echo     5 关闭无线路由器 
echo     6 显示IP并退出 
echo －－－请选择项目后回车 
set /p answer= 
  
if %answer%==1 goto 1 
if %answer%==2 goto 2 
if %answer%==3 goto 3 
if %answer%==4 goto 4 
if %answer%==5 goto 5 
if %answer%==6 goto 6 
:1 
echo 正在进行内网IP1设置，请稍等... 
rem 可以根据你的需要更改  
echo. I P 地址 = %addr0%  
echo. 子网掩码 = %Mask0%  
echo. 默认网关 = %Gway1%  
netsh interface ip set address name=%Nic% source=static addr=%addr0% mask=%Mask0% gateway=%Gway1% gwmetric=1  
echo. I P 地址 = %addr1%  
echo. 子网掩码 = %Mask1%  
netsh interface ip add address name=%Nic% addr=%addr1% mask=%Mask1%  
echo. I P 地址 = %addr2%  
echo. 子网掩码 = %Mask2%  
netsh interface ip add address name=%Nic% addr=%addr2% mask=%Mask2%  
goto skip1 
  
echo. I P 地址 = %addr3%  
echo. 子网掩码 = %Mask3%  
netsh interface ip add address name=%Nic% addr=%addr3% mask=%Mask3% 
echo. I P 地址 = %addr4%  
echo. 子网掩码 = %Mask4%  
netsh interface ip add address name=%Nic% addr=%addr4% mask=%Mask4%  
echo. I P 地址 = %addr5%  
echo. 子网掩码 = %Mask5%  
netsh interface ip add address name=%Nic% addr=%addr5% mask=%Mask5% 
echo. I P 地址 = %addr6%  
echo. 子网掩码 = %Mask6%  
netsh interface ip add address name=%Nic% addr=%addr6% mask=%Mask6% 
  
:skip1 
echo. 首选 DNS = %Dns1% 
netsh interface ip set dns name=%Nic% source=static addr=%Dns1% register=PRIMARY  
echo. 备用 DNS = %Dns2%  
netsh interface ip add dns name=%Nic% addr=%Dns2% index=2  
echo ---- 
echo 全部设置完成!  
pause 
goto showip 
  
:2 
echo 正在进行IP2设置，请稍等... 
rem //可以根据你的需要更改  
echo. I P 地址 = %addr%  
echo. 子网掩码 = %Mask%  
echo. 默认网关 = %Gway2%  
netsh interface ip set address name=%Nic% source=static addr=%addr% mask=%Mask% gateway=%Gway2% gwmetric=1 >nul  
echo. 首选 DNS = %Dns3%  
netsh interface ip set dns name=%Nic% source=static addr=%Dns3% register=PRIMARY >nul  
echo. 备用 DNS = %Dns4%  
netsh interface ip add dns name=%Nic% addr=%Dns4% index=2 >nul  
echo ---- 
echo 全部设置完成!  
pause 
goto showip 
  
:3 
echo 正在进行动态IP设置，请稍等... 
echo. IP 地址正在从DHCP自动获取... 
netsh interface ip set address "本地连接" dhcp 
echo. DNS地址正在从DHCP自动获取... 
netsh interface ip set dns "本地连接" dhcp 
echo ---- 
echo 全部设置完成!  
pause 
goto showip 
  
:4 
netsh wlan set hostednetwork mode=allow ssid="mini_net" key=net987 
netsh wlan start hostednetwork 
goto showip 
  
:5 
netsh wlan stop hostednetwork 
netsh wlan set hostednetwork mode=disallow ssid="mini_net"
goto showip 
  
:6 
goto showip 
  
:showip 
cls
ipconfig /all 
pause 
  
:end 
exit