SAP 01-初识AMDP(ABAP-Managed Database Procedure)

1. 什么是AMDP(ABAP-Managed Database Procedure)

• AMDP - ABAP管理数据库程序，是一种程序，我们可以使用SQLSCRIPT在AMDP内部编写代码，SQLSCRIPT是一种与SQL脚本相同的数据库语言，这种语言易于理解和编码。 将AMDP方法内的逻辑编码后，可以在ABAP报表中使用，也可以在CDS Table Function中使用AMDP方法。
• 使用AMDP，可以将ABAP Application编写的代码通过HANA的新特性(代码下推技术)，将逻辑在数据库层执行。

2. AMDP的弊端

• AMDP还不能在Eclipse、HANA Studio上进行Debug操作
• 不能使用mseg表，但可以使用 MATDOC的代理对象 NSDM_V_MSEG 代替
• 数据类型必须是表或者标准类型（INT CHAR …）
• 对于传入的Select-option，必须先在ABAP中用方法 cl_shdb_seltab=>combine_seltabs处理后在传入AMDP；然后在AMDP中用 APPLY_FILTER
• AMDP不能自动处理Client信息，使用时必须传入SY-MANDT；否则取出来的数据是所有Client的全部数据
  

3. 实现简单的AMDP Functions for AMDP Methods

• 在Eclipse或者HANA Studio新建一个ABAP Class
  
  
• 实现Class，必须注明实施的Interface：IF_AMDP_MARKER_HDB（目前只支持HDB，若未来支持其他DB；接口名称则为：IF_AMDP_MARKER_<DB_NAME>）
  • By database Procedure： 实现一个数据库过程。使用此方法，AMDP方法将自动在HANA系统中创建一个过程
  • FOR HDB： 指定数据库类型为 HANA database
  • LANGUAGE SQLSCRIPT： 指定用于实现AMDP的数据库特定语言为 SQLSCRIPT
  • OPTION READ-ONLY： 设置只能在数据库过程中读取
  • USING <table_name/view_name>： 设置使用的数据库表或视图
    
    

    CLASS zamdp_demo_01 DEFINITION
      PUBLIC
      FINAL
      CREATE PUBLIC .
    
      PUBLIC SECTION.
        interfaces:
            IF_AMDP_MARKER_HDB.
    
        class-methods:
        get_data_go_back importing value(ip_mandt) type spfli-mandt
                         exporting value(et_spfli) type SPFLI_TAB.
    
      PROTECTED SECTION.
      PRIVATE SECTION.
    ENDCLASS.
    
    CLASS zamdp_demo_01 IMPLEMENTATION.
        method get_data_go_back by database procedure
                                for hdb language sqlscript
                                options read-only
                                using spfli sflight.
    * GET DATA GO BACK
        et_spfli =
            select
                t1.MANDT,
                t2.CARRID,
                t2.CONNID,
                t1.COUNTRYFR,
                t1.CITYFROM,
                t1.AIRPFROM,
                t1.COUNTRYTO,
                t1.CITYTO,
                t1.AIRPTO,
                t1.FLTIME,
                t1.DEPTIME,
                t1.ARRTIME,
                t1.DISTANCE,
                t1.DISTID,
                t1.FLTYPE,
                t1.PERIOD
            from spfli as T1
            left outer join sflight as t2
                ON t1.CARRID = t2.CARRID
                and t1.CONNID = t2.CONNID
            where t1.mandt = :ip_mandt;
    
       endmethod.
    ENDCLASS.
    

4. 在ABAP中调用AMDP

DATA: lt_spfli TYPE spfli_tab.

START-OF-SELECTION.
  IF cl_abap_dbfeatures=>use_features(
            EXPORTING
              requested_features = VALUE #( ( cl_abap_dbfeatures=>call_amdp_method )
                                                    ( cl_abap_dbfeatures=>amdp_table_function ) ) ).
    zamdp_demo_01=>get_data_go_back(
            EXPORTING
              ip_mandt = sy-mandt
            IMPORTING
              et_spfli = lt_spfli ).

    cl_demo_output=>display( lt_spfli ).
  ELSE.
    cl_demo_output=>display( '警告！当前系统不支持AMDP.' ).
  ENDIF.