六、大数据之Hive-06

最新推荐文章于 2023-03-27 11:11:06 发布

不念人间朝暮

最新推荐文章于 2023-03-27 11:11:06 发布

阅读量250

点赞数

分类专栏： Hive 文章标签： hive sql 数据库大数据

本文链接：https://blog.csdn.net/qq18056047745/article/details/119807701

版权

Hive 专栏收录该内容

9 篇文章 0 订阅

订阅专栏

六、大数据之Hive-06

查询

查询语句语法：

[WITH CommonTableExpression (, CommonTableExpression)*] (Note: Only available
starting with Hive 0.13.0)
SELECT [ALL | DISTINCT] select_expr, select_expr, ...
FROM table_reference
[WHERE where_condition]
[GROUP BY col_list]
[ORDER BY col_list]
[CLUSTER BY col_list
| [DISTRIBUTE BY col_list] [SORT BY col_list]
]
[LIMIT number]

1、基本查询（Select…From）

1、全表和特定列查询

#创建部门表
create table if not exists dept(
deptno int,
dname string,
loc int
)
row format delimited fields terminated by '\t';

#创建员工表
create table if not exists emp(
empno int,
ename string,
job string,
mgr int,
hiredate string, 
sal double, 
comm double,
deptno int)
row format delimited fields terminated by '\t';

#导入数据
hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table
dept;
hive (default)> load data local inpath '/opt/module/datas/emp.txt' into table emp;

#全表查询
hive (default)> select * from emp;
#选择特定列查询
hive (default)> select empno, ename from emp;

注意：

（1）SQL 语言大小写不敏感。

（2）SQL 可以写在一行或者多行

（3）关键字不能被缩写也不能分行

（4）各子句一般要分行写。

（5）使用缩进提高语句的可读性。

2、列别名

（1）重名名一个列

（2）便于计算

（3）紧跟列名，也可以在列名和别名之间加入关键字’AS’

（4）案例

#查询名称和部门
hive (default)> select ename AS name, deptno dn from emp;

3、算数运算符

运算符	描述
A+B	A和B相加
A-B	A减去B
A*B	A和B相乘
A/B	A除以B
A%B	A对B取余
A&B	A和B按位取与
A\|B	A和B按位取或
A^B	A和B按位取异或
~A	A按位取反

#查询出所有员工的薪水后加 1 显示。
hive (default)> select sal +1 from emp;

4、常用函数

#求总行数（count）
hive (default)> select count(*) cnt from emp;
#求工资的最大值（max）
hive (default)> select max(sal) max_sal from emp;
#求工资的最小值（min）
hive (default)> select min(sal) min_sal from emp;
#求工资的总和（sum）
hive (default)> select sum(sal) sum_sal from emp;
#求工资的平均值（avg）
hive (default)> select avg(sal) avg_sal from emp;

5、Limit语句

#典型的查询会返回多行数据。LIMIT 子句用于限制返回的行数
hive (default)> select * from emp limit 5;

2、where语句

（1）使用WHERE子句，将不满足条件的行过滤掉

（2）WHERE子句紧随FROM子句

（3）案例

#查询出薪水大于 1000 的所有员工
hive (default)> select * from emp where sal >1000;
#where 子句中不能使用字段别名。

1、比较运算符（Between/In/Is Null）

（1）下面表中描述了谓词操作符，这些操作符同样可以用于 JOIN…ON 和 HAVING 语句中。

在这里插入图片描述

（2）案例

#查询出薪水等于 5000 的所有员工
hive (default)> select * from emp where sal =5000;

#查询工资在 500 到 1000 的员工信息
hive (default)> select * from emp where sal between 500 and 1000;

#查询 comm 为空的所有员工信息
hive (default)> select * from emp where comm is null;

#查询工资是 1500 或 5000 的员工信息
hive (default)> select * from emp where sal IN (1500, 5000);

2、Like和RLike

（1）使用LIKE运算选择类似的值

（2）选择条件可以包含字符或数字

% 代表零个或多个字符(任意个字符)。
_ 代表一个字符。

（3）RLIKE子句时Hive中这个功能的一个扩展，其可以通过Java的正则表达式这个更强大的语言来指定匹配条件。

（4）案例

#查找以 2 开头薪水的员工信息
hive (default)> select * from emp where sal LIKE '2%';

