计算机系统1 实验 LC-3 Nim游戏 子程序

最新推荐文章于 2022-08-17 18:18:26 发布
最新推荐文章于 2022-08-17 18:18:26 发布
阅读量403 收藏 5
点赞数 5
分类专栏： 计算机系统1 文章标签： 青少年编程 学习 游戏
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/qq_25851273/article/details/124892379
版权

写在前面

今天找时间把LC-3的Nim游戏（实验四、五）给做了，浅浅地分享一下吧。

一个目录

一、游戏背景和规则

背景：Nim是一个简单的双人游戏，可能起源于中国。游戏中使用的计数器类型有很多种类，如石头、火柴、苹果等。游戏界面被划分为很多行，每行中有数量不等的计数器，如表所示：

行号计数器数量
1○○○
2○○○○○○
······
n○○○○○○○○○

本次实验对Nim游戏做了一些小的改变，具体如下：
游戏界面由三行组成，计数器类型为石头，其中A行包含3个石头，B行包含5个石头，C行包含8个石头。
规则如下：
⑴ 每个玩家轮流从某一行中移除一个或多个石头。
⑵ 一个玩家不能在一个回合中从多个行中移除石头。
⑶ 当某个玩家从游戏界面上移除最后剩余的石头时，此时游戏结束，该玩家获胜。

二、实验要求

⑴ 在游戏开始时，你应该显示游戏界面的初始化状态。具体包括：在每行石头的前面，你应该先输出行的名称，例如“ROW A”。你应该使用ASCII字符小写字母“o”（ASCII码 x006F）来表示石头。游戏界面的初始化状态应该如下：

ROW A: ooo
ROW B: ooooo
ROW C: oooooooo

⑵ 游戏总是从玩家1先开始，之后玩家1和玩家2轮流进行。在每一个回合开始时，你应该输出轮到哪一个玩家开始，并提示玩家进行操作。例如，对于玩家1，应该有如下显示：

Player 1,choose a row and number of rocks:

⑶ 为了指定要移除哪一行中的多少石头，玩家应该输入一个字母后跟一个数字（输入结束后不需要按Enter键），其中字母（A,B或C）指定行，数字（从1到所选行中石头的数量）指定要移除的石头的数量。你的程序必须要确保玩家从有效的行中移除有效数量的石头，如果玩家输入无效，你应该输出错误提示信息并提示该玩家再次进行输入。例如，如果轮到玩家1：

Player 1, choose a row and number of rocks: D4
Invalid move. Try again.
Player 1, choose a row and number of rocks: A9
Invalid move. Try again.
Player 1, choose a row and number of rocks: A*
Invalid move. Try again.
Player 1, choose a row and number of rocks: &4
Invalid move. Try again.
Player 1, choose a row and number of rocks:

你的程序应保持提示玩家，直到玩家选择有效的输入为止。确保你的程序能够回显玩家的输入到屏幕上，当回显玩家的输入后，此时应该输出一个换行符（ASCII码x000A）使光标指向下一行。
⑷ 玩家选择有效的输入后，你应该检查获胜者。如果有一个玩家获胜，你应该显示相应的输出来表明该玩家获胜。如果没有胜利者，你的程序应该更新游戏界面中每行石头的数量，重新显示更新的游戏界面，并轮到下一个玩家继续。
⑸ 当某个玩家从游戏界面上移除最后的石头时，游戏结束。此时，你的程序应该显示获胜者然后停止。例如，如果玩家2移除了最后的石头，你的程序应该输出一下内容：

Player 2 Wins.

三、样例输入/输出

据说要和样例输出一模一样

ROW A: ooo
ROW B: ooooo
ROW C: oooooooo
Player 1, choose a row and number of rocks: B2

ROW A: ooo
ROW B: ooo
ROW C: oooooooo
Player 2, choose a row and number of rocks: A1

ROW A: oo
ROW B: ooo
ROW C: oooooooo
Player 1, choose a row and number of rocks: C6

