Unity Shader 从未入门到已放弃（十九）--高级 边缘检测

卷积

常见的边缘检测算子

边是如何形成的：如果相邻像素之间存在明显差别的颜色、亮度、纹理等属性，我们会认为他们之间存在一条边界。这种相邻像素之间的差值可以用梯度来表示，边缘处的梯度值通常较大。

我们需要对每个像素进行一次卷积计算，得到两个方向上的梯度值，再计算得到整体梯度值：

实现

首先还是需要OnRenderImage函数来进行真正的特效处理：

[Range(0.0f, 1.0f)]
    public float edgesOnly = 0.0f;

    public Color edgeColor = Color.black;

    public Color backgroundColor = Color.white;

    private void OnRenderImage(RenderTexture source, RenderTexture destination)
    {
        if (material != null)
        {
            material.SetFloat("_EdgeOnly", edgesOnly);
            material.SetColor("_EdgeColor", edgeColor);
            material.SetColor("_BackgroundColor", backgroundColor);

            Graphics.Blit(source, destination, material);
        }
        else
        {
            Graphics.Blit(source, destination);
        }
    }

再实现shader部分：

Shader "myShader/EdgeDetection"
{
	Properties
	{
		_MainTex("Base (RGB)", 2D) = "white" {}
		_EdgeOnly("Edge Only", Float) = 1.0
		_EdgeColor("Edge Color", Color) = (0, 0, 0, 1)
		_BackgroundColor("Background Color", Color) = (1, 1, 1, 1)
	}
	SubShader
	{
		Pass
		{
			ZTest Always Cull Off ZWrite Off

			CGPROGRAM
			
			#pragma vertex vert  
			#pragma fragment fragSobel  

			#include "UnityCG.cginc"  

			sampler2D _MainTex;
			uniform half4 _MainTex_TexelSize; //提供访问_MainTex纹理对应的每个纹素的大小
			fixed _EdgeOnly;
			fixed4 _EdgeColor;
			fixed4 _BackgroundColor;

			struct v2f {
				float4 pos : SV_POSITION;
				half2 uv[9]: TEXCOORD0;//9维纹理数组
			};

			v2f vert(appdata_img v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);

				half2 uv = v.texcoord;

				o.uv[0] = uv + _MainTex_TexelSize.xy * half2(-1, -1);
				o.uv[1] = uv + _MainTex_TexelSize.xy * half2(0, -1);
				o.uv[2] = uv + _MainTex_TexelSize.xy * half2(1, -1);
				o.uv[3] = uv + _MainTex_TexelSize.xy * half2(-1, 0);
				o.uv[4] = uv + _MainTex_TexelSize.xy * half2(0, 0);
				o.uv[5] = uv + _MainTex_TexelSize.xy * half2(1, 0);
				o.uv[6] = uv + _MainTex_TexelSize.xy * half2(-1, 1);
				o.uv[7] = uv + _MainTex_TexelSize.xy * half2(0, 1);
				o.uv[8] = uv + _MainTex_TexelSize.xy * half2(1, 1);

				return o;
			}

			fixed luminance(fixed4 color) {
				return 0.2125 * color.r + 0.7154 * color.g + 0.0721 * color.b;
			}

			//利用Sobel算子对原图进行边缘检测
			half Sobel(v2f i) {
				//水平方向卷积核
				const half Gx[9] = { -1,-2,-1,
									  0, 0, 0,
									  1, 2, 1 };
				//垂直方向卷积核
				const half Gy[9] = { -1, 0, 1,
									 -2, 0, 2,
									 -1, 0, 1 };
				half texColor;
				half edgeX;
				half edgeY;
				for (int it = 0; it < 9; it++)
				{
					texColor = luminance(tex2D(_MainTex, i.uv[it]));
					edgeX += texColor * Gx[it];
					edgeY += texColor * Gy[it];
				}

				half edge = 1 - abs(edgeX) - abs(edgeY);
				return edge;
			}

			fixed4 fragSobel(v2f i) :SV_Target{
				half edge = Sobel(i); //获得当前像素梯度值

				fixed4 withEdgeColor = lerp(_EdgeColor, tex2D(_MainTex, i.uv[4]), edge); //背景为原图
				fixed4 onlyEdgeColor = lerp(_EdgeColor, _BackgroundColor, edge); //纯色下
				return lerp(withEdgeColor, onlyEdgeColor, _EdgeOnly);
			}
			ENDCG
		}
	}
	Fallback Off
}

这个方法实现的边缘检测仅仅利用了屏幕的颜色信息，而在实际的运用中，物体的纹理、阴影等信息都会影响边缘检测的结果。

效果图：