#查找第二个数值为 2 的薪水的员工信息
hive (default)> select * from emp where sal LIKE '_2%';

#查找薪水中含有 2 的员工信息
hive (default)> select * from emp where sal RLIKE '[2]';

3、逻辑运算符（AND/Or/Not）

操作符	含义
AND	逻辑并
OR	逻辑或
NOT	逻辑否

案例

#查询薪水大于 1000，部门是 30
hive (default)> select * from emp where sal>1000 and deptno=30;

#查询薪水大于 1000，或者部门是 30
hive (default)> select * from emp where sal>1000 or deptno=30;

#查询除了 20 部门和 30 部门以外的员工信息
hive (default)> select * from emp where deptno not IN(30, 20);

3、分组

1、Group By语句

GROUP BY 语句通常会和聚合函数一起使用，按照一个或者多个列队结果进行分组，然后对每个组执行聚合操作。

案例：

#计算 emp 表每个部门的平均工资
hive (default)> select t.deptno, avg(t.sal) avg_sal from emp t group by t.deptno;

#计算 emp 每个部门中每个岗位的最高薪水
hive (default)> select t.deptno, t.job, max(t.sal) max_sal from emp t group by t.deptno, t.job;

2、Having语句

（1）having与where不同点

a、where后面不能写分组函数，而having后面可以使用分组函数

c、having只用于group by分组统计语句

（2）案例

#求每个部门的平均薪水大于 2000 的部门

#先求求每个部门的平均工资
hive (default)> select deptno, avg(sal) from emp group by deptno;

#然后求每个部门的平均薪水大于 2000 的部门
hive (default)> select deptno, avg(sal) avg_sal from emp group by deptno having avg_sal > 2000;

4、Join语句

1、等值Join

Hive 支持通常的 SQL JOIN 语句，但是只支持等值连接，不支持非等值连接。

#根据员工表和部门表中的部门编号相等，查询员工编号、员工名称和部门名称；
hive (default)> select e.empno, e.ename, d.deptno, d.dname from emp e join dept 
d on e.deptno = d.deptno;

2、表的别名

（1）好处

a、使用别名可以简化查询

c、使用表名前缀可以提高执行效率

#合并员工表和部门表
hive (default)> select e.empno, e.ename, d.deptno from emp e join dept d on e.deptno= d.deptno;

3、内连接

#内连接：只有进行连接的两个表中都存在与连接条件相匹配的数据才会被保留下来。
hive (default)> select e.empno, e.ename, d.deptno from emp e join dept d on e.deptno= d.deptno;

4、左外连接

#左外连接：JOIN 操作符左边表中符合 WHERE 子句的所有记录将会被返回。
hive (default)> select e.empno, e.ename, d.deptno from emp e left join dept d on e.deptno = d.deptno;

5、右外连接

#右外连接：JOIN 操作符右边表中符合 WHERE 子句的所有记录将会被返回。
hive (default)> select e.empno, e.ename, d.deptno from emp e right join dept d on e.deptno = d.deptno;

6、满外连接

#满外连接：将会返回所有表中符合 WHERE 语句条件的所有记录。如果任一表的指定字段没有符合条件的值的话，那么就使用 NULL 值替代。
hive (default)> select e.empno, e.ename, d.deptno from emp e full join dept d on e.deptno= d.deptno;

7、多表连接

n个表，至少需要n-1个连接条件。

#1、创建位置表
create table if not exists location(
loc int,
loc_name string
)
row format delimited fields terminated by '\t';

#2、导入数据
hive (default)> load data local inpath '/opt/module/datas/location.txt' into table 
location;

#3、多表连接查询
hive (default)>SELECT e.ename, d.dname, l.loc_name
FROM emp e 
JOIN dept d
ON d.deptno = e.deptno 
JOIN location l
ON d.loc = l.loc;

大多数情况下，Hive 会对每对 JOIN 连接对象启动一个 MapReduce 任务。本例中会首先启动一个 MapReduce job 对表 e 和表 d 进行连接操作，然后会再启动一个 MapReduce job将第一个 MapReduce job 的输出和表 l 进行连接操作。

**优化：**当对 3 个或者更多表进行 join 连接时，如果每个 on 子句都使用相同的连接键的话，那么只会产生一个 MapReduce job。

8、笛卡尔积

1、笛卡尔积的产生

（1）省略连接条件