ROW A: oo
ROW B: ooo
ROW C: oo
Player 2, choose a row and number of rocks: G1
Invalid move. Try again.
Player 2, choose a row and number of rocks: B3

ROW A: oo
ROW B: 
ROW C: oo
Player 1, choose a row and number of rocks: A3
Invalid move. Try again.
Player 1, choose a row and number of rocks: C2

ROW A: oo
ROW B: 
ROW C: 
Player 2, choose a row and number of rocks: A1

ROW A: o
ROW B: 
ROW C: 
Player 1, choose a row and number of rocks: A*
Invalid move. Try again.
Player 1, choose a row and number of rocks: &4
Invalid move. Try again.
Player 1, choose a row and number of rocks: A1

Player 1 Wins.
----- Halting the processor -----

四、代码编写

数据存放

1、程序从x3000开始存放
2、每行石头的数量从x3200开始存放，且以-1结尾作为结束标志，以支持非题目要求的D~Z行（属于是自找麻烦了）

编写代码

注意：
以下代码片段并非代码实际顺序。
并且子程序没有严格地保存和恢复寄存器状态，这是不对滴。

1、石头状态输出子程序：

;石头状态输出
;R1-石头数量地址,R2-数量
FUNC_DRAW		ST  R7,SAVER7		;保存R7的值,因为PUTS和OUT会对其进行修改
				LD  R1,PTR_STONES	;石头堆首地址
				LD  R3,CHAR_ROWBASE	;'A'的ASCII码
  ;遍历石头堆
LOOP_1			LDR R2,R1,#0		;读取当前行石头数量
				BRn END_DRAW		;若数字为-1,结束输出
				LEA R0,STR_ROW
				PUTS
				AND R0,R0,#0
				ADD R0,R3,#0
				OUT
				LEA R0,STR_ROW2
				PUTS
				LD  R0,CHAR_SYMBOL	;
				ADD R2,R2,#0		;将CC恢复为R2
    ;循环输出o
LOOP_2			BRz OUT_2			;若数字R2降到0,结束当前循环
				OUT	
				ADD R2,R2,#-1
				BRnzp LOOP_2
OUT_2			LD  R0,CHAR_LF
				OUT
				ADD R1,R1,#1
				ADD R3,R3,#1		
				BRnzp LOOP_1
END_DRAW		LD R7,SAVER7
				RET

2、检查石头是否被取完：

;检查石头是否被取完了
;Output(R6):没取完(0),取完了(1)
FUN_CHECK		LD  R1, PTR_STONES	;R1指向石头
				AND R6, R6, #0
				ADD R6, R6, #1		;初始化R6为1
SUB_CHECK_LOOP	LDR R2, R1, #0		;读取当前行石头数
				BRp SUB_CHECK_FALSE	;任意行非零则返回0
				BRn SUB_CHECK_END	;遇到-1,说明石头数全为0,返回1
				ADD R1, R1, #1
				BRnzp SUB_CHECK_LOOP	

SUB_CHECK_FALSE ADD R6, R6, #-1		;R6置为0
SUB_CHECK_END	RET

3、判断当前输入的合法性并取走石头：

;判断当前的输入是否还有剩余,若无剩余输出错误信息
;Input(PTR_ROW,PTR_CNT)  Output(R6):非法输入(0),取走前一切正常(n)
FUN_HASLEFT		ST  R7, SAVER7		;保存R7,因为PUTS
				LD  R1, PTR_STONES	;R1指向首堆石头
				LD  R2, PTR_ROW
				LD  R3, NCHAR_A
				ADD R2, R2, R3		;行距离A的偏移
				BRn SUB_HAS_ERROR	;行号非法
				ADD R1, R1, R2		;指向输入指定的行
				AND R6, R6, #0
				LDR R2, R1, #0
				BRnz SUB_HAS_ERROR	;剩下的石头<=0,可同时判断行号非法和当前行为0
				ADD R6, R6, R2		;R6 = R2
