SAP AMDP数据库存储过程，AMDP语法实例

Gong JX

已于 2022-04-06 09:08:25 修改

阅读量5.7k

点赞数 8

分类专栏： CDS ABAP开发回顾总结文章标签：数据库 java 经验分享

于 2021-04-26 16:55:45 首次发布

本文链接：https://blog.csdn.net/qq_40977705/article/details/115932873

版权

ABAP开发回顾总结同时被 2 个专栏收录

90 篇文章 48 订阅

订阅专栏

CDS

9 篇文章 11 订阅

订阅专栏

AMDP function，AMDP函数实现

AMDP procedure，AMDP过程实现

常用函数

实例测试

AMDP介绍

AMDP（ABAP-Managed Database Procedure）是在ABAP层进行HANA数据库过程的实现和生命周期的管理，使用ABAP开发语言在ADT工具编HANA SQLScript。允许ABAP开发人员在HANA数据库层直接编写应用逻辑，即所谓的数据库存储过程。

AMDP类只能在ADT里进行开发，在SAP GUI里可以用只读的方式浏览源代码，无法编写

AMDP语法

AMDP是实现了一个特殊的类，并为这个类实现接口if_amdp_marker_hdb，这个接口就是这个类的特殊之处，该接口的实现表明了该类是一个AMDP类，可以编写AMDP代码。所以这类型接口也叫标记接口。

AMDP类的方法与普通的ABAP类方法相比也是有一些特殊之处的，它需要有一些关键字去修饰。 BY DATABASE FUNCTION FOR HDB LANGUAGE SQLSCRIPT表明被修饰的方法是一个AMDP的容器，实现语言为HANA SQLScript，实现体内以只读方式访问数据库表SPFLI。

DECLARE变量声明

AMDP中变量，内表的定义使用关键字DECLARE

DECLARE LV_txt "$ABAP.type( CHAR20 )" ; "字符串变量
DECLARE lv_index int ; "数字整形变量
DECLARE lv_datafr DATE; "日期类型
DECLARE lv_timefr TIME; "时间类型
"内表结构
DECLARE lt_RETURN TABLE (

     MANDT      "$ABAP.TYPE( MANDT )",
     FIELD1     "$ABAP.TYPE( CHAR20 )" ,
     FIELD2     "$ABAP.TYPE( CHAR20 )" ,
     FIELD3     "$ABAP.TYPE( CHAR20 )",
     FIELD4     "$ABAP.TYPE( CHAR20 )",
     FIELD5     "$ABAP.TYPE( INT1 )",
     FIELD6     "$ABAP.TYPE( CHAR20 )"  
   );

变量赋值使用 ‘:=’

LV_txt := 'test' ;

CURSOR循环（FOR）

游标CURSOR，使用游标可以先把数据取出来放到一张内表里，然后对它进行循环处理

   DECLARE CURSOR lt_spfli FOR (
      select * FROM SPFLI  
   );
   for ls_spfli as lt_spfli do
     "...
   END FOR ;

数组的使用

数组的使用方法类似C语言中的数组，可以使用索引的方式去读写

    DECLARE ARRAY_TIME INTEGER ARRAY; /*定义int类型数组*/

    IV_TIMEFR := CURRENT_TIME ; /*当前系统时间*/

    ARRAY_TIME[1] := HOUR( :IV_TIMEFR);
    ARRAY_TIME[2] := MINUTE (:IV_TIMEFR);
    ARRAY_TIME[3] := SECOND (:IV_TIMEFR);

另外内表也可以用这种角标的方法去给某一行赋值，下面是一个完整的过程，只做演示。先从SPFLI表中获取数据，然后用游标去循环处理，将这些数据处理后（自行脑补）放入lt_return表结果集中返回。

  METHOD GET_FLYDATAS BY DATABASE FUNCTION FOR HDB LANGUAGE SQLSCRIPT
                      OPTIONS READ-ONLY
                      USING SPFLI.
   DECLARE ARRAY_TIME INTEGER ARRAY;
   DECLARE lv_index   int ;
   DECLARE lt_return  TABLE (

                MANDT    "$ABAP.TYPE( MANDT )",
                Carrid   "$ABAP.TYPE( s_carr_id )",
                Connid   "$ABAP.TYPE( s_conn_id )"
                                     );
   DECLARE CURSOR lt_spfli FOR (
      select * FROM SPFLI
   );
   lv_index := 1;
   for ls_spfli as lt_spfli do
      lt_return.mandt[:lv_index] :=  :ls_spfli.mandt ;
      lt_return.mandt[:lv_index] :=  :ls_spfli.mandt ;
      lt_return.mandt[:lv_index] :=  :ls_spfli.mandt ;
      lv_index := :lv_index + 1;
   END FOR ;
   RETURN
     SELECT mandt, CARRID, CONNID FROM :lt_return;


  ENDMETHOD .

IF...ELSE

条件判断和ABAP语法没太大区别，大致格式如下

      if lv_index = 1 then 
      
      elseif lv_index = 2 then
      
      else 
      
      end if ;

内表读取

AMDP支持所有HANA SQL语句

   LT_SPFLI = SELECT * FROM SPFLI ; 
   lv_index := 1;
   lv_len = record_count( :LT_SPFLI ) ;
   WHILE lv_index <= lv_len do 
     lv_field1 := :LT_SPFLI.carrid[ :lv_index ];
     lv_index  := :lv_index + 1 ;
   end WHILE ;