（2）连接条件无效

（3）所有表中的所有行相互连接

#举例
hive (default)> select empno, dname from emp, dept;

9、连接谓词中不支持or

#hive join 目前不支持在 on 子句中使用谓词 or
hive (default)> select e.empno, e.ename, d.deptno from emp e join dept d on e.deptno
= d.deptno or e.ename=d.ename; #错误的

5、排序

1、全局排序（Order By）

Order By：全局排序，只有一个reducer

（1）使用ORDER BY 子句排序

ASC（ascend）：升序（默认）

DESC（descend）：降序

（2）ORDER BY 子句在SELECT语句的结尾

#查询员工信息按工资升序排列
hive (default)> select * from emp order by sal;

#查询员工信息按工资降序排列
hive (default)> select * from emp order by sal desc;

2、按照别名排序

#按照员工薪水的 2 倍排序
hive (default)> select ename, sal*2 twosal from emp order by twosal;

3、多个列排序

#按照部门和工资升序排序
hive (default)> select ename, deptno, sal from emp order by deptno, sal ;

4、每个Map Reduce内部排序（Sort By）

Sort By：对于大规模的数据集 order by 的效率非常低。在很多情况下，并不需要全局排序，此时可以使用 sort by。

Sort by 为每个 reducer 产生一个排序文件。每个 Reducer 内部进行排序，对全局结果集来说不是排序。

#1、设置reduce个数
hive (default)> set mapreduce.job.reduces=3;

#2、查看设置 reduce 个数
hive (default)> set mapreduce.job.reduces;

#3、根据部门编号降序查看员工信息
hive (default)> select * from emp sort by deptno desc;

#4、将查询结果导入到文件中（按照部门编号降序排序）
hive (default)> insert overwrite local directory '/opt/module/datas/sortbyresult'
select * from emp sort by deptno desc;

5、分区排序（Distribute By）

Distribute By：在有些情况下，我们需要控制某个特定行应该到哪个 reducer，通常是为了进行后续的聚集操作。distribute by 子句可以做这件事。distribute by 类似 MR 中 partition（自定义分区），进行分区，结合 sort by 使用。对于 distribute by 进行测试，一定要分配多 reduce 进行处理，否则无法看到 distribute by的效果。

#先按照部门编号分区，再按照员工编号降序排序。
hive (default)> set mapreduce.job.reduces=3;
hive (default)> insert overwrite local directory '/opt/module/datas/distributeresult' select * from emp distribute by deptno sort by empno desc;

注意：

1、distribute by 的分区规则是根据分区字段的hash码与reduce的个数进行模除后，余数相同的分到一个区。

2、Hive要求DISTRIBUTE BY 语句要写在SORT BY语句之前。

6、Cluster By

当 distribute by 和 sorts by 字段相同时，可以使用 cluster by 方式。

cluster by 除了具有 distribute by 的功能外还兼具 sort by 的功能。但是排序只能是升序排序，不能指定排序规则为 ASC 或者 DESC。

#以下两种写法等价
hive (default)> select * from emp cluster by deptno;
hive (default)> select * from emp distribute by deptno sort by deptno;

注意：按照部门编号分区，不一定就是固定死的数值，可以是 20 号和 30 号部门分到一个分区里面去。

6、分桶及抽样查询

1、分桶表数据存储

分区提供一个隔离数据和优化查询的便利方式。不过，并非所有的数据集都可形成合理的分区。对于一张表或者分区，Hive 可以进一步组织成桶，也就是更为细粒度的数据范围划分。

分桶是将数据集分解成更容易管理的若干部分的另一个技术。

分区针对的是数据的存储路径；分桶针对的是数据文件。

（1）先创建分桶表，通过直接导入数据文件的方式

#创建分桶表
create table stu_buck(id int, name string)
clustered by(id) 
into 4 buckets
row format delimited fields terminated by '\t';

#查看表结构
hive (default)> desc formatted stu_buck;
Num Buckets:

#导入数据到分桶表中
hive (default)> load data local inpath '/opt/module/datas/student.txt' into table stu_buck;

（2）创建分桶表时，数据通过子查询的方式导入

#1、先建一个普通的 stu 表
create table stu(id int, name string)
row format delimited fields terminated by '\t';

#2、向普通的 stu 表中导入数据
load data local inpath '/opt/module/datas/student.txt' into table stu;

