学了一段时间汇编,想搞点事情来玩玩,于是整出一个冒泡排序的小程序。
程序功能:
将给定字节数组中的元素排序,并将结果输出到DOS。
功能拆分:
1、排序
最简单最容易想的就是冒泡排序,只有两重循环,而且里外关系明确,所以我们就选它了。
2、输出
DOS有很多中断子程序,其中21号中断的编号为9的功能就可以打印字符串到DOS。
3、转换
排序和输出解决了,中间还有一个很重要的过程:将数字转成字符串。这个需要我们自己手写,原理也很简单,循环对10取余就可以了。
功能实现:
1、冒泡排序
首先我们在数据段申请一块区域存放数组和元素个数:
DATA SEGMENT
BUF DB 12, 32, -2, 4, 0 ; NUMBER ARRAY BUFFER
CNT DB $-BUF ; COUNT FOR BUFFER
DATA ENDS
过程和冒泡排序一样,在内层循环比较内外层的两个数,我们把外层循环的数组下标放在 SI
中,内层的下标放在 DI
中。显然有 DI = SI + 1
每次循环的操作如下:
AX = DS[SI]
DX = DS[DI]
IF (AX > DX):
SWAP (AX, DX)
DS[SI] = AX
DS[DI] = DX
完整的代码如下:
ASSUME CS:CODE,DS:DATA
DATA SEGMENT
BUF DB 12, 32, -2, 4, 0 ; NUMBER ARRAY BUFFER
CNT DB $-BUF ; COUNT FOR BUFFER
DATA ENDS
CODE SEGMENT
START: MOV AX, DATA
MOV DS, AX ; DATA SEGMENT
MOV SI, OFFSET BUF ; BUFFER INDEX
MOV CL, CNT ; LOOP COUNT
DEC CL
MOV CH, 0
OUTER: ; OUTER LOOP
MOV AL, [SI] ; BUF[SI]
PUSH CX
MOV DI, SI ; BUFFER INDEX
INNER: ; INNER LOOP
INC DI ; DI = SI + 1
MOV DL, [DI] ; BUF[DI]
CMP AL, DL ; IF (BUF[SI] > BUF[DI])
JLE CONT ;
XCHG AX, DX ; SWAP (BUF[SI], BUF[DI])
MOV [SI], AL
MOV [DI], DL
CONT: LOOP INNER ; CONTINUE
POP CX
INC SI
LOOP OUTER
MOV AH, 4CH
INT 21H
CODE ENDS
END START
我们在 DOSBOX 中测试:
可以看到排序前后的结果在内存中。
2、打印字符串
这个很简单,之前说过,调用 DOS 中断子程序就可以了:
字符串偏移地址保存在 DX
中,字符串以 ‘$’ 结尾
DATA SEGMENT
BUF DB 'WELCOME TO THE DOS!', 13, 10, '$'
DATA ENDS
CODE SEGMENT
ASSUME CS:CODE,DS:DATA
START: MOV AX, DATA
MOV DS, AX
MOV AH, 09H
MOV DX, OFFSET BUF
INT 21H
MOV AH, 4CH
INT 21H
CODE ENDS
END START
运行截图:
注意这里有一个换行(0x0d 0x0a)。
3、整数转为字符串
待转化的整数存放在AX
中,字符串存放在DS[DI]
中。
首先AX
对 10 取余,入栈。
然后出栈,转移到BUF
中。
这里要注意如果是负数,必须给出判断条件,并将缓冲区第一个位置设置’-‘。
完整代码如下:
DATA SEGMENT
BUF DB 16 DUP(0), 13, 10, '$'
DATA ENDS
CODE SEGMENT
ASSUME CS:CODE,DS:DATA
START: MOV AX, DATA
MOV DS, AX
MOV DI, OFFSET BUF
XOR AX, AX
MOV AL, -23
MOV BX, 10
MOV CX, 0
CMP AX, 127
JLE MODLP
NEG AL
MOV BYTE PTR [DI], '-'
INC DI
MODLP: XOR DX, DX
DIV BX
ADD DX, 30H
PUSH DX
INC CX
CMP AX, 0
JG MODLP
STOLP: POP DX
MOV [DI], DL
INC DI
LOOP STOLP
MOV DX, OFFSET BUF
MOV AH, 09H
INT 21H
MOV AH, 4CH
INT 21H
CODE ENDS
END START
运行截图:
负数可以正常显示,这里我们利用到上面的字符串输出函数。
函数封装:
我们实现了每个子程序,下面就要将他们合并,我们可以把每个子程序的核心功能部分提取成函数,然后利用这些函数完成数组的排序及输出:
完整代码:
; BUBBLESORT BY WUST_HMK
; 2016-04-16
ASSUME CS:CODE,DS:DATA
DATA SEGMENT
BUF DB 16 DUP(0), 13, 10, '$' ; BUFFER TO STORE STRING
LOL DB 'WELCOME TO THE BUBBLESORT PROGRAM!', 13, 10, '$'
STR1 DB 'BEFORE SORT:', 13, 10, '$'
STR2 DB 'AFTER SORT:', 13, 10, '$'
ARR DB 12, -34, -2, 4, 0 ; NUMBER ARRAY BUFFER, CHANGE IT!!!
CNT DB $-ARR ; COUNT FOR BUFFER
DATA ENDS
CODE SEGMENT
START: MOV AX, DATA
MOV DS, AX ; DATA SEGMENT
MOV SI, OFFSET ARR ; ARRAY INDEX
MOV DI, OFFSET BUF ; BUFFER INDEX
MOV CL, CNT ; ELEMENTS COUNT
MOV CH, 0
MOV DX, OFFSET LOL ; PRINT WELCOME
MOV AH, 09H
INT 21H
MOV DX, OFFSET STR1 ; BEFORE SORT
MOV AH, 09H
INT 21H
MOV SI, OFFSET ARR ; ARRAY INDEX
MOV DI, OFFSET BUF ; BUFFER INDEX
MOV CL, CNT ; ELEMENTS COUNT
MOV CH, 0
CALL PRINTARR ; PRINT ARRAY
MOV SI, OFFSET ARR ; ARRAY INDEX
MOV DI, OFFSET BUF ; BUFFER INDEX
MOV CL, CNT ; ELEMENTS COUNT
MOV CH, 0
CALL BUBBLESORT ; BUBBLE SORT
MOV DX, OFFSET STR2 ; AFTER SORT
MOV AH, 09H
INT 21H
MOV SI, OFFSET ARR ; ARRAY INDEX
MOV DI, OFFSET BUF ; BUFFER INDEX
MOV CL, CNT ; ELEMENTS COUNT
MOV CH, 0
CALL PRINTARR ; PRINT ARRAY
MOV AH, 4CH
INT 21H ; RETURN TO DOS
;
; FUNCTION NAME: BUBBLESORT
; PARAMETERS: DS: BASE OF BUFFER
; SI: OFFSET
; CX: NUMBERS COUNT - 1
;
BUBBLESORT PROC NEAR
PUSH AX
PUSH BX
PUSH CX
PUSH DX
PUSH SI
PUSH DI
DEC CX ; LOOP COUNT = ELEMENTS COUNT - 1
OUTER: ; OUTER LOOP
MOV AL, [SI] ; BUF[SI]
PUSH CX
MOV DI, SI ; BUFFER INDEX
INNER: ; INNER LOOP
INC DI ; DI = SI + 1
MOV DL, [DI] ; BUF[DI]
CMP AL, DL ; IF (BUF[SI] > BUF[DI])
JLE CONT ;
XCHG AX, DX ; SWAP (BUF[SI], BUF[DI])
MOV [SI], AL
MOV [DI], DL
CONT: LOOP INNER ; CONTINUE
POP CX
INC SI
LOOP OUTER
POP DI
POP SI
POP DX
POP CX
POP BX
POP AX
RET
BUBBLESORT ENDP
;
; FUNCTION NAME: PRINTARR
; ARRAY IN DS[SI], BUFFER IN DS[DI], COUNT CX
PRINTARR PROC NEAR
PUSH SI
PUSH DI
MOV DX, DI
ITERAT: MOV AL, [SI] ; AL = DS[SI]
MOV AH, 0
INC SI
CALL NTOC ; CONVERT AX TO STRING
MOV AH, 09H
INT 21H ; PRINT STRING TO DOS
CALL CLRBUF ; CLEAR STRING BUFFER
LOOP ITERAT
POP DI
POP SI
RET
PRINTARR ENDP
; CONVERT NUMBER TO STRING
; AX TO DS[DI]
NTOC PROC NEAR
PUSH BX
PUSH CX
PUSH DX
PUSH DI
MOV BX, 10 ; DECIMAL BASE
MOV CX, 0
CMP AX, 127 ; IF AX > 127 THEN AX = -AX
JLE MODLP
NEG AL
MOV BYTE PTR [DI], '-' ; NEGTIVE NUMBER SIGN
INC DI
MODLP: XOR DX, DX
DIV BX ; AX = AX / BX; DX = AX % BX
ADD DX, 30H ; DX += 30H, CONVERT DX TO ASCII
PUSH DX
INC CX
CMP AX, 0
JG MODLP
MOV AX, CX ; RETURN AX: LENGTH OF NUMBER
STOLP: POP DX
MOV [DI], DL ; SAVE NUMBER TO STRING BUFFER
INC DI
LOOP STOLP
POP DI
POP DX
POP CX
POP BX
RET
NTOC ENDP
; CLEAR DS[DI], COUNT FOR CX (RESERVED)
CLRBUF PROC NEAR
PUSH CX
PUSH DI
MOV CX, 16 ; BUFFER LENGTH
BUFCLS: MOV BYTE PTR [DI], 0
INC DI
LOOP BUFCLS
POP DI
POP CX
RET
CLRBUF ENDP
CODE ENDS
END START
程序有点乱,将就着看看吧。
执行结果:
还是可以的。
总结体会:
第一次独立写一个完整的汇编小程序,期间遇到了很多问题, 有时候程序逻辑没问题,在DOSBOX debug 下可以跑,但是直接运行就挂。然后改了若干遍才发现汇编也会出现变量初始化的问题。
另外汇编程序设计的规范我并不熟悉,所以寄存器的使用很杂乱,还望各位指正。