window springboot项目打包脚本.bat

脚本依赖Maven

projectName-deploy.bat

@echo off
set JAVA_HOME=D:\java\javaJDK8.0
set PATH=.;%JAVA_HOME%/bin;%PATH%
call mvn -version

rem 环境菜单提示
REM set ENV_CHOMSG=请选择打包方式:
set ENV_MAVEN_INSTALL_MSG=Maven install jar安装
set ENV_MAVEN_PACKAGE_MSG=项目打包

rem 项目目录
set PROJECT_PARENT=D:\jin\svn\projectName\trunk\projectName-parent
set PROJECT_CORE=projectName-core
set PROJECT_NETWORK=projectName-network

rem 项目部署目录
set PROJECT_DEPLOY=deploy

rem 打包环境选择
:EVNMENU
echo  -------环境选择-----------
echo  1) %ENV_MAVEN_INSTALL_MSG%
echo  2) %ENV_MAVEN_PACKAGE_MSG%
echo  Q) 退出
echo  -------环境选择----------
set /p envchoflg=%ENV_CHOMSG%

if "%envchoflg%" == "1" (goto install)
if "%envchoflg%" == "2" (
	rem 打包起始值
	set BUILD_SWITCH=0
	goto package
)
if "%envchoflg%" == "Q" (goto:eof)
if "%envchoflg%" == "q" (goto:eof)

goto EVNMENU

:package
echo %PROJECT_PARENT%
if not exist %PROJECT_PARENT%\pom.xml (
	echo %PROJECT_PARENT%\ 目录不存在!
	goto EVNMENU
)

echo ----开始 %PROJECT_PARENT% 打包----

call mvn clean package -Dmaven.test.skip=true -f %PROJECT_PARENT%\pom.xml
echo Maven 执行结果错误为：%ERRORLEVEL%
if %ERRORLEVEL%==0 (
	goto build-all
)


:build-all
echo 打包顺序值为 %BUILD_SWITCH%
if %BUILD_SWITCH%==0 (
	set ENV_SOURCE=%PROJECT_CORE%
    set ENV_BUILD=%PROJECT_DEPLOY%\%PROJECT_CORE%-app
	rem 设置下一个执行顺序值
	set BUILD_SWITCH=1
	goto build-task
) else if %BUILD_SWITCH%==1 (
	set ENV_SOURCE=%PROJECT_NETWORK%
	set ENV_BUILD=%PROJECT_DEPLOY%\%PROJECT_NETWORK%-app
	set BUILD_SWITCH=2
	goto build-task
) else (
	echo "========================================================================"
	echo **已全部打包完成或未找到对应的打包顺序值，请核对打包产物后，重新选择菜单**
	echo "========================================================================"
	goto EVNMENU
)

:build-task
if exist %ENV_BUILD% (rd /s /Q %ENV_BUILD%)
md %ENV_BUILD%\bin %ENV_BUILD%\config
echo 拷贝%ENV_SOURCE%\bin至 %ENV_BUILD%\bin
xcopy /E %ENV_SOURCE%\bin %ENV_BUILD%\bin
echo 拷贝%ENV_SOURCE%\config至 %ENV_BUILD%\config
xcopy /E %ENV_SOURCE%\config %ENV_BUILD%\config
echo 拷贝%ENV_SOURCE%\target\*.jar至 %ENV_BUILD%
copy /Y %ENV_SOURCE%\target\*.jar %ENV_BUILD%
echo ----%ENV_BUILD% 打包完成!----
goto build-all

:build-config
if exist %ENV_BUILD% (rd /s /Q %ENV_BUILD%)
md %ENV_BUILD%\config
echo 拷贝%ENV_SOURCE%\bin至 %ENV_BUILD%
xcopy /E %ENV_SOURCE%\bin %ENV_BUILD%
echo 拷贝%ENV_SOURCE%\config至 %ENV_BUILD%\config
xcopy /E %ENV_SOURCE%\config %ENV_BUILD%\config
echo 拷贝%ENV_SOURCE%\target\*.jar至 %ENV_BUILD%
copy /Y %ENV_SOURCE%\target\*.jar %ENV_BUILD%
echo ----%ENV_BUILD% 打包完成!----
goto build-all

:install
echo %PROJECT_PARENT%
if not exist %PROJECT_PARENT%\pom.xml (
	echo %PROJECT_PARENT%\ 目录不存在!
	goto EVNMENU
)

echo ----开始 %PROJECT_PARENT% 打包----

call mvn clean install -Dmaven.test.skip=true -f %PROJECT_PARENT%\pom.xml
echo 执行结果：%ERRORLEVEL%
if %ERRORLEVEL%==0 (
   goto EVNMENU
    
) else (goto error)

:end
echo.&pause&
goto:eof

:error
echo process error!
echo.&pause&
goto:eof