bzoj1562 NOI2009变换序列 二分图匹配(匈牙利)

我看见很多人因为题意很繁杂所以直接贴题面，这样是不对滴~~，其实题意没你们想的那么复杂。
题意：给你一个数N，设序列A=0,1，，，，N-1.现在让你求一个T序列。每一个a[i]都可以变为T[i],但是我们定义两个数之间的距离为min(abs(x-y),n-abs(x-y))，现在给出你所有的距离D[I]让你求出T序列。
刚开始我以为直接满足就可以，所以认为直接O(N)扫一遍判断距离的四种情况就可以了。。没想到答案是个0到N-1的序列。
那么我们怎么办呢？
这里我们需要建图，模型参考的BYVOID大神（觉得大神脑洞好大啊）：
抽象成图论模型，建立一个二分图，X集合每个顶点代表0,1,…,N-1的N个整数，Y集合每个顶点为对应的N个整数。X集合的第i个顶点向其环上距离为Di的Y集合中的两个顶点连一条边。样例建图后如图1所示。

其实就是倒着匹配，然后贪心的去最小的，因为如果不可以的话，前面的会自行调整，所以这个算法是正确的。
顺便复习了一下匈牙利算法。。差点忘记了具体细节。。。还好很简单。。

uses math;
var
    i,j,k,p,n,m,tot,x,a,b:longint;
    vis:array[0..10000]of boolean;
    head,go,next,ans,c:array[0..100000]of longint;
function dis(x,y:longint):longint;
begin
        exit(min(abs(x-y),n-abs(x-y)) );
end;
procedure add(x,y:longint);
begin
    inc(tot);
    next[tot]:=head[x];
    head[x]:=tot;
    go[tot]:=y;
end;
function find(x:longint):boolean;
var
    i:longint;
begin
    i:=head[x];
    while i<>0 do
    begin
        if not vis[go[i]] then
        begin
            vis[go[i]]:=true;
            if (c[go[i]]=0)or(find(c[go[i]]))then
            begin
                c[go[i]]:=x;
                exit(true);
            end;
        end;
                i:=next[i];
    end;
    exit(false);
end;
procedure swap(var x,y:longint);
var
        t:longint;
begin
        t:=x;
        x:=y;
        y:=t;
end;
begin
    readln(n);
    for i:=0 to n-1 do
    begin
        read(x);
        a:=i-x+n;
        b:=i+x;
        a:=a mod n;
        b:=b mod n;
                if a<b then swap(a,b);
        if dis(a,i)=x then add(i,a);
        if dis(b,i)=x then add(i,b);
    end;
    for i:=n-1 downto 0 do
    begin
        fillchar(vis,sizeof(vis),0);
        if not find(i) then
        begin
            writeln('No Answer');
            exit;
        end;
    end;
    for i:=0 to n-1 do ans[c[i]]:=i;
    for i:=0 to n-1 do write(ans[i],' ');
end.