#3、清空 stu_buck 表中数据
truncate table stu_buck;
select * from stu_buck;

注意：发现在HDFS上时只有一个桶，原因是未进行属性的设置

#设置属性
hive (default)> set hive.enforce.bucketing=true;
hive (default)> set mapreduce.job.reduces=-1;
hive (default)> insert into table stu_buck
select id, name from stu;

这时：可以发现有了分桶。

#查询分桶的数据
hive (default)> select * from stu_buck;
OK
stu_buck.id stu_buck.name
1004 ss4
1008 ss8
1012 ss12
1016 ss16
1001 ss1
1005 ss5
1009 ss9
1013 ss13
1002 ss2
1006 ss6
1010 ss10
1014 ss14
1003 ss3
1007 ss7
1011 ss11
1015 ss15

分桶规则：

根据结果可知：Hive 的分桶采用对分桶字段的值进行哈希，然后除以桶的个数求

余的方式决定该条记录存放在哪个桶当中。

2、分桶抽样查询

对于非常大的数据集，有时用户需要使用的是一个具有代表性的查询结果而不是全部结果。Hive 可以通过对表进行抽样来满足这个需求。

#查询表 stu_buck 中的数据
hive (default)> select * from stu_buck tablesample(bucket 1 out of 4 on id);

注意：tablesample 是抽样语句，语法：TABLESAMPLE(BUCKET x OUT OF y) 。

y 必须是 table 总 bucket 数的倍数或者因子。hive 根据 y 的大小，决定抽样的比例。例

如，table 总共分了 4 份，当 y=2 时，抽取(4/2=)2 个 bucket 的数据，当 y=8 时，抽取(4/8=)1/2个 bucket 的数据。

x 表示从哪个 bucket 开始抽取，如果需要取多个分区，以后的分区号为当前分区号加上y。例如，table 总 bucket 数为 4，tablesample(bucket 1 out of 2)，表示总共抽取

（4/2=）2 个bucket 的数据，抽取第 1(x)个和第 3(x+y)个 bucket 的数据。注意：x 的值

必须小于等于 y 的值，否则FAILED: SemanticException [Error 10061]: Numerator

should not be bigger than denominatorn sample clause for table stu_buck

7、其他常用查询函数

1、空子段赋值

（1）函数说明

NVL：给值为 NULL 的数据赋值，它的格式是 NVL( value，default_value)。它的功能是如果 value 为 NULL，则 NVL 函数返回 default_value 的值，否则返回 value 的值，如果两个参数都为 NULL ，则返回 NULL。

（2）数据准备：采用员工表

（3）查询：如果员工的comm为NULL，则用-1代替

hive (default)> select comm,nvl(comm, -1) from emp;
OK
comm _c1
NULL -1.0
300.0 300.0
500.0 500.0
NULL -1.0
1400.0 1400.0
NULL -1.0
NULL -1.0
NULL -1.0
NULL -1.0
0.0 0.0
NULL -1.0
NULL -1.0
NULL -1.0
NULL -1.0

（4）查询：如果员工的comm为NULL，则用领导id代替

hive (default)> select comm, nvl(comm,mgr) from emp;
OK
comm _c1
NULL 7902.0
300.0 300.0
500.0 500.0
NULL 7839.0
1400.0 1400.0
NULL 7839.0
NULL 7839.0
NULL 7566.0
NULL NULL
0.0 0.0
NULL 7788.0
NULL 7698.0
NULL 7566.0
NULL 7782.0

2、CASE WHEN

（1）数据准备

在这里插入图片描述

（2）需求

求出不同部门男女个多少人。如下示

A 2 1
B 1 2

#3、创建本地 emp_sex.txt，导入数据
[lyinl@hadoop102 datas]$ vi emp_sex.txt
悟空 A 男
大海 A 男
宋宋 B 男
凤姐 A 女
婷姐 B 女
婷婷 B 女

#4、创建 hive 表并导入数据
create table emp_sex(
name string, 
dept_id string, 
sex string) 
row format delimited fields terminated by "\t";
load data local inpath '/opt/module/datas/emp_sex.txt' into table emp_sex;

#5、按需求查询数据
select 
 dept_id,
 sum(case sex when '男' then 1 else 0 end) male_count,
 sum(case sex when '女' then 1 else 0 end) female_count
from emp_sex
group by dept_id;

