jzoj_3386_守卫者的挑战

Description

打开了黑魔法师Vani的大门，队员们在迷宫般的路上漫无目的地搜寻着关押applepi的监狱的所在地。突然，眼前一道亮光闪过。“我，Nizem，是黑魔法圣殿的守卫者。如果你能通过我的挑战，那么你可以带走黑魔法圣殿的地图……”瞬间，队员们被传送到了一个擂台上，最初身边有一个容量为K的包包。

擂台赛一共有N项挑战，各项挑战依次进行。第i项挑战有一个属性ai，如果ai>=0，表示这次挑战成功后可以再获得一个容量为ai的包包；如果ai=-1，则表示这次挑战成功后可以得到一个大小为1 的地图残片。地图残片必须装在包包里才能带出擂台，包包没有必要全部装满，但是队员们必须把 获得的所有的地图残片都带走（没有得到的不用考虑，只需要完成所有N项挑战后背包容量足够容纳地图残片即可），才能拼出完整的地图。并且他们至少要挑战成功L次才能离开擂台。

队员们一筹莫展之时，善良的守卫者Nizem帮忙预估出了每项挑战成功的概率，其中第i项挑战成功的概率为pi%。现在，请你帮忙预测一下，队员们能够带上他们获得的地图残片离开擂台的概率。

Input

第一行三个整数N,L,K。

第二行N个实数，第i个实数pi表示第i项挑战成功的百分比。

第三行N个整数，第i个整数ai表示第i项挑战的属性值.

Output

一个整数，表示所求概率，四舍五入保留6 位小数。

Solutions

用f[i][j][k]代表参加了i场挑战赢了j场时有k个空间的概率，最后累加一下

代码

var
  n,l,k:longint;
  v:array [0..201] of longint;
  a:array [0..201] of real;
  f:array [0..201,0..201,0..201] of real;
  ans:real;
procedure init;
var
  i:longint;
begin
  readln(n,l,k);
  for i:=1 to n do
    begin
      read(a[i]); a[i]:=a[i]/100;
    end;
  for i:=1 to n do
    read(v[i]);
end;

function min(o,p:longint):longint;
begin
  if o<p then exit(o);
  exit(p);
end;

procedure qsort(l,r:longint);
var
  i,j,mid,t:longint;
begin
  if l>r then exit;
  i:=l; j:=r;
  mid:=v[(l+r) div 2];
  repeat
    while v[i]>mid do inc(i);
    while v[j]<mid do dec(j);
    if i<=j then
      begin
        t:=v[i]; v[i]:=v[j]; v[j]:=t;
        a[0]:=a[i]; a[i]:=a[j]; a[j]:=a[0];
        inc(i); dec(j);
      end;
  until i>j;
  qsort(i,r);
  qsort(l,j);
end;

procedure main;
var
  i,j,kk,t:longint;
begin
  f[0,0,min(k,200)]:=1;
  for i:=0 to n-1 do
    for kk:=0 to i do
      for j:=0 to n do
        begin
          f[i+1,kk,j]:=f[i+1,kk,j]+f[i,kk,j]*(1-a[i+1]);
          t:=j+v[i+1];
          if t<0 then continue;
          t:=min(t,n);
          f[i+1,kk+1,t]:=f[i+1,kk+1,t]+f[i,kk,j]*a[i+1];
        end;
  ans:=0;
  for i:=0 to n do
    for j:=l to n do
      ans:=ans+f[n,j,i];
  write(ans:0:6);
end;

begin
  init;
  qsort(1,n);
  main;
end.