第三章、vb6的ByVal与ByRef详解

日期：2021年04月26日
作者：Commas
注释：网络上没有一个比较系统的VB6或者VBA的教程，于是打算利用中午休息的时间写一写这方面的教程，不喜欢写得很文绉绉，一切都以常用为前提进行介绍。因为要覆盖更多读者，所以本系列文章有些地方可能会介绍比较地通俗易懂，当然也会包含一些比较有意思的知识点，不喜勿喷，有问题敬请指出，有疑惑欢迎留言，大家一起讨论，共同进步，谢谢大家(^ _ ^) (^ _ ^)

---

目录

---

一、函数或过程参数修饰符关键字

修饰符	说明
ByVal	表示修饰的参数按值传递
ByRef	表示修饰的参数按地址传递，ByRef是VB的缺省选项

二、ByVal与ByRef的比较

Option Explicit

Private Sub Form_Load()
    Dim intA As Integer
    
    '初始值为1
    intA = 1
    Debug.Print "初始值--------->intA的地址：" & VarPtr(intA), "intA=" & intA
    
    'ByVal
    Call NumAddOne_ByVal(intA)
    Debug.Print "ByVal之后------>intA的地址：" & VarPtr(intA), "intA=" & intA
    
    'ByRef
    Call NumAddOne_ByRef(intA)
    Debug.Print "ByRef之后------>intA的地址：" & VarPtr(intA), "intA=" & intA
    
End Sub

Sub NumAddOne_ByVal(ByVal intX As Integer)
On Error Resume Next
    intX = intX + 1
    Debug.Print "NumAddOne_ByVal-intX的地址：" & VarPtr(intX), "intX=" & intX
End Sub

Sub NumAddOne_ByRef(ByRef intX As Integer)
On Error Resume Next
    intX = intX + 1
    Debug.Print "NumAddOne_ByRef-intX的地址：" & VarPtr(intX), "intX=" & intX
End Sub

立即窗口（控制台）输出结果：

初始值--------->intA的地址：1701858       intA=1
NumAddOne_ByVal-intX的地址：1701832       intX=2
ByVal之后------>intA的地址：1701858       intA=1
NumAddOne_ByRef-intX的地址：1701858       intX=2
ByRef之后------>intA的地址：1701858       intA=2

1、调用NumAddOne_ByVal，过程外部的intA=1（值未改变）；而调用NumAddOne_ByRef，过程外部的值intA=2（值发生改变）；

2、NumAddOne_ByVal中的intX的地址与intA的地址不一样，应该是开辟了一个新的内存空间，并复制了变量的值，所以过程内部修改，修改的是另外一个内存空间，并不会影响过程外部的变量值；

3、NumAddOne_ByRef中的intX的地址与intA的地址是一样，操作的内存地址是一致的，也就是对同一个内存空间进行操作，那么无论内部或者外部修改，指向该内存空间所有变量的值都会发生改变，如intX=2，打印出来的intA=2；

---

版权声明：本文为博主原创文章，如需转载，请给出：
原文链接：https://blog.csdn.net/qq_35844043/article/details/116150845