SUB_HAS_SUB		LD  R2, PTR_CNT		;读取输入的数字
				LD  R3, NCHAR_0
				ADD R2, R2, R3		;ASCII -> num
				BRnz SUB_HAS_ERROR	;数字非法
				NOT R2, R2
				ADD R2, R2, #1		;R2 = -R2
				ADD R4, R6, R2		;R4 = 该行剩余 - 取走数量
				BRn SUB_HAS_ERROR	;该行剩下的石头不够
				STR R4, R1, #0		;更新石头数量
				BRnzp SUB_HAS_END
SUB_HAS_ERROR	AND R6, R6, #0		;需要返回的0
				LD  R0, CHAR_LF
				OUT
				LEA R0, STR_INVALID
				PUTS
				LD  R0, CHAR_LF
				OUT
SUB_HAS_END		LD  R7, SAVER7		;载入R7
				RET

4、行号及数量输入：

;输入行号(ABCDEFGHIJKLMNOPQRSTUVWXYZ)
INPUT_ROW		ST  R7, SAVER7
				GETC
				OUT
				ST  R0, PTR_ROW
				LD  R7, SAVER7
				RET

;输入个数(123456789)
INPUT_CNT		ST  R7, SAVER7
				GETC
				OUT
				ST  R0, PTR_CNT
				LD  R7, SAVER7
				RET

;此处用PTR命名是因为原来是打算用LDI和STI的,后来改用LD和ST懒得改了哈哈哈
PTR_ROW			.BLKW 1			;储存输入的行号(ASCII码A~Z)
PTR_CNT			.BLKW 1			;储存输入的数字(ASCII码0~9)
PTR_PLAYER		.FILL x0000		;储存当前玩家,0为P1,1为P2

5、主程序及玩家控制：

;主程序
;FUNC_MAIN
LOOP_PLAY		JSR FUNC_DRAW		;开局先输出一次石堆
				LD  R6, PTR_PLAYER
				BRz FUNC_P1			;为0就是玩家1
				BRp FUNC_P2			;为1就是玩家2
PLAY_AFTER		LD  R0, CHAR_LF
				OUT					;输出换行
				JSR FUNC_CHANGE		;切换玩家
				BRnzp LOOP_PLAY		;循环就是了,跳出在玩家控制中

;玩家1控制
FUNC_P1			LEA R0, STR_PLAYER1	;输出游戏提示
				PUTS
				JSR INPUT_ROW		;输入行号
				JSR INPUT_CNT		;输入数量
				JSR FUN_HASLEFT		;进行一个的判断和取石头
				ADD R6, R6, #0		;刷新CC
				BRnz FUNC_P1		;非法输入,再来
				LD  R0, CHAR_LF
				OUT					;为了让输出和样例一模一样
				JSR FUN_CHECK
				ADD R6, R6, #0		;刷新CC
				BRnz PLAY_AFTER		;R6=0,还没赢
				LD  R0, CHAR_LF		;R6=1,赢了
				OUT
				LEA R0, STR_WIN_1
				PUTS
				BRnzp _END
		
;玩家2控制(结构同玩家1)
FUNC_P2			LEA R0, STR_PLAYER2
				PUTS
				JSR INPUT_ROW		;输入行号
				JSR INPUT_CNT		;输入数量
				JSR FUN_HASLEFT		;进行一个的判断和取石头
				ADD R6, R6, #0		;刷新CC
				BRnz FUNC_P2		;非法输入,再来
				LD  R0, CHAR_LF
				OUT					;为了让输出和样例一模一样
				JSR FUN_CHECK
				ADD R6, R6, #0		;刷新CC
				BRnz PLAY_AFTER		;R6=0,还没赢
				LD  R0, CHAR_LF		;R6=1,赢了
				OUT
				LEA R0, STR_WIN_2
				PUTS
				BRnzp _END		

