ABAP--新语法--New Keyword in ABAP--第五天--GROUP BY(FOR LOOP)分组 FILTER过滤 EXACT ENUM枚举

最新推荐文章于 2024-07-18 17:38:52 发布
最新推荐文章于 2024-07-18 17:38:52 发布
阅读量2.6k 收藏 16
点赞数 3
分类专栏： ABAP新语法 文章标签： SAP ABAP
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/qq_34060435/article/details/118573311
版权

GROUP BY(FOR LOOP)

在 LOOP 语句中使用 GROUP BY 实现分组处理数据

*---------------------------------------------------------------------*
* 在 LOOP 中使用 GROUP BY 后，LWA_DATA 中不会存储相应的数据，同样，如果使用 FIELD-SYMBOL，
* 也不会被分配，如果需要修改内表数据，只能通过每个组进行修改，对内表数据进行分组时，
* 可通过 ASCENDING / DESCENDING 按组排序，否则按前后的顺序依次输出；
* GROUP BY 在需要使用多个字段进行分组时：GROUP BY  (  KEY1 = field1  KEY2 = field2  …  )
*---------------------------------------------------------------------*
TYPES: BEGIN OF TY_DATA,
         MATNR TYPE MARA-MATNR,
         MTART TYPE MARA-MTART,
         MATKL TYPE MARA-MATKL,
         TEXT1 TYPE CHAR50,
       END OF TY_DATA.

DATA LT_DATA TYPE TABLE OF TY_DATA.

DATA LT_TABLE TYPE TABLE OF TY_DATA.


LT_DATA = VALUE #( ( MATNR = 'Material-001'
                     MTART = 'FOOD'
                     MATKL = '1020'
                     TEXT1 = 'FIRST' )
                   ( MATNR = 'Material-002'
                     MTART = 'WATR'
                     MATKL = '1030'
                     TEXT1 = 'SECOND' )
                   ( MATNR = 'Material-003'
                     MTART = 'WATR'
                     MATKL = '1020'
                     TEXT1 = 'THIRD' ) ).

LOOP AT LT_DATA INTO DATA(LWA_DATA) GROUP BY LWA_DATA-MATKL INTO DATA(G1).
  LT_TABLE = VALUE #( FOR LWA_TABLE IN GROUP G1 ( LWA_TABLE ) ).

  CALL METHOD CL_DEMO_OUTPUT=>DISPLAY( LT_TABLE ).
ENDLOOP.

在这里插入图片描述

*---------------------------------------------------------------------*
* 如果需要根据自定义条件进行分组，可以使用 COND 语句将特定条件转换成字符或数字再进行分组
*---------------------------------------------------------------------*
TYPES: BEGIN OF TY_DATA,
         MATNR TYPE MARA-MATNR,
         MTART TYPE MARA-MTART,
         MATKL TYPE MARA-MATKL,
         TEXT1 TYPE CHAR50,
       END OF TY_DATA.

DATA LT_DATA TYPE TABLE OF TY_DATA.
DATA LT_TABLE TYPE TABLE OF TY_DATA.

LT_DATA = VALUE #( ( MATNR = 'Material-001'
                     MTART = 'FOOD'
                     MATKL = '1020'
                     TEXT1 = 'FIRST' )
                   ( MATNR = 'Material-002'
                     MTART = 'WATR'
                     MATKL = '1030'
                     TEXT1 = 'SECOND' )
                   ( MATNR = 'Material-003'
                     MTART = 'WATR'
                     MATKL = '1010'
                     TEXT1 = 'THIRD' ) ).

LOOP AT LT_DATA INTO DATA(LWA_DATA)
                GROUP BY COND STRING( WHEN LWA_DATA-MATKL = '1020' THEN 'A'
                                      ELSE 'B' ) DESCENDING INTO DATA(G1).

  LT_TABLE = VALUE #( FOR LWA_TABLE IN GROUP G1 ( LWA_TABLE ) ).

  CALL METHOD CL_DEMO_OUTPUT=>DISPLAY( LT_TABLE ).
ENDLOOP.

在这里插入图片描述

*---------------------------------------------------------------------*
*    修改内表数据示例如下，第一层 LOOP 遍历的是每个组，
*      第二层遍历的是对应组里的数据，我们需要在第二层做变更
*---------------------------------------------------------------------*
TYPES: BEGIN OF TY_DATA,
         MATNR TYPE MARA-MATNR,
         MTART TYPE MARA-MTART,
         MATKL TYPE MARA-MATKL,
         TEXT1 TYPE CHAR50,
       END OF TY_DATA.

DATA LT_DATA TYPE TABLE OF TY_DATA.