3、行转列

（1）相关函数说明

CONCAT(string A/col, string B/col…)：返回输入字符串连接后的结果，支持任意个

输入字符串;

CONCAT_WS(separator, str1, str2,…)：它是一个特殊形式的 CONCAT()。第一个参

数剩余参数间的分隔符。分隔符可以是与剩余参数一样的字符串。如果分隔符是 NULL，

返回值也将为 NULL。这个函数会跳过分隔符参数后的任何 NULL 和空字符串。分隔符

将被加到被连接的字符串之间;

COLLECT_SET(col)：函数只接受基本数据类型，它的主要作用是将某字段的值进行

去重汇总，产生 array 类型字段。

（2）数据准备

在这里插入图片描述

（3）需求

把星座和血型一样的人归类到一起。如下示：

射手座,A 大海|凤姐
白羊座,A 孙悟空|猪八戒
白羊座,B 宋宋

#创建本地 constellation.txt，导入数据
[lyinl@hadoop102 datas]$ vi constellation.txt
孙悟空 白羊座 A
大海 射手座 A
宋宋 白羊座 B
猪八戒 白羊座 A
凤姐 射手座 A

#创建 hive 表并导入数据
create table person_info(
name string, 
constellation string, 
blood_type string) 
row format delimited fields terminated by "\t";
load data local inpath "/opt/module/datas/constellation.txt" into table person_info;

#按需求查询数据
select
 t1.base,
 concat_ws('|', collect_set(t1.name)) name
from
 (select
 name,
 concat(constellation, ",", blood_type) base
 from
 person_info) t1
group by t1.base;

4、列转行

（1）函数说明

EXPLODE(col)：将 hive 一列中复杂的 array 或者 map 结构拆分成多行。LATERAL VIEW

用法：LATERAL VIEW udtf(expression) tableAlias AS columnAlias

解释：用于和 split, explode 等 UDTF 一起使用，它能够将一列数据拆成多行数据，在此基础上可以对拆分后的数据进行聚合。

（2）数据准备

在这里插入图片描述

（3）需求

将电影分类中的数据展开，如下：

《疑犯追踪》 悬疑
《疑犯追踪》 动作
《疑犯追踪》 科幻
《疑犯追踪》 剧情
《Lie to me》 悬疑
《Lie to me》 警匪
《Lie to me》 动作
《Lie to me》 心理
《Lie to me》 剧情
《战狼 2》 战争
《战狼 2》 动作
《战狼 2》 灾难

#创建本地 movie.txt，导入数据
[lyinl@hadoop102 datas]$ vi movie.txt
《疑犯追踪》 悬疑,动作,科幻,剧情
《Lie to me》 悬疑,警匪,动作,心理,剧情
《战狼 2》 战争,动作,灾难

#创建 hive 表并导入数据
create table movie_info(
 movie string, 
 category array<string>) 
row format delimited fields terminated by "\t"
collection items terminated by ",";
load data local inpath "/opt/module/datas/movie.txt" into table movie_info;

#按需求查询数据
select
 movie,
 category_name
from 
 movie_info lateral view explode(category) table_tmp as category_name;

4、窗口函数（开窗函数）

（1）相关函数说明

OVER()：指定分析函数工作的数据窗口大小，这个数据窗口大小可能会随着行的变而变化。

CURRENT ROW：当前行

n PRECEDING：往前 n 行数据

n FOLLOWING：往后 n 行数据

UNBOUNDED：起点，UNBOUNDED PRECEDING 表示从前面的起点，

UNBOUNDED

FOLLOWING 表示到后面的终点

LAG(col,n,default_val)：往前第 n 行数据

LEAD(col,n, default_val)：往后第 n 行数据

NTILE(n)：把有序分区中的行分发到指定数据的组中，各个组有编号，编号从 1 开始，对于每一行，NTILE 返回此行所属的组的编号。注意：n 必须为 int 类型。

（2）数据准备：name，orderdate，cost

jack,2021-01-01,10
tony,2021-01-02,15
jack,2021-02-03,23
tony,2021-01-04,29
jack,2021-01-05,46
jack,2021-04-06,42
tony,2021-01-07,50
jack,2021-01-08,55
mart,2021-04-08,62
mart,2021-04-09,68
neil,2021-05-10,12
mart,2021-04-11,75
neil,2021-06-12,80
mart,2021-04-13,94

