[易语言]易语言实现数据结构中的括弧匹配算法

首先使用易语言的类模块实现关键的栈功能.

.版本 2

.程序集 栈
.程序集变量 成员_栈成员, 文本型, , "10"
.程序集变量 成员_栈顶指针, 整数型

.子程序 _初始化, , , 当基于本类的对象被创建后，此方法会被自动调用

成员_栈顶指针 ＝ 0


.子程序 入栈, 逻辑型, 公开
.参数 元素, 文本型

' //判断栈是否满
.如果真 (成员_栈顶指针 ＝ 10)
    返回 (假)
.如果真结束
成员_栈顶指针 ＝ 成员_栈顶指针 ＋ 1
成员_栈成员 [成员_栈顶指针] ＝ 元素
返回 (真)


.子程序 出栈, 逻辑型, 公开
.参数 元素, 文本型, 参考, 出栈的元素,注意此参数传入的是引用类型,不可为空

' //判断栈是否为空
.如果真 (成员_栈顶指针 ＝ 0)
    返回 (假)
.如果真结束
元素 ＝ 成员_栈成员 [成员_栈顶指针]
成员_栈顶指针 ＝ 成员_栈顶指针 － 1
返回 (真)

.子程序 是否为空, 逻辑型, 公开

返回 (成员_栈顶指针 ＝ 0)

.子程序 _销毁, , , 当基于本类的对象被销毁前，此方法会被自动调用

下面就是主程序集算法，这里创建的是控制台程序

.版本 2

.程序集 主程序集

.子程序 _启动子程序, 整数型, , 本子程序在程序启动后最先执行
.局部变量 多项式文本, 文本型

.判断循环首 (真)
    标准输出 (#标准输出设备, “请输入你要进行检查的多项式(禁止输入非数学符号):” ＋ #换行符)
    多项式文本 ＝ 标准输入 (真)
    .如果 (括号匹配 (多项式文本))
        标准输出 (#标准输出设备, “多项式没有残缺括号!” ＋ #换行符)
    .否则
        标准输出 (#标准输出设备, “多项式有残缺括号!” ＋ #换行符)
    .如果结束

.判断循环尾 ()
返回 (0)  ' 可以根据您的需要返回任意数值

.子程序 括号匹配, 逻辑型
.参数 多项式文本, 文本型, 参考
.局部变量 局部_计次, 整数型
.局部变量 栈对象, 栈
.局部变量 当前所处的文本, 文本型
.局部变量 栈顶元素, 文本型

输出调试文本 (多项式文本)
.计次循环首 (取文本长度 (多项式文本), 局部_计次)
    当前所处的文本 ＝ 取文本中间 (多项式文本, 局部_计次, 1)
    .如果 (当前所处的文本 ＝ “(” 或 当前所处的文本 ＝ “{” 或 当前所处的文本 ＝ “[”)
        栈对象.入栈 (当前所处的文本)
    .否则
        ' //不是左括号
        .如果 (当前所处的文本 ＝ “)”)
            栈顶元素 ＝ “”
            栈对象.出栈 (栈顶元素)
            .如果真 (栈顶元素 ≠ “(”)
                返回 (假)
            .如果真结束

        .否则
            .如果 (当前所处的文本 ＝ “]”)
                栈顶元素 ＝ “”
                栈对象.出栈 (栈顶元素)
                .如果真 (栈顶元素 ≠ “[”)
                    返回 (假)
                .如果真结束

            .否则
                .如果真 (当前所处的文本 ＝ “}”)
                    栈顶元素 ＝ “”
                    栈对象.出栈 (栈顶元素)
                    .如果真 (栈顶元素 ≠ “{”)
                        返回 (假)
                    .如果真结束

                .如果真结束

            .如果结束

        .如果结束

    .如果结束

.计次循环尾 ()
.如果真 (取反 (栈对象.是否为空 ()))
    返回 (假)
.如果真结束
返回 (真)