PPT演示设置：插入音频&同步切换&播放时长计算

一、 插入音频及音频设置

1.插入音频：点击菜单栏插入-音频-选择PC上的音频（已存在的音频）或者录制音频（现场录制）

2. 点击PPT中音频文件喇叭图标-菜单栏找到播放菜单
① 开始设置为自动
② 勾选放映时隐藏
③ 其它：如果本音频只应用于此页PPT则不要勾选跨幻灯片播放（推荐！）（否则在播放过程中意外导致中断，则只能从头播放，并且当音频内容效果不佳时，分页音频调整起来更加方便）

二、设置页面切换和音频同步

点击菜单栏切换-效果选择无（默认：声音设置为无声音-持续时长为自动）-在换片方式中勾选点击鼠标时和设置自动换片时间，时长设置为音频时长（鼠标放到音频进度条最后会显示时长）

三、播放时长计算

1.手工计算
在切换选项中将每一页的自动换片时间相加。当幻灯片数量较多时，计算起来比较费时间。

2.快速计算
①添加宏：按下 Alt+F11 打开 VBA 编辑器。在VBA 编辑器的菜单栏点击 插入 菜单，选择 模块。在模块窗口中输入代码，然后关闭 VBA 编辑器。

代码如下：

Sub ElapsedTime()
    Dim osld As Slide
    Dim sngTime As Single
    
    ' 遍历所有幻灯片
    For Each osld In ActivePresentation.Slides
        If Not osld.SlideShowTransition.Hidden Then
            sngTime = sngTime + osld.SlideShowTransition.AdvanceTime
        End If
    Next osld
    
    ' 显示总时长
    MsgBox "Total time = " & Int(sngTime / 60) & " mins, " & (sngTime Mod 60) & " seconds."
End Sub

②运行宏：按下 “Alt+F8” 打开 “宏” 对话框，选择相应宏，点击 “运行”，即可弹出显示总时间的消息框。

四、使用宏设置设置页面切换和音频同步

在设置页面切换和音频同步时，同样可使用宏，代码如下。

Sub SetSlideTransitionTime()
    Dim slide As slide
    Dim shape As shape
    Dim audioLength As Single
    
    ' 遍历所有幻灯片
    For Each slide In ActivePresentation.Slides
        audioLength = 0 ' 重置音频时长
        
        ' 遍历幻灯片上的所有对象
        For Each shape In slide.Shapes
            ' 确保对象是多媒体对象（音频或视频）
            If shape.Type = msoMedia Then
                ' 获取音频时长，转换为秒
                audioLength = shape.MediaFormat.Length / 1000
                Exit For ' 只处理第一个音频
            End If
        Next shape
        
        ' 如果找到了音频，则设置自动换片时间
        If audioLength > 0 Then
            With slide.SlideShowTransition
                .AdvanceOnTime = msoTrue ' 启用自动换片
                .AdvanceTime = audioLength ' 设置换片时间
            End With
        End If
    Next slide
    
    MsgBox "已完成所有幻灯片的自动换片时间设置！", vbInformation, "完成"
End Sub