变量介绍
- 变量类型介绍
- 1,局部变量
- 2,类变量
- 3,全局变量
变量类型介绍
首先,看一下变量基础类型和申请方法
变量 文本1:文本 = "你好,结绳"
变量 整数1:整数 = 100
变量 逻辑1:逻辑型 = 真
除了上述以及图片中基本类型外,还有json类型等,申请用法是一样的。如:
变量 js1 : JSON对象
变量 js1 : JSON数组
接下来是变量的作用域
1,局部变量
顾名思义,局部变量的作用域,只在局部申请的位置运行。如:
类 启动窗口 : 窗口
@布局配置([[根布局=真,宽度=-1,高度=-1,纵向布局=真]])
变量 线性布局1 : 线性布局
@布局配置([[父布局=线性布局1]])
变量 按钮1 : 按钮
@布局配置([[父布局=线性布局1]])
变量 按钮2 : 按钮
事件 启动窗口 : 创建完毕()
申请所有权限()
订阅事件()
变量 局部变量1:文本 = "你好"
弹出提示(局部变量1)
// 正确写法
// 此时运行,会正常弹出提示"你好",
// 变量和调用都在同一个事件或方法内。
结束 事件
事件 按钮1 : 被单击()
弹出提示(局部变量1)
// 注意注意,这是错误写法
// 此时肯定会报错,因为局部变量1申请在创建完毕事件内
// 故此,局部变量1只能在创建完毕事件内使用。
结束 事件
// 下方测试弹窗方法,属于超前学习自定义方法
// 当一个程序需要调用多次同样的步骤,可以用自定义方法节省代码量
// 如按钮1点击,触发这个事件,但是按钮2点击,也要触发这个事件。
方法 测试弹窗(内容 : 文本)
弹出提示(内容)
结束 方法
事件 按钮2:被单击()
变量 临时1:文本 = "成功了"
测试弹窗(临时1)
// 调用上方自定义方法,测试弹窗,弹出局部变量临时1
// 此时正常运行,弹出提示"成功了"
// 因为局部变量申明和调用,都在同一个事件或方法
// 超前点播自定义方法
// 运行下列代码,会弹出提示"你好呀"
// 上方参数设定为文本,故调用时可以输入文本型变量,或直接输入文本
测试弹窗("你好呀")
结束 事件
结束 类
2,类变量
类变量,就是能运行在当前类中的变量,申明方法如下。
类 启动窗口:窗口
变量 临时1:文本 = "你好"
事件 按钮1:被单击()
弹出提示(临时1)
结束 事件
事件 按钮2:被单击()
弹出提示(临时1)
结束 事件
// 无论是触发按钮1还是按钮2被单击,都可正常运行
//因为变量 申明在类中,是一个类变量
结束 类
类 窗口2:窗口
变量 窗口1 : 启动窗口
事件 按钮1:被单击()
弹出提示(窗口1.临时1)
// 此时也会正常弹出提示
// 这是调用不同窗口类的演示
// 先用变量名为窗口1的变量,继承了启动窗口类
// 再调用其中包含的变量方法等。
结束 事件
结束 类
3,全局变量
直接申请一个全局变量,全局变量,意思就是在任意窗口,任意位置都可以调用的方法或变量等。
@全局类
类 全局1
@静态
变量 临时1 : 文本 = "你好"
// 这是静态申请方法,调用下面会讲到
变量 临时2 : 文本 = "你好呀"
// 这里,也是一个全局变量
// 这是一个全局自定义方法
@静态
方法 修改变量(内容 : 文本)
临时1 = 内容
临时2 = 内容
结束 方法
结束 类
上面已经申请了两个全局变量,下面来开始调用
类 启动窗口:窗口
事件 按钮1:被单击()
弹出提示(全局1.临时1)
// 此时会弹出提示"你好",虽然不在同一个类,但因为是全局变量,所以任意位置都可调用
弹出提示(临时1)
// 此时也会正常调用运行,但是不建议如此使用
// 虽然可以调用全局静态变量,但代码量大了以后,容易混淆
修改变量("修改成功啦!")
弹出提示(临时1)
// 此时会弹出提示,"修改成功啦!"
// 代码从上往下执行,先执行了全局方法,修改变量,然后再弹出提示。
结束 事件
事件 按钮2 : 被单击()
弹出提示(临时2)
// 这是错误写法,会报错
// 虽然上方全局变量申请了,但由于这个不是静态变量,需要先创建类,才能调用
变量 全局2 : 全局1
弹出提示(全局2.临时2)
// 此时正常运行,因为全局2变量,继承了全局1
结束 事件
结束 类