;玩家切换子程序(没有用到TRAP故)
FUNC_CHANGE	LD  R6, PTR_PLAYER
				BRz SUB_ZERO
				ADD R6, R6, #-1		;如果是1就切0
				ST  R6, PTR_PLAYER
				BRnzp SUB_CHANGE_RET
SUB_ZERO		ADD R6, R6, #1		;如果是0就切1
				ST  R6, PTR_PLAYER
SUB_CHANGE_RET	RET

完整代码如下（仅供参考，建议独立思考，所以我删掉了完整代码中的很多注释哈哈哈哈）：

				.ORIG x3000

;主程序
;FUNC_MAIN	
LOOP_PLAY		JSR FUNC_DRAW
		
				LD  R6, PTR_PLAYER
				BRz FUNC_P1
				BRp FUNC_P2
PLAY_AFTER		LD  R0, CHAR_LF
				OUT			;LF
				JSR FUNC_CHANGE
				BRnzp LOOP_PLAY

;玩家1
FUNC_P1			LEA R0, STR_PLAYER1
				PUTS
				JSR INPUT_ROW
				JSR INPUT_CNT
				JSR FUN_HASLEFT
				ADD R6, R6, #0
				BRnz FUNC_P1
				LD  R0, CHAR_LF
				OUT
				JSR FUN_CHECK
				ADD R6, R6, #0
				BRnz PLAY_AFTER
				LD  R0, CHAR_LF
				OUT
				LEA R0, STR_WIN_1
				PUTS
				BRnzp _END
		
;玩家2
FUNC_P2			LEA R0, STR_PLAYER2
				PUTS
				JSR INPUT_ROW
				JSR INPUT_CNT
				JSR FUN_HASLEFT
				ADD R6, R6, #0
				BRnz FUNC_P2
				LD  R0, CHAR_LF
				OUT
				JSR FUN_CHECK
				ADD R6, R6, #0
				BRnz PLAY_AFTER
				LD  R0, CHAR_LF
				OUT
				LEA R0, STR_WIN_2
				PUTS
				BRnzp _END		

;玩家切换子程序	
FUNC_CHANGE	LD  R6, PTR_PLAYER
				BRz SUB_ZERO
				ADD R6, R6, #-1
				ST  R6, PTR_PLAYER
				BRnzp SUB_CHANGE_RET
SUB_ZERO		ADD R6, R6, #1
				ST  R6, PTR_PLAYER
SUB_CHANGE_RET	RET

;输入行号(ABCDEFGHIJKLMNOPQRSTUVWXYZ)
INPUT_ROW		ST  R7, SAVER7
				GETC
				OUT
				ST  R0, PTR_ROW
				LD  R7, SAVER7
				RET

;输入个数
INPUT_CNT		ST  R7, SAVER7
				GETC
				OUT
				ST  R0, PTR_CNT
				LD  R7, SAVER7
				RET

PTR_ROW			.BLKW 1
PTR_CNT			.BLKW 1
PTR_PLAYER		.FILL x0000

;石头状态输出
;R1-石头数量地址,R2-数量
FUNC_DRAW		ST  R7,SAVER7
				LD  R1,PTR_STONES
				LD  R3,CHAR_ROWBASE
  ;遍历石头堆
LOOP_1			LDR R2,R1,#0
				BRn END_DRAW
				LEA R0,STR_ROW
				PUTS
				AND R0,R0,#0
				ADD R0,R3,#0
				OUT
				LEA R0,STR_ROW2
				PUTS
				LD  R0,CHAR_SYMBOL
				ADD R2,R2,#0
    ;循环输出o
LOOP_2			BRz OUT_2
				OUT	
				ADD R2,R2,#-1
				BRnzp LOOP_2
OUT_2			LD  R0,CHAR_LF
				OUT
				ADD R1,R1,#1
				ADD R3,R3,#1		
				BRnzp LOOP_1
END_DRAW		LD R7,SAVER7
				RET
		
		
;检查石头是否完了
;Output(R6):false(0),true(1)
FUN_CHECK		LD  R1, PTR_STONES
				AND R6, R6, #0
				ADD R6, R6, #1
