触发器

/*
触发器
每当一个特定的数据操作语句（insert、update、delete）在指定的表上发出时，Oracle自动地执行触发器中定义的语句序列。

第一个触发器：每当成功插入新员工后，自动打印“成功插入新员工”
（触发器单词：trigger）
*/

create trigger saynewemp
after insert
on emp
declare
begin
  dbms_output.put_line('成功插入新员工');
end;
/

执行插入语句则打印“成功插入新员工”

/*触发器的具体应用场景
1、复杂的安全性检查
2、数据的确认
3、数据库审计
4、数据的备份和同步
*/
/*
创建触发器的语法
CREATE [or REPLACE] TRIGGER 触发器名
{BEFORE| AFTER}
{DELETE|INSERT|UPDATE[OF 列名]}
ON 表名
[FOR EACH ROW [WHEN(条件)]]
PLSQL块
*/

–触发器应用场景1：实施复杂的安全性检查
–禁止在非工作时间插入新员工
/*
1.周末：to_char(sysdate,’day’) in (‘星期六’,’星期日’)
2.上班前，下班后：to_number(to_char(sysdate,’hh24’)) not between 9 and 18
*/

–语句级触发器（针对整个表的操作，一次操作触发一次）

create or replace trigger securityemp
before insert
on emp
begin
 if to_char(sysdate,'day') in ('星期六','星期日') or
    to_number(to_char(sysdate,'hh24')) not between 9 and 18 then
    --禁止insert新员工,抛出应用异常，区别去系统的异常
    raise_application_error(-20001,'禁止在非工作时间插入新员工');
 end if;
end;
/

–触发器应用场景二：数据的确认
–涨工资不能越涨越少

/*
行级触发器
触发语句作用的每一条记录都被触发。在行级触发器中使用:old和:new伪记录变量，识别值的状态。

1. :old和：new 代表同一条记录
2. :old表示操作该行之前，这一行的值
   :new表示操作该行之后，这一行的值
   */

create or replace trigger checksalary
before update
on emp
for each row
begin
  --if 涨后的薪水 < 涨前的薪水 then
 if :new.sal < :old.sal then
   raise_application_error(-20002,'涨后的工资不能小于涨前的工资,涨后的工资为：'||:new.sal||'，涨前的工资为：'||:old.sal) ;
 end if;
end;
/  

/*
触发器应用场景三：数据库的审计—>基于值的审计功能
给员工涨工资，当涨后的薪水超过6000块钱时，审计该员工的信息
*/

--创建表，用于保存审计信息
create table audit_info(
information varchar2(300)
);

create or replace trigger checksal
after update
on emp
for each row
begin
 if :new.sal > 6000 then
   insert into audit_info values (:new.empno||' '||:new.ename||' '||:new.sal);
 end if;

end;
/  

/*
触发器应用场景四：数据的备份和同步
当给员工涨完工资后，自动备份新的工资到备份表中
*/

create table emp_bck as select * from emp;

create or replace trigger sync_salary
after update
on emp
for each row
begin
  --当主表更新后，自动更新备份表
 if :old.sal <> :new.sal then
   update emp_bck set sal = :new.sal where empno = :new.empno;
 end if; 
end;
/