gradle自定义任务，修改xml，创建目录

如标题所示，使用gradle对xml进行操作，网上相关的资料非常少，看了例子和官网和查源码才得出解决方案，其中有一些空逻辑，是原先预防vm使用了其他参数的判断，后来直接全删IDEA的Junit启动项了，但还保留着

//初始化项目目录
task initFileStructure(){
    //doFirst在task之前执行
    setGroup("tools")
    doFirst {
        def packagename=project.group.toString().replaceAll("\\.","/")+"/"+project.name.replaceAll("-","")
        def paths = ['src/main/java','src/main/resources','src/test/java','src/test/resources'];
        paths.addAll(
                'src/main/java/'+packagename+'/service',
                'src/main/java/'+packagename+'/config',
                'src/main/java/'+packagename+'/dao',
                'src/main/java/'+packagename+'/utils',
                'src/main/resources/sql',
        )
        //遍历数组，调用createDir闭包，创建目录
        paths.forEach(){path->
            File dir=new File(path);
            if (!dir.exists()){
                print("create "+path+"\n")
                dir.mkdirs();
            }
        };
    }
}

//切换junit使用jmockit驱动
task ideaSwitchJmockit{
    setGroup("tools")
    doLast {
        //查看测试依赖是否使用了jmockit jar包
        def jmockit=configurations.testCompile.find { it.name.contains("jmockit") }
        if (jmockit) {
            //读取idea项目配置
            String fileurl = ".idea/workspace.xml"
            //解析xml
            def workspace = new XmlParser().parse(fileurl)
            //获取属性name为RunManager的标签
            def xmlrunmanager = workspace.find { it.@name == "RunManager" }
            if (xmlrunmanager) {//如果标签存在
                //查找当下所有Junit项，对应idea启动列表
                def xmljunit = xmlrunmanager.value().findAll { it.@type == "JUnit" }
                def temp = []
                def xmlVM_PARAMETERS//区分是否加了jmockit配置
                xmljunit.each {//遍历所有Junit启动项
                    xmlVM_PARAMETERS = it.value().find { option -> option.@name == "VM_PARAMETERS" }
                    temp.add(it)//加到需要删除的队列
                }
                temp.each {//进行删除，直接删除的话会影响xmlJunit的each循环
                    xmlrunmanager.remove(it)//删除Junit启动项，作用是删掉启动参数
                }
                if (xmlVM_PARAMETERS) {//如果有vm参数
                    if (xmlVM_PARAMETERS.@value.find("jmock")) {//且参数有jmock字段
                        file(fileurl).write(groovy.xml.XmlUtil.serialize(workspace))//写入源文件
                        println "success,remove junit jmock"
                    } else {
                        def jvmargs = "-ea -javaagent:${jmockit.absolutePath}"//定制jvm参数
                        xmlVM_PARAMETERS.@value = jvmargs//设置jvm参数
                        file(fileurl).write(groovy.xml.XmlUtil.serialize(workspace))
                        println "success ,switch now junit with jmock"
                    }
                } else {//如果Junit项是空的，就是没有进行过测试
                    def node = new XmlParser().parseText("<configuration default=\"true\" type=\"JUnit\" factoryName=\"JUnit\">\n" +
                            "      <option name=\"MAIN_CLASS_NAME\" value=\"\" />\n" +
                            "      <option name=\"METHOD_NAME\" value=\"\" />\n" +
                            "      <option name=\"VM_PARAMETERS\" value=\"-ea -javaagent:${jmockit.absolutePath}\" />\n" +
                            "      <option name=\"PARAMETERS\" value=\"\" />\n" +
                            "      <method v=\"2\">\n" +
                            "        <option name=\"Make\" enabled=\"true\" />\n" +
                            "      </method>\n" +
                            "    </configuration>")//定义一个子节点，就是默认Junit模板，启动参数加入了Jmockit的jar包
                    xmlrunmanager.append(node)//增加到XML中的运行管理器段下
                    file(fileurl).write(groovy.xml.XmlUtil.serialize(workspace))
                    println "success ,switch now junit with jmock"
                }
            } else println "can't find runmanager xml!"
        }
    }
}