Halcon例程分析7：划痕检测

打开halcon，按下ctrl+e打开halcon自带例程。工业领域->光学与精密工程->surface_scratch.hdev

* This programm shows the extraction of surface scratches via
* local thresholding and morphological post-processing
* 
dev_update_off ()
dev_close_window ()
* 
* Step 1: Acquire image
* 
*获取图像
read_image (Image, 'surface_scratch')
get_image_size (Image, Width, Height)
*原图大小显示图像
dev_open_window_fit_image (Image, 0, 0, Width, Width, WindowID)
set_display_font (WindowID, 16, 'mono', 'true', 'false')
dev_set_draw ('margin')
dev_set_line_width (4)
dev_display (Image)
*提示信息
Message := 'This program shows the extraction of'
Message[1] := 'surface scratches via local thresholding'
Message[2] := 'and morphological post-processing'
disp_message (WindowID, Message, 'window', 12, 12, 'black', 'true')
disp_continue_message (WindowID, 'black', 'true')
stop ()
* 
* Step 2: Segment image
* 
* Using a local threshold
*均值滤波，卷积核大小7×7
mean_image (Image, ImageMean, 7, 7)
*动态阈值化，关于这个函数的说明可以参考
*第一个参数原始图像
*第二个参数参考图像
*第三个参数输出图像
*第四个参数偏移值
*第五个参数明暗选择参数。选择'dark'是输出图像选择比参考图像灰度值小5的部分
dyn_threshold (Image, ImageMean, DarkPixels, 5, 'dark')
* 
* Extract connected components
*分割阈值化后的图像
connection (DarkPixels, ConnectedRegions)
dev_set_colored (12)
dev_display (Image)
dev_display (ConnectedRegions)
Message := 'Connected components after image segmentation'
Message[1] := 'using a local threshold.'
disp_message (WindowID, Message, 'window', 12, 12, 'black', 'true')
disp_continue_message (WindowID, 'black', 'true')
stop ()
* 
* Step 3: Process regions
* 
* Select large regions
*选择面积特征在10到1000之间的区域
select_shape (ConnectedRegions, SelectedRegions, 'area', 'and', 10, 1000)
dev_display (Image)
dev_display (SelectedRegions)
disp_message (WindowID, 'Large Regions', 'window', 12, 12, 'black', 'true')
disp_continue_message (WindowID, 'black', 'true')
stop ()
* 
* Visualize fractioned scratch
*打开一个缩放窗口，显示原图像中小划痕这部分
open_zoom_window (0, round(Width / 2), 2, 303, 137, 496, 3, WindowHandleZoom)
dev_set_color ('blue')
dev_display (Image)
dev_display (SelectedRegions)
set_display_font (WindowHandleZoom, 16, 'mono', 'true', 'false')
disp_message (WindowHandleZoom, 'Fractioned scratches', 'window', 12, 12, 'black', 'true')
disp_continue_message (WindowHandleZoom, 'black', 'true')
stop ()
* 
* Merge fractioned scratches via morphology
*联结图像，把前面connection函数分割的区域联结起来
union1 (SelectedRegions, RegionUnion)
*图像腐蚀，把大点的区域选择出来，小的区域隐藏
dilation_circle (RegionUnion, RegionDilation, 3.5)
dev_display (Image)
dev_display (RegionDilation)
Message := 'Region of the scratches after dilation'
disp_message (WindowHandleZoom, Message, 'window', 12, 12, 'black', 'true')
disp_continue_message (WindowHandleZoom, 'black', 'true')
stop ()
*对腐蚀后的图像提取骨架
skeleton (RegionDilation, Skeleton)
*分割骨架图像，把各自划痕和污点分割开
connection (Skeleton, Errors)
dev_set_colored (12)
dev_display (Image)
dev_display (Errors)
Message := 'Fractioned scratches merged via morphology'
disp_message (WindowHandleZoom, Message, 'window', 12, 12, 'black', 'true')
disp_continue_message (WindowHandleZoom, 'black', 'true')
stop ()
* 
* Distinguish small and large scratches
close_zoom_window (WindowHandleZoom, Width, Height)
*选择面积特征50到10000的区域为划痕
select_shape (Errors, Scratches, 'area', 'and', 50, 10000)
*选择1到50的区域为污点
select_shape (Errors, Dots, 'area', 'and', 1, 50)

dev_display (Image)
dev_set_color ('red')
dev_display (Scratches)
dev_set_color ('blue')
dev_display (Dots)
Message := 'Extracted surface scratches'
Message[1] := 'Not categorized as scratches'
disp_message (WindowID, Message, 'window', 440, 310, ['red','blue'], 'true')

测试原图像

划痕与污点测试结果图像，红色显示划痕区域，蓝色显示污点区域