有关在Win32ASM中写不定参函数的一些研究

今天突然需要写一个不定参函数，而写了这么久的Win32ASM，还真没有确实实践过。以前见过的资料也不知道哪里找去。好吧。那就上网找。
网上的资料真是少。可怜见的，还是给我找着一篇。关键部分如下：

testproc proc C args:VARARG
 mov eax , [ esp+4 ]     ;  return address
 movzx ecx , byte ptr  [ eax+2 ]     ;  get the number of bytes out of the add esp instruction
 shr   eax , 2
 ret
testproc endp

一看之下，茅塞顿开，原来不知道怎么确定传递进来的参数个数。原来技巧就是这么简单。
原理：由于不定参函数是C调用形式的，需要调用者恢复堆栈，这样函数调用下一指令便是堆栈恢复。add esp,XXX。而这个XXX便是我们需要知道的参数个数啦。
当然，找到的这个资料用esp作为下一指令寻址定位不具有通用性，因为由于局部变量存在，在函数中我们无法确定esp的初始值。而用ebp也并不是很好。
于是我想作一些改进。
现在注意到参数列表：args。其实它就指向堆栈中第一个参数（C形式）的地址。而函数调用时参数进栈完毕后立即是下一指令地址进栈了。
嘿嘿，那就是说，我们所需要得到的“返回地址”便与args相差一个dword的距离。
这样，我们完全可以利用args来定位“返回地址”，进而确定参数个数了。实现如下：

ex proc C @args:VARARG
 LOCAL @argc
 pushad
 lea eax , @args
 mov eax , [ eax-4 ]   ; 返回地址
 movzx eax , byte ptr  [ eax+2 ]
 shr eax , 2   ; 参数个数
 mov @argc , eax
 invoke outint , eax
 mov eax , @args [ 4 ]   ; 参数2
 invoke outint , eax
 popad
 ret

ex endp

如果需要更多的参数，则需要注意定位的准确。

ex proc C @func , @args:VARARG
 LOCAL @argc
 LOCAL @count
 lea eax , @func
 mov eax , [ eax-4 ]   ; 返回地址
 movzx eax , byte ptr  [ eax+2 ]
 shr eax , 2   ; 参数个数
 cmp eax , 1
 jb @F
 mov @argc , eax
 sub eax , 2
 mov @count , eax
 invoke outint , @argc
 mov eax , @args [ 0 ]
 invoke outint , eax
 .while @count
  mov eax , @argc
  sub eax , @count
  dec eax  ; 因为前面有一个参数，所以这里需要注意修正。
  shl eax , 2
  mov eax , @args [ eax ]
  invoke outint , eax
  dec @count
 .endw
@@: ret
ex endp