S3C2440存储管理器详解

存储管理器概念，通俗而言就是可以通过它来访问外部存储设备的一种东西

s3c2440地址空间分布
s3c2440对外引出了27根地址线ADDR0-ADDR26，访问空间为128MB，还对外引出了8根片选信号nGCS0-nGCS7，对应BANK0~BANK7，n表示低电平有效。学过数电的同学都知道。

这是s3c2440存储器的BANK0~BANK7

但是2440是32位的CPU，地址空间应该为4GB，除以上1GB空间用来连接外设外，还有一部分是CPU内部寄存器的地址，剩下的地址空间没有使用，寄存器空间的地址是0X48000000~0X5FFFFFFF

BANK0~BANK5的连接方式都是相似的，BANK6连接SDRAM时复杂些
SDRAM的内部是一个存储阵列，分为行地址和列地址，可以通过行列地址来找到存储位置，这一个存储单元就是逻辑BANK，SDRAM一般含有4个L_BANK

对于操作SDRAM的方法就是先片选信号nSCS0选中，然后用ADDR24和ADDR25作为L_BANK的选择信号 意思就是两位二进制数分别对应2*2个L_BANK
然后就可从ADDR2~ADDR14发出行列地址接着就就可以读取或者写数据了
通过查阅手册我们可以知道怎么使用存储管理器的寄存器，存储管理器共有13个寄存器,BANK0~BANK5只需要设置BWSCON和BANKCONx两个寄存器 而BANK6~BANK7外接SDRAM时，还需要设置REFRESH,BANKSIZE,MRSRB6，MRSRB7四个寄存器
具体寄存器的介绍就自己翻阅手册可知 如果你连手册都没有 那也是不会读此文的了~

下面是实例介绍

@*************************************************************************
@ File：head.S
@ 功能：设置SDRAM，将程序复制到SDRAM，然后跳到SDRAM继续执行
@*************************************************************************       

.equ        MEM_CTL_BASE,       0x48000000
.equ        SDRAM_BASE,         0x30000000

.text
.global _start
_start:
    bl  disable_watch_dog               @ 关闭WATCHDOG，否则CPU会不断重启
    bl  memsetup                        @ 设置存储控制器
    bl  copy_steppingstone_to_sdram     @ 复制代码到SDRAM中
    ldr pc, =on_sdram                   @ 跳到SDRAM中继续执行
on_sdram:
    ldr sp, =0x34000000                 @ 设置堆栈
    bl  main
halt_loop:
    b   halt_loop

disable_watch_dog:
    @ 往WATCHDOG寄存器写0即可
    mov r1,     #0x53000000
    mov r2,     #0x0
    str r2,     [r1]
    mov pc,     lr      @ 返回

copy_steppingstone_to_sdram:
    @ 将Steppingstone的4K数据全部复制到SDRAM中去
    @ Steppingstone起始地址为0x00000000，SDRAM中起始地址为0x30000000

    mov r1, #0
    ldr r2, =SDRAM_BASE
    mov r3, #4*1024
1:  
    ldr r4, [r1],#4     @ 从Steppingstone读取4字节的数据，并让源地址加4
    str r4, [r2],#4     @ 将此4字节的数据复制到SDRAM中，并让目地地址加4
    cmp r1, r3          @ 判断是否完成：源地址等于Steppingstone的未地址？
    bne 1b              @ 若没有复制完，继续
    mov pc,     lr      @ 返回

memsetup:
    @ 设置存储控制器以便使用SDRAM等外设

    mov r1,     #MEM_CTL_BASE       @ 存储控制器的13个寄存器的开始地址
    adrl    r2, mem_cfg_val         @ 这13个值的起始存储地址
    add r3,     r1, #52             @ 13*4 = 54
1:  
    ldr r4,     [r2], #4            @ 读取设置值，并让r2加4
    str r4,     [r1], #4            @ 将此值写入寄存器，并让r1加4
    cmp r1,     r3                  @ 判断是否设置完所有13个寄存器
    bne 1b                          @ 若没有写成，继续
    mov pc,     lr                  @ 返回


.align 4
mem_cfg_val:
    @ 存储控制器13个寄存器的设置值
    .long   0x22011110      @ BWSCON
    .long   0x00000700      @ BANKCON0
    .long   0x00000700      @ BANKCON1
    .long   0x00000700      @ BANKCON2
    .long   0x00000700      @ BANKCON3  
    .long   0x00000700      @ BANKCON4
    .long   0x00000700      @ BANKCON5
    .long   0x00018005      @ BANKCON6
    .long   0x00018005      @ BANKCON7
    .long   0x008C07A3      @ REFRESH
    .long   0x000000B1      @ BANKSIZE
    .long   0x00000030      @ MRSRB6
    .long   0x00000030      @ MRSRB7