（3）需求

#1、查询在 2021 年 4 月份购买过的顾客及总人数
#2、查询顾客的购买明细及月购买总额
#3、上述的场景,要将 cost 按照日期进行累加
#4、查询每个顾客上次的购买时间
#5、查询前 20%时间的订单信息

#创建本地 business.txt，导入数据
[lyinl@hadoop102 datas]$ vi business.txt

#创建 hive 表并导入数据
create table business(
name string, 
orderdate string,
cost int
) ROW FORMAT DELIMITED FIELDS TERMINATED BY ',';
load data local inpath "/opt/module/datas/business.txt" into table business;

（4）按需求查询数据

#查询在 2021 年 4 月份购买过的顾客及总人数
select name,count(*) over () 
from business
where substring(orderdate,1,7) = '2021-04' 
group by name;

#查询顾客的购买明细及月购买总额
select name,orderdate,cost,sum(cost) over(partition by month(orderdate)) from business;

#上述的场景, 将每个顾客的 cost 按照日期进行累加
select name,orderdate,cost, 
sum(cost) over() as sample1,--所有行相加
sum(cost) over(partition by name) as sample2,-- 按 name 分组，组内数据相加
sum(cost) over(partition by name order by orderdate) as sample3,
-- 按 name 分组，组内数据累加
sum(cost) over(partition by name order by orderdate rows between UNBOUNDED PRECEDING 
and current row ) as sample4 ,-- 和 sample3 一样,由起点到当前行的聚合
sum(cost) over(partition by name order by orderdate rows between 1 PRECEDING and 
current row) as sample5, -- 当前行和前面一行做聚合
sum(cost) over(partition by name order by orderdate rows between 1 PRECEDING AND 1 
FOLLOWING ) as sample6,-- 当前行和前边一行及后面一行
sum(cost) over(partition by name order by orderdate rows between current row and 
UNBOUNDED FOLLOWING ) as sample7 -- 当前行及后面所有行
from business;

注意：rows 必须跟在 Order by 子句之后，对排序的结果进行限制，使用固定的行数来限制分区中的数据行数量

#查看顾客上次的购买时间
select name,orderdate,cost, 
lag(orderdate,1,'1900-01-01') over(partition by name order by orderdate ) as time1, 
lag(orderdate,2) over (partition by name order by orderdate) as time2 
from business;

#查询前 20%时间的订单信息
select * from (
 select name,orderdate,cost, ntile(5) over(order by orderdate) sorted
  from business
) t
where sorted = 1;

5、Rank

1、函数说明

RANK() 排序相同时会重复，总数不会变

DENSE_RANK() 排序相同时会重复，总数会减少

ROW_NUMBER() 会根据顺序计算

2、数据准备

在这里插入图片描述

3、需求

计算每门学科成绩排名

#4、创建本地 score.txt，导入数据
[lyinl@hadoop102 datas]$ vi score.txt

#5、创建 hive 表并导入数据
create table score(
name string,
subject string, 
score int) 
row format delimited fields terminated by "\t";
load data local inpath '/opt/module/datas/score.txt' into table score;

#6、按需求查询数据
select name,subject,score,
rank() over(partition by subject order by score desc) rp,
dense_rank() over(partition by subject order by score desc) drp,
row_number() over(partition by subject order by score desc) rmp
from score;
name subject score rp drp rmp
孙悟空 数学 95 1 1 1
宋宋 数学 86 2 2 2
婷婷 数学 85 3 3 3
大海 数学 56 4 4 4
宋宋 英语 84 1 1 1
大海 英语 84 1 1 2
婷婷 英语 78 3 2 3
孙悟空 英语 68 4 3 4
大海 语文 94 1 1 1
孙悟空 语文 87 2 2 2
婷婷 语文 65 3 3 3
宋宋 语文 64 4 4 4

不念人间朝暮

关注

0
点赞
踩
1

收藏

觉得还不错? 一键收藏
0
评论
六、大数据之Hive-06

六、大数据之Hive-06查询查询语句语法：[WITH CommonTableExpression (, CommonTableExpression)*] (Note: Only availablestarting with Hive 0.13.0)SELECT [ALL | DISTINCT] select_expr, select_expr, ...FROM table_reference[WHERE where_condition][GROUP BY col_list][ORD
复制链接

扫一扫