使用 idea 生成实体类代码

最近用idea的插件生成代码挺方便的记录下

配置数据库连接

选择对应数据库后，配置好连接和帐号密码，稍微注意点的是，这个需要配置到库

配置完成后需要刷新下

生成代码

idea自己是有默认的代码生成的，右键表，tools->Scripted Extensions->Generate POJOs.groovy

修改代码生成脚本

idea自带的脚本不太符合我的代码习惯，我稍微做了改动，加入了mybatis-plus和lamda的注释，右键表，tools->Scripted Extensions->Go to script Direcroty，打开脚本文件夹后复制一份脚本进行修改，同样放在同一个文件夹下

import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil
import com.intellij.database.model.ObjectKind
import java.io.*
import java.text.SimpleDateFormat


/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */

packageName = "com.clqd.admin.simple_rpg.web.pojo;"
typeMapping = [
        (~/(?i)tinyint|smallint|mediumint/): "Integer",
        (~/(?i)int/)                       : "Long",
        (~/(?i)bool|bit/)                  : "Boolean",
        (~/(?i)float|double|decimal|real/) : "Double",
        (~/(?i)datetime|timestamp/)        : "Date",
        (~/(?i)date/)                      : "Date",
        (~/(?i)time/)                      : "Date",
        (~/(?i)/)                          : "String"
]

FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = javaName(table.getName(), true)
    def fields = calcFields(table)
    packageName = getPackageName(dir)
    // 这个utf8是解决乱码
    new File(dir, className + ".java").withPrintWriter ("UTF-8"){ out -> generate(out, className, fields,table) }
}

// 获取包所在文件夹路径
static def getPackageName(dir) {
    return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}

def generate(out, className, fields, table) {
    tableName = table.getName();
    out.println "package $packageName"
    out.println ""
    out.println "import com.baomidou.mybatisplus.annotation.IdType;"
    out.println "import com.baomidou.mybatisplus.annotation.TableField;"
    out.println "import com.baomidou.mybatisplus.annotation.TableId;"
    out.println "import com.baomidou.mybatisplus.annotation.TableName;"
    out.println "import java.util.Date;"
    out.println "import java.io.Serializable;"
    out.println "import lombok.Data;"
    out.println "import lombok.AllArgsConstructor;"
    out.println "import lombok.Builder;"
    out.println "import lombok.NoArgsConstructor;"
    out.println ""
    out.println "/**"
    out.println "* @author zjx"
    out.println "*/"
    out.println "@Data"
    out.println "@TableName(\"$tableName\")"
    out.println "@NoArgsConstructor"
    out.println "@AllArgsConstructor"
    out.println "@Builder"
    out.println "public class $className implements Serializable{"
    out.println ""
    out.println "\t@TableField(exist = false)"
    out.println genSerialID()
    out.println ""
    fields.each() {
        // 输出注释
        if (isNotEmpty(it.commoent)) {
            out.println "\t/**"
            out.println "\t * ${it.commoent}"
            out.println "\t */"
        }
        if (it.annos != "") out.println "  ${it.annos}"
        out.println "\tprivate ${it.type} ${it.name};"
    }
    out.println ""
    out.println "}"
}


def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())

        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        def comm =[
                colName : col.getName(),
                name :  javaName(col.getName(), false),
                type : typeStr,
                commoent: col.getComment(),
                annos: ""]
        if("主键".equals(col.getComment().toString()))
            comm.annos +="\t@TableId(type = IdType.AUTO)"
        fields += [comm]
    }
}


def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

static def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

static String genSerialID()
{
    return "\tprivate static final long serialVersionUID =  "+Math.abs(new Random().nextLong())+"L;"
}