SUB_CHECK_LOOP	LDR R2, R1, #0
				BRp SUB_CHECK_FALSE
				BRn SUB_CHECK_END
				ADD R1, R1, #1
				BRnzp SUB_CHECK_LOOP	

SUB_CHECK_FALSE ADD R6, R6, #-1
SUB_CHECK_END	RET

;判断当前的输入是否还有剩余,若无剩余输出错误信息
;Input(x5001)  Output(R6):false(0),p-left(n)
FUN_HASLEFT		ST  R7, SAVER7
				LD  R1, PTR_STONES
				LD  R2, PTR_ROW
				LD  R3, NCHAR_A
				ADD R2, R2, R3
				BRn SUB_HAS_ERROR
				ADD R1, R1, R2
				AND R6, R6, #0
				LDR R2, R1, #0
				BRnz SUB_HAS_ERROR
				ADD R6, R6, R2
SUB_HAS_SUB		LD  R2, PTR_CNT
				LD  R3, NCHAR_0
				ADD R2, R2, R3
				BRnz SUB_HAS_ERROR
				NOT R2, R2
				ADD R2, R2, #1
				ADD R4, R6, R2
				BRn SUB_HAS_ERROR
				STR R4, R1, #0
				BRnzp SUB_HAS_END
SUB_HAS_ERROR	AND R6, R6, #0
				LD  R0, CHAR_LF
				OUT
				LEA R0, STR_INVALID
				PUTS
				LD  R0, CHAR_LF
				OUT
SUB_HAS_END		LD  R7, SAVER7
				RET

_END			HALT

CHAR_ROWBASE	.FILL x0041	;'A'的ASCII码
NCHAR_A			.FILL xFFBF	;'A'的负值
NCHAR_0			.FILL xFFD0	;'0'的负值
CHAR_SYMBOL		.FILL x006f	;'o'的ASCII码
CHAR_LF			.FILL x000A	;换行符的ASCII
NCHAR_LF		.FILL xFFF6	;LF的负值
PTR_STONES		.FILL x3200	;石头数量信息储存起点

STR_ROW			.STRINGZ "ROW "
STR_ROW2		.STRINGZ ": "
STR_PLAYER1		.STRINGZ "Player 1, choose a row and number of rocks:"
STR_PLAYER2		.STRINGZ "Player 2, choose a row and number of rocks:"
STR_WIN_1		.STRINGZ "Player 1 Wins."
STR_WIN_2		.STRINGZ "Player 2 Wins."
STR_INVALID		.STRINGZ "Invalid move. Try again."

SAVER7			.BLKW 1		;保存R7

.END

五、小小总结

这次的实验长度（难度）肯定是比上次要翻倍的，不过有了子程序思想的加持，以及对LC-3汇编指令理解的加深，感觉也不是特别的难。
以上代码可能仍存在一些问题，但毕竟只是个实验嘛，凑合着做做（逃）~