LT_DATA = VALUE #( ( MATNR = 'Material-001'
                     MATKL = '1020'
                     TEXT1 = 100 )
                   ( MATNR = 'Material-002'
                     MATKL = '1030'
                     TEXT1 = 200 )
                   ( MATNR = 'Material-003'
                     MATKL = '1020'
                     TEXT1 = 300 ) ).

LOOP AT LT_DATA INTO DATA(LWA_DATA) GROUP BY LWA_DATA-MATKL ASCENDING INTO DATA(G1).
  DATA(LV_COUNT) = REDUCE #( INIT LV_INDEX = 0
                             FOR LWA_GROUP IN GROUP G1
                             NEXT LV_INDEX = LV_INDEX + LWA_GROUP-TEXT1 ).
  LOOP AT GROUP G1 ASSIGNING FIELD-SYMBOL(<FS_LINE>).
    <FS_LINE>-TEXT1 = LV_COUNT.
  ENDLOOP.
ENDLOOP.

CALL METHOD CL_DEMO_OUTPUT=>DISPLAY( LT_DATA ).

在这里插入图片描述

FILTER

使用 FILTER 根据条件来过滤内表数据

*---------------------------------------------------------------------*
* 使用 FILTER 时，待过滤的内表结构至少需要有一个用于访问的 SORTED KEY 或 HASHED KEY，
* 否则不能通过语法检查，另外，在 WHERE 条件中运算符两边的字段类型需要完全兼容，否则也不能通过语法检查；
* 根据条件进行过滤的功能可以使用 VALUE 嵌套 FOR 语句实现，而且不用考虑内表的键值问题
*---------------------------------------------------------------------*
TYPES: BEGIN OF TY_DATA,
         MATNR TYPE MARA-MATNR,
         MTART TYPE MARA-MTART,
         MATKL TYPE MARA-MATKL,
         TEXT1 TYPE CHAR50,
       END OF TY_DATA.
DATA:LT_DATA TYPE TABLE OF TY_DATA WITH KEY MATNR WITH NON-UNIQUE SORTED KEY MATKL COMPONENTS MATKL.

LT_DATA = VALUE #( ( MATNR = 'Material-001'
                     MATKL = '1020'
                     TEXT1 = 100 )
                   ( MATNR = 'Material-002'
                     MATKL = '1030'
                     TEXT1 = 200 )
                   ( MATNR = 'Material-003'
                     MATKL = '1020'
                     TEXT1 = 300 ) ).

DATA(LT_FILTER) = FILTER #( LT_DATA USING KEY MATKL WHERE MATKL = CONV MATKL( '1020' ) )."CONV对值进行类型转换
CALL METHOD CL_DEMO_OUTPUT=>DISPLAY( LT_FILTER ).

DATA(LT_FILTER2) = FILTER #( LT_DATA USING KEY MATKL WHERE MATKL > CONV MATKL( '1020' ) )."可以填入比较运算符
CALL METHOD CL_DEMO_OUTPUT=>DISPLAY( LT_FILTER2 ).

在这里插入图片描述

*---------------------------------------------------------------------*
* 参照内表来过滤数据时，被参照的内表仍然需要有 SORTED KEY 或 HASHED KEY，对于过滤数据的内表没有键值要求；
* 在 FILTER 语句中可以通过 EXCEPT 关键字来指定是需要过滤数据还是保留数据；
* 该语法可以实现 FOR ALL ENTRIES IN，但是需要将数据全部取出，影响性能，
* 不建议使用，且在 ABAP 7.52 后，允许将内表作为数据源，可以用来代替 FOR ALL ENTRIES IN 使用
*---------------------------------------------------------------------*
TYPES: BEGIN OF TY_DATA,
         MATNR TYPE MARA-MATNR,
         MTART TYPE MARA-MTART,
         MATKL TYPE MARA-MATKL,
         TEXT1 TYPE CHAR50,
       END OF TY_DATA.
DATA: LT_DATA TYPE SORTED TABLE OF TY_DATA WITH UNIQUE KEY MATNR,
      LT_TEMP TYPE TABLE OF TY_DATA.

LT_DATA = VALUE #( ( MATNR = 'MATERIAL-001' MATKL = '1020' )
                   ( MATNR = 'MATERIAL-002' MATKL = '1030' )
                   ( MATNR = 'MATERIAL-003' MATKL = '1020' ) ).

LT_TEMP = VALUE #( ( MATNR = 'MATERIAL-002' MATKL = '1000' )
                   ( MATNR = 'MATERIAL-002' MATKL = '1040' )
                   ( MATNR = 'MATERIAL-004' MATKL = '1020' ) ).

