SQL Server 查询出金额转换为大写

在画报表时,金额合计字段需要使用大写金额,所以查了很多地方,最后记录下这个简单的,可以实现的函数:

USE [Orz]
GO

/****** Object:  UserDefinedFunction [dbo].[OW_Function_ChangeNumType]    Script Date: 2019-08-05 10:12:38 ******/
SET ANSI_NULLS ON
GO

SET QUOTED_IDENTIFIER ON
GO


CREATE  FUNCTION [dbo].[OW_Function_ChangeNumType]
(@num numeric(14,2))  
 
RETURNS varchar(100) --WITH ENCRYPTION   
AS   
BEGIN   
  DECLARE @n_data VARCHAR(20),@c_data VARCHAR(100),@n_str VARCHAR(10),@i int   
  SET @n_data=RIGHT(SPACE(14)+CAST(CAST(ABS(@num*100) AS bigint) AS varchar(20)),14)   
  SET @c_data=''   
  SET @i=1   
  WHILE @i<=14   
  BEGIN   
    SET @n_str=SUBSTRING(@n_data,@i,1)   
    IF @n_str<>' '   
    BEGIN   
       IF not ((SUBSTRING(@n_data,@i,2)='00') or   
         ((@n_str='0') and ((@i=4) or (@i=8) or (@i=12) or (@i=14))))   
        SET @c_data=@c_data+SUBSTRING('零壹贰叁肆伍陆柒捌玖',CAST(@n_str AS int)+1,1)   
       IF not ((@n_str='0') and (@i<>4) and (@i<>8) and (@i<>12))   
        SET @c_data=@c_data+SUBSTRING('仟佰拾亿仟佰拾万仟佰拾圆角分',@i,1)   
       IF SUBSTRING(@c_data,LEN(@c_data)-1,2)='亿万'   
        SET @c_data=SUBSTRING(@c_data,1,LEN(@c_data)-1)   
    END   
    SET @i=@i+1   
  END   
   IF @num<0   
    SET @c_data='（负数）'+@c_data   
   IF @num=0   
    SET @c_data='零圆'
  if RIGHT(@c_data,1)='圆'    
    SET @c_data=@c_data+'整'   
  RETURN(@c_data)   
END

GO

注:第15行的[WITH ENCRYPTION]为加密创建,即sp_helptext函数无法查看函数内容,不需要的可以去掉