白告月‮
关注
  • 5
    点赞
  • 踩
  • 5
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
LC-3 子程序调用与模拟栈调用递归函数
AKGWSB 's blog
06-03 2605
在LC-3的编程中，有时候需要重复调用一些子程序，但是又不能像c语言一样定义函数，但是LC-3提供了相当的机制供我们使用 TRAP机制调用子程序 在上一篇文章【LC-3简易四子棋（深大计系1实验4） 思路+代码+详细注释】中，我们提到： 对于输入输出，我们通过一些“伪操作”进行“系统调用”来实现读取字符，输出字符，可是这些操作的本质是TRAP机制来完成的调用 TRAP调用 TRAP将目标中断矢量（也就是trap的操作数，比如TRAP x21操作数是0x21）的高位补0得到一个数x，然后去内存x处寻找下一条
计算机系统（1）实验四 LC-3简单游戏设计（Nim游戏）
君叶寒的博客
08-01 1015
```ja
[转]博弈论（一）：Nim游戏
weixin_33936401的博客
04-29 243
重点结论：对于一个Nim游戏的局面(a1,a2,...,an)，它是P-position当且仅当a1^a2^...^an=0，其中^表示位异或(xor)运算。Nim游戏是博弈论中最经典的模型（之一？），它又有着十分简单的规则和无比优美的结论，由这个游戏开始了解博弈论恐怕是最合适不过了。 Nim游戏是组合游戏(Combinatorial Games)的一种，准确来说，属于“Impartial Co...
【计算机系统1】实验4、5：用LC-3写一个Nim游戏（无子程序）
Giro_6T的博客
05-15 722
Emmm，大概就是Nim游戏被我用汇编语言写出来了的一篇文章罢
LC-3 汇编语言 Nim游戏
最新发布
笔记
08-17 1613
计算机系统1
计算机系统（1） 实验四 Nim游戏
weixin_52827539的博客
07-19 669
计算机系统（1） 实验四 Nim游戏 文章目录计算机系统（1） 实验四 Nim游戏实验目的实验内容与实验要求实验步骤实验代码及注释总结 实验目的 （1）分析和理解试验指定的需解决问题。 （2）利用子程序代码设计实现相关程序。 实验内容与实验要求 实验要求： （1）熟悉和理解LC-3的子程序指令格式。 （2）掌握利用子程序解决问题的思路，加深对底层硬件的理解。 实验内容: ⑴ 在游戏开始时，你应该显示游戏界面的初始化状态。具体包括：在每行石子的前面，你应该先输出行的名称，例如“ROW A”。你应该使用
计算机系统1 实验四、五 Nim游戏 汇编源码
05-25
计算机系统1 实验四、五 Nim游戏 汇编源码 计算机系统1 实验四、五 Nim游戏 汇编源码 计算机系统1 实验四、五 Nim游戏 汇编源码 计算机系统1 实验四、五 Nim游戏 汇编源码 计算机系统1 实验四、五 Nim游戏 汇编源码 ...
nim-pop3：Nim POP3模块
02-04
在Nim的世界中，`nim-pop3`是用于处理POP3（Post Office Protocol version 3）协议的一个模块。POP3是一种广泛使用的互联网协议，主要用于从邮件服务器上下载电子邮件。下面我们将深入探讨`nim-pop3`模块，了解其...
heroku-buildpack-nim：将nim应用程序部署到heroku
02-03
nim语言是一个高效、现代且具有系统编程特性的高级编程语言，而Heroku则是一个流行的云平台，它提供了便捷的应用程序部署服务。当我们想要将用nim编写的程序发布到Heroku时，就需要借助特定的构建包——heroku-...
nim-d3：使用nim的D3.js库
02-03
1. **类型安全**：nim-d3库提供了与D3.js API对应的Nim接口，保持了Nim语言的类型安全特性，减少了运行时错误的可能性。 2. **无缝集成**：nim-d3允许开发者直接在Nim代码中调用D3.js的功能，无需编写JavaScript桥接...
深圳大学计算机系统LC-3中实现简易版四子棋实验报告（含源代码及截图）
12-11
计算机系统第四次实验是用LC3做简单游戏：四子棋。本资源含有实验报告、源代码以及截图，可以参考参考，有助于早日完成作业
nim-i3ipc：Nim的i3 IPC客户端库
02-04
nim-i3ipc库允许开发者通过Nim程序与i3进行交互，从而实现自动化任务、脚本编写或自定义工作流。 **Nim语言介绍** Nim是一种静态类型、命令式、面向对象、函数式并具有系统编程特性的现代编程语言。它的设计目标是...
Nim游戏
qq_44618625的博客
07-29 614
【题目】 你和你的朋友，两个人一起玩 Nim 游戏：桌子上有一堆石头，每次你们轮流拿掉 1 - 3 块石头。 拿掉最后一块石头的人就是获胜者。你作为先手。 你们是聪明人，每一步都是最优解。 编写一个函数，来判断你是否可以在给定石头数量的情况下赢得游戏。 示例: 输入: 4 输出: false 解释: 如果堆中有 4 块石头，那么你永远不会赢得比赛； 因为无论你拿走 1 块、2 块 还是 3 块石头，最后一块石头总是会被你的朋友拿走。 【官方题解】 如果石头的个数是4n，那么先手者必输：后手者只要保证每回合能
C语言实现Nim游戏
qq_44113419的博客
01-09 1740
Nim概述 nim游戏详解（易懂） 再强调一遍结论： 对于一个Nim游戏的局面(a1,a2,…,an)，它是P-position当且仅当a1^ a2^ … ^ an=0，其中“^”指抑或(xor)运算。 这便是整个程序的基础。 话不多说，直接上代码： 代码 #include&lt;stdio.h&gt; #include&lt;stdlib.h&gt; #include&lt;time.h&gt;...
【计算机系统】LC-3简单游戏设计
Alex_SCY的博客
05-17 958
NIM游戏 Nim是一个简单的双人游戏，可能起源于中国。游戏中使用的计数器类型有很多种类，如石子、火柴、苹果等。游戏界面被划分为很多行，每行中有数量不等的计数器，如图1所示： 行号 计数器数量 1 ○○○ 2 ○○○○○○ …… …… n ○○○○○○○○○○ 图1 游戏界面 1.游戏规则 本次实验对Nim游戏做了一些小的改变，具体如下：游戏界面由三行组成，计数器类型为石子，其中A行包含3个石子，B行包含5个石子，C行包含8个石子。 规则如下： 每个玩家轮流从某一行中移除一
力扣Nim游戏c语言,力扣292.Nim游戏---动态规划与巧妙的数学思想
weixin_42231590的博客
05-22 310
292. Nim 游戏你和你的朋友，两个人一起玩 Nim 游戏：桌子上有一堆石头。你们轮流进行自己的回合，你作为先手。每一回合，轮到的人拿掉 1 - 3 块石头。拿掉最后一块石头的人就是获胜者。假设你们每一步都是最优解。请编写一个函数，来判断你是否可以在给定石头数量为 n 的情况下赢得游戏。如果可以赢，返回 true；否则，返回 false 。示例 1：输入：n = 4输出：false解释：如果堆...
LeetCode3 Nim Game
BiYunTianThomas的博客
10-14 352
You are playing the following Nim Game with your friend: There is a heap of stones on the table, each time one of you take turns to remove 1 to 3 stones. The one who removes the last stone will be the
理论： 博弈3： Nim博弈
sun897949163的博客
01-30 744
Nim博弈原型个人定义： 有n堆石头， 每ai颗石头。 Alice和Bob分别从非空的石头堆中取走至少一颗石子。Alice先取， 取光所有的石头即为获胜。当双方都采取最优策略的时候， 谁会获胜？ 严谨定义： 有若干堆石子，每堆石子的数量都是有限的，合法的移动是“选择一堆石子并拿走若干颗（不能不拿）”，如果轮到某个人时所有的石子堆都已经被拿空了，则判负（因为他此刻没有任何合法的移动）。
Camp Day2 1前缀后缀和 3nim博弈相关 异或 5子树编号排序相邻差的平方和
qq_40423146的博客
02-04 193
#include<bits/stdc++.h> using namespace std; #define maxn 1000050 #define IO ios::sync_with_stdio(false);cin.tie(0); typedef long long ll; ll T,n,k,suff[maxn],suf[maxn],pre[maxn],sum[maxn]; doub...
组合博弈入门：Nim-Sum与简单取子游戏解析
"这篇资料是关于杭州电子科技大学的ACM程序设计课程的课件，主题是组合博弈入门，特别介绍了Nim-Sum的概念，并通过一个简单的取子游戏来阐述组合游戏的基本规则和必败点、必胜点的性质。课程还包含了一些实战练习，...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值