若列表内包含重复出现的元素,则应只保留一个副本,且保持原列表元素的顺序。如
sash> (compress '(a a a a b c c a a d e e e e))
sash> (a b c a d e)
问题分析
使用递归解决问题的好处在于能全局分析问题,从“局部“解决一个全局的问题。使用递归解决的问题的关键在于能找到相似的子问题。子问题与原问题具有相同的流程,但问题空间应越来越小,直至达到边界条件。
在该问题中,可以抽象出具有相同的操作流程【这个过程类似于提取公因式,确定哪个流程是共有的】:取当前元素,如果一个元素与之相同,则舍弃当前元素,继续子列表;如果不同,则保留当前元素,继续子列表。那么下一步就是确定递归的边界。
从上面的问题,我们可以得到两个边界情况:
- 列表为空,则结果为
'()
; - 列表包含一个元素,如
'(a)
,则结果为原列表'(a)
;
结合刚才得到的递归过程,我们总是拿当前元素和下一元素进行比较,在到达列表的末端时,不会遇到第一种情况。第二种情况才是我们需要的边界,即当前元素a
是最后一个元素,这时直接返回'(a)
。第一种情况是特殊的边界,可认为是递归的干扰情况,应先排除。
有了思路,给出三种解法:
Pure Version
(define compress
(lambda (ls)
(if (null? ls)
'()
(let f ([h (car ls)] [t (cdr ls)])
(if (null? t) (cons h '()) (let ([th (car t)] [tt (cdr t)]) (if (equal? h th) (f th tt) (cons h (f th tt)))))))))
Mutation Version
(define compress!
(lambda (ls)
(if (null? ls)
ls
(let f ([ls ls] [h (car ls)] [t (cdr ls)])
(unless (null? t) (let ([th (car t)] [tt (cdr t)]) (if (equal? h th) (begin (set-cdr! ls tt) (f ls h (cdr ls))) (f t (car t) (cdr t)))))))))
Reduce Version
(define compress
(lambda (ls)
(fold-right (lambda (e a)
(cond [(null? a) (cons e a)] [(equal? e (car a)) a] [else (cons e a)]))
'()
ls)))
从上面解法中,可以看到第三种最为简单,是因为Reduce已经帮我们实现统一的递归流程,我们只要确定当前元素和accumulator项之间的关系就可以了。而方法(1)则需要考虑当前问题和子问题的关系,问题的复杂度不言而喻。很多编程语言的标准库都引入了这种函数式的操作,比如C++的std::accumulate
,Python的functools.reduce
。
提reduce
有点多了,下次一带而过。