DATA(LT_FILTER) = FILTER #( LT_TEMP IN LT_DATA WHERE MATNR = MATNR ).
DATA(LT_EXCEPT) = FILTER #( LT_TEMP EXCEPT IN LT_DATA WHERE MATNR = MATNR ).

在这里插入图片描述

EXACT

关键字 EXACT 可以用来检查操作语句返回值是否存在丢失，如果存在丢失则会抛出异常

*---------------------------------------------------------------------*
* 抛出异常的范围比CONV更广，例如将CHAR10的数据赋值到CHAR1时，
* 因此在使用时需要注意异常的捕获，如果没有特殊的处理或属性需求，
* 可以直接使用父类异常 CX_SY_CONVERSION_ERROR 进行捕获.
* 判断数值语句是否被精确计算，如下实际抛出的异常是CX_SY_CONVERSION_ROUNDING，
* 获取到该异常类中的属性字段VALUE的数据
*---------------------------------------------------------------------*

TRY .
    DATA(LV_DATA) = EXACT #( 3 * ( 1 / 3 ) ).
  CATCH CX_SY_CONVERSION_ROUNDING INTO DATA(LO_EXCEPT).
    DATA(LV_RESULT) = LO_EXCEPT->VALUE.
ENDTRY.

在这里插入图片描述

*---------------------------------------------------------------------*
* 字段类型不兼容时，如下实际抛出的异常是 CX_SY_CONVERSION_NO_NUMBER，
* 这里获取的是父类CX_SY_CONVERSION_ERROR中的返回信息
*---------------------------------------------------------------------*
TYPES LTY_NUM TYPE N LENGTH 10.
TRY .
    DATA(LV_NUM) = EXACT LTY_NUM( '4 Apples' ).
  CATCH CX_SY_CONVERSION_ERROR INTO DATA(LO_CONVERT).
    DATA(LV_ERROR) = LO_CONVERT->GET_TEXT( ).
ENDTRY.

在这里插入图片描述

ENUM枚举

ENUM 定义一个结构样式的集合，包含枚举类型的枚举值。如果某个字段参考枚举类型，则字段定义必须为枚举集里面的枚举类型，否则报错。

TYPES:
  BEGIN OF ENUM COLORS1,
    BLACK,
    RED,
    GOLD,
  END OF ENUM COLORS1.
DATA MYCOLOR1 TYPE COLORS1.
MYCOLOR1 = BLACK. "如果此处修改为mycolor1 = orange.则无法激活，报错。


TYPES:
  BEGIN OF ENUM COLORS2 STRUCTURE COLORS2_VALUES,
    RED1,
    WHITE1,
    BLUE1,
  END OF ENUM COLORS2 STRUCTURE COLORS2_VALUES.
DATA MYCOLOR2 TYPE COLORS2.
MYCOLOR2 = COLORS2_VALUES-RED1.


TYPES:
  BEGIN OF ENUM COLORS3 STRUCTURE COLORS3_VALUES BASE TYPE INT1,
    RED2   VALUE IS INITIAL,
    GREEN2 VALUE 42,
    BLUE2  VALUE 255,
  END OF ENUM COLORS3 STRUCTURE COLORS3_VALUES.
