aosp中app源码使用as打开的项目配置

本文所使用Android Studio版本：Android Studio Giraffe | 2022.3.1 Patch 1
测试项目为YY3568安卓开发板，其中android11源码路径为：YY3568-Android11\packages\apps\Browser2

1、新建settings.gradle文件，内容如下：

pluginManagement {
    repositories {
        google()
        mavenCentral()
        gradlePluginPortal()
    }
}
dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        google()
        mavenCentral()
    }
}

2、新建build.gradle文件，内容如下：

plugins {
    id 'com.android.application' version '8.1.1' apply true
}
android {
    signingConfigs {
        platform {
            storeFile file('platform.keystore')
            storePassword 'android'
            keyAlias 'platform'
            keyPassword 'android'
        }
    }
    namespace "org.chromium.webview_shell"
    compileSdk 30
    defaultConfig {
        applicationId "org.chromium.webview_shell"
        minSdk 19
        targetSdk 28
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            signingConfig signingConfigs.platform
        }
        debug {
            signingConfig signingConfigs.platform
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            java.srcDirs = ['src']
            res.srcDirs = ['res']
        }
    }
}
dependencies {
    implementation 'androidx.appcompat:appcompat:1.0.0'
    implementation 'com.google.android.material:material:1.0.0'
    implementation 'androidx.constraintlayout:constraintlayout:2.0.0'
    testImplementation 'junit:junit:4.13.2'
    androidTestImplementation 'androidx.test.ext:junit:1.0.0'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.5.1'
}

3、将AndroidManifest.xml中的package、versionCode、versionName、minSdkVersion、targetSdkVersion填写到build.gradle中

4、新建gradle.properties文件，内容如下：

org.gradle.jvmargs=-Xmx2048m -Dfile.encoding=UTF-8
android.useAndroidX=true
android.nonTransitiveRClass=true

5、用Android Studio打开项目，同时项目会报错，解决方法：在Android Studio中File > Project Structure > Gralde Version中将默认的7.5.1版本切换为8.0，然后点击Apply，然后点击Ok

文章所有文件集合：https://gitee.com/liyiwei1032/aosp_app_gradle_init.git

如果你觉得这篇文章帮助到了你，欢迎打赏