方法嵌套调用

AMDP方法有两种，一种是AMDP procedure，AMDP过程实现；另一种是AMDP function，AMDP函数实现。

BY DATABASE FUNCTION: 会将方法标记为table function
BY DATABASE PROCEDURE标记为存储过程.
FOR HDB: 设定数据库类型为HDB (HANA数据库).
LANGUAGE SQLSCRIPT: HANA数据库存储的语言.
OPTIONS READ-ONLY: 存储过程内不允许修改数据.
USING: 定义table function中消费的数据库表、视图或者存储过程等。

AMDP function，AMDP函数实现

AMDP function方法，关键字BY DATABASE FUNCTION FOR HDB LANGUAGE SQLSCRIPT添加了AMDP函数实现，这种AMDP方法，只能实现对CDS表功能的AMDP方法，CDS表函数的AMDP函数实现只能在静态AMDP类的公共可见性部分中声明，声明必须使用特殊形式的CLASS-METHODS语句以及 FOR TABLE FUNCTION语句

AMDP procedure，AMDP过程实现

AMDP过程实现用‘BY DATABASE PROCEDURE FOR HDB LANGUAGE SQLSCRIPT’修饰为过程实现，AMDP过程实现的方法不能为空。必须使用附加的USING声明在AMDP方法中访问，方法名必须大写。

DEFINITION

IMPLEMENTATION

USING

方法名大写

常用函数

record_count( ) 计算内表行

MOD(:lv_line , 2 ) 取余

CURRENT_DATE 当前系统日期

CURRENT_TIME 当前系统时间

DAYS_BETWEEN（）两个日期的间隔，返回INT值

HOUR（）取小时

MINUTE（）取分钟

SECOND （）取秒

实例测试

TABLE FUNCTION

@EndUserText.label: 'TEST TABLE FUNCTION'
define table function ZTEST_TABLEF
returns {
 key mandt : abap.clnt;
 key CARRID : s_carr_id ;
 key CONNID : s_conn_id ;
    
}
implemented by method ZCL_TEST_AMDP=>get_flydatas;

CODE

CLASS ZCL_TEST_AMDP DEFINITION
  PUBLIC
  FINAL
  CREATE PUBLIC .

  PUBLIC SECTION.
    INTERFACES if_amdp_marker_hdb.
    CLASS-METHODS:
       get_flydatas FOR TABLE FUNCTION ZTEST_TABLEF.
PROTECTED SECTION.
PRIVATE SECTION.
   CLASS-METHODS:
       get_data_FLY IMPORTING VALUE(iv_carrid) type s_carr_id
                              VALUE(iv_connid) TYPE s_conn_id
                    exporting value(iv_test) type i .
ENDCLASS.

CLASS ZCL_TEST_AMDP IMPLEMENTATION.
  METHOD GET_FLYDATAS BY DATABASE FUNCTION FOR HDB LANGUAGE SQLSCRIPT
                      OPTIONS READ-ONLY
                      USING SPFLI ZCL_TEST_AMDP=>get_data_FLY .
   DECLARE ARRAY_TIME INTEGER ARRAY;
   DECLARE lv_index   int ;
   DECLARE lv_test    int ;
   DECLARE lv_len     int ;
   DECLARE lv_field1   "$ABAP.TYPE( s_carr_id )";
   DECLARE lt_return  TABLE (

                MANDT    "$ABAP.TYPE( MANDT )",
                Carrid   "$ABAP.TYPE( s_carr_id )",
                Connid   "$ABAP.TYPE( s_conn_id )"
                                     );
   DECLARE CURSOR lt_spfli FOR (
      select * FROM SPFLI
   );
   lv_index := 1;
   for ls_spfli as lt_spfli do
      if lv_index = 1 then
         call "ZCL_TEST_AMDP=>GET_DATA_FLY"(
                                              iv_carrid => 'AA',
                                              iv_connid => '12',
                                              iv_test  => :lv_test
                                               );
      elseif lv_index = 2 then

      else

      end if ;
      lt_return.mandt [:lv_index]  :=  :ls_spfli.mandt ;
      lt_return.carrid[:lv_index] :=  :ls_spfli.carrid ;
      lt_return.connid[:lv_index] :=  :ls_spfli.connid ;
      lv_index := :lv_index + 1;
   END FOR ;
   RETURN
     SELECT mandt, CARRID, CONNID FROM :lt_return;


  ENDMETHOD .


  METHOD GET_DATA_FLY BY DATABASE PROCEDURE FOR HDB LANGUAGE SQLSCRIPT
                      OPTIONS READ-ONLY.

    iv_test = 1 ;
  ENDMETHOD.

ENDCLASS.

Gong JX

关注

8
点赞
踩
35

收藏

觉得还不错? 一键收藏
打赏
0
评论
SAP AMDP数据库存储过程，AMDP语法实例

目录AMDP介绍AMDP语法DECLARECURSORAMDP介绍AMDP（ABAP-Managed Database Procedure）是在ABAP层进行HANA数据库过程的实现和生命周期的管理，使用ABAP开发语言在ADT工具编HANA SQLScript。允许ABAP开发人员在HANA数据库层直接编写应用逻辑，即所谓的数据库存储过程。AMDP类只能在ADT里进行开发，在SAP GUI里可以用只读的方式浏览源代码，无法编写AMDP语法AMDP是实现了一个特殊的.
复制链接

扫一扫