DATA MYCOLOR3 TYPE COLORS3.
MYCOLOR3 = COLORS3_VALUES-GREEN2.
尤其是十月的风
关注
  • 3
    点赞
  • 踩
  • 16
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
【ABAP】OPEN SQL（七）「GROUP BY | HAVING | ORDER BY」
Thunder Wang的博客
03-16 5509
各位小伙伴们大家好呀！今天继续SAP ABAP系列文章的讲解，本节带来的内容是OPEN SQL中GROUP BY语句和HAVING语句以及ORDER BY语句的介绍，希望大家喜欢！
ABAP-Swagger:使用Swaggeropenapi规范公开ABAP REST服务
05-18
昂首阔步公开ABAP REST服务的方法用法1：使用公共方法在ABAP中开发课程2：实现接口ZIF_SWAG_HANDLER，并注册公共方法（示例 ） 3：现在可以通过rest访问这些方法（） 4：可以通过REST服务的基本目录中的swagger.html...
ABAP 新语法
sap_abap_kang的博客
07-10 1145
使用此语法，可以省去read,直接读取指定行号的数据，但需要判断gt_data是否有指定index行，需要catch 异常CX_SY_ITAB_LINE_NOT_FOUND异常，否则会直接dump。LT_DATA = CORRESPONDING #( LT_TMP1 FROM LT_TMP2 USING INDEX = INDEX )."from后表的数据传递给前表，按照using后条件操作”与 FOR 语句类似，LET 语句中定义的临时变量同样只能在当前语句中使用，在其他语句中使用时会检查出语法错误。
ABAP group by 语句学习
最新发布
月阴荒的博客
07-18 364
然后回到第一个循环，从第二行FI Consultant 开始，然后可以看到有2个FI Consultant。第一个循环先从第一行 ABAP guru开始 ，然后可以看到有3个 ABAP guru,所以 SIZE = 3 ,这是第一组，所以 index = 1。第一个案例：原文链接：https://blog.csdn.net/lmf496891416/article/details/111317377。然后第二个循环，将组中的数据读出来计算平均年龄，这时候把3个ABAP guru拿出来，计算平均年龄。
ABAP group by 的用法
月阴荒的博客
04-26 2025
即 结合合计函数，根据一个或者多个列对结果集进行分组。我们先解释 group by 的意思。现在我们希望查找每个用户的总金额。
ABAP新语法 LOOP AT ... GROUP BY ...
谁的博客来着？
09-29 907
ABAP新语法 LOOP AT ... GROUP BY ...
ABAP-SDK-for-Azure：用于SAP Azure与Azure服务的本机集成的ABAP库
02-05
5. **事件驱动架构**：ABAP SDK for Azure可以与Azure Event Grid或Service Bus结合，实现事件驱动的架构，让SAP系统能够响应来自Azure的事件，如消息队列中的新消息或特定事件触发的数据更新。 6. **容器化和...
abap新手资料-[sapscript编程指南-].doc
07-13
- 控制命令用于控制表单的布局和逻辑流程，如 NEW-PAGE 分页，PROTECT 限制分页，NEW-WINDOW 创建新窗口，DEFINE 分配文本符号值，SET DATE MASK 和 SET TIME MASK 格式化日期和时间，SET COUNTRY 设置国家相关格式...
abap-advent-2020:abap-advent-2020
04-19
abap-advent-2020-template 2020的-ABAP模板让我们用困难的方式做吧！ 通过在运行的ABAP先决条件已安装NodeJS 12 无需ABAP系统但是，要使ABAP在Node中运行需要大量的耐心，这将涉及对javascript和打字稿代码的调试！...
abap-metrics-provider:让我们使用预定义或自定义指标通过您选择的监视工具来监视abap堆栈
05-17
abap-metrics提供者 兼容性 建筑学 组件图 类图 提供者 刮刀 文件资料 本地测试 本地测试文件夹 影片播放清单 基于 https://github.com/pacroy/abap-prometheus
ABAP loop group by 分组统计/求和
youyousummer的博客
02-23 1372
ABAP 分组统计/求和 loop group by
ABAP新语法之LOOP GROUP BY
matinal 當冬夜漸暖 。公众号：matinal
07-26 6377
TYPES: BEGIN OF ty_customer, customer TYPE char10, NAME TYPE char30, city TYPE char30, route TYPE char10, END OF ty_customer. TYPES: tt_customers TYPE SORTED TABLE OF...
SAP ABAP新语法之LOOP GROUP BY
热门推荐
weixin_40672823的博客
05-18 1万+
通过下面2个实例代码来理解 LOOP GROUP BY 效果测试代码如下： REPORT ZENG_T06. TYPES: BEGIN OF struct, key1 TYPE string, key2 TYPE string, col TYPE i, END OF struct, itab TYPE STANDARD TABLE OF struct WITH EMPTY KEY. DATA(itab) = VALUE itab( ( key1 = `a`
LOOP GROUP BY 分组循环的使用方法小栗子
寒武青锋的博客
12-17 7142
1.格式： LOOP AT 内表 INTO DATA(工作区) GROUP BY ( 字段 = 工作区-字段 size = GROUP SIZE "分组组数-- index = GROUP INDEX ) "分组的组序号 ASCENDING ASSIGNING FIELD-SYMBOL(<组>). LOOP AT GROUP &
SAP ABAP新语法：LOOP AT GROUP
SAP ABAP开发技能记录分享
12-13 911
ABAP新语法：LOOP AT GROUP的使用，以实例为准。
ABAP 分组循环
qq_39128364的博客
07-06 748
ABAP 分类循环的用法 LOOP GROUP BY
ABAP 新语法 LOOP AT Group 和 REDUCE 分组循环
su-george的博客
06-05 5035
*LOOP AT itab result [cond] GROUP BY key ( key1 = dobj1 key2 = dobj2 … * [gs = GROUP SIZE] [gi = GROUP INDEX] ) * [ASCENDING|DESCENDING [AS TEXT]] * [WITHOUT MEMBERS] * [{INTO group}|{ASSIGNING <group>}] * … * [LOOP AT .
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值