文章目录
参考: 【1】Groovy语言学习:groovy语言简介及基本语法
1、类型
- 没有类型的java
- 作为动态语言,groovy中所有的变量都是对象
- 在声明一个变量时,groovy不要求强制类型声明,仅仅要求变量名前使用关键字def(从groovy jsr 1开始,在以前的版本中,甚至连def都不需要)。
def var='栓Q'
//打印方式
println(var)
print var
println var
//查看变量的类型
print var.class
栓Q
栓Q栓Q
class java.lang.String
注:
- groovy中默认的修饰符就是public,所以public修饰符你根本就不需要写,这点跟java不一样
- Groovy中没有语句结束符,当然为了与java保持一致性,你也可以使用;号作为语句结束符。
2、一切皆对象
groovy对于对象是什么类型并不关心,一个变量的类型在运行中随时可以改变,一切根据需要而定。如果你赋给它boolean ,那么不管它原来是什么类型,它接受boolean值之后就会自动把类型转变为boolean值。
def var = "hello "+
"world"+
",groovy!"
println var;
println var.class;
var = 1001
println var.class
hello world,groovy!
class java.lang.String
class java.lang.Integer
3、字符串拼接
// +号拼接不换行,字符串中的格式符都会保留(如:回车、tab、空格)
def var = "hello "+
"world"+
",beijing"
println(var)
//三引号拼接,不需要+号进行连接(不过字符串中的格式符都会被保留,包括回车和tab)
def var2 = """hello
world
,shanghai"""
println(var2)
hello world,beijing
hello
world
,shanghai
4、for循环
“0…3” 表明包含 整数 0、1、2、3。Groovy 还支持排除范围,“0…❤️” 表示 0、1、2。还可以创建字符范围:“a…e” 相当于 a、b、c、d、e。
def var = "hello "+
"world"+
",groovy!"
def repeat(var){
for(i = 0; i < 3; i++){
println(var)
}
}
repeat(var)
println("-------------")
def repeat2(var){
for(i in 0..3){
println(var)
}
}
repeat2(var)
hello world,groovy!
hello world,groovy!
-------------
hello world,groovy!
hello world,groovy!
hello world,groovy!
5、String和Gstring
单引号里面是啥样就打印啥样
双引号里面有引用就打印引用的值
def var = "hello world,groovy!"
def repeat(var){
for(i in 0..2){
println(var) //结果:hello world,groovy!
println('$var') //结果:$var
println("$var:$i") //结果:hello world,groovy!:0
}
}
repeat(var)
def str1 = "编程语言"
def str2 = "Groovy"
println "$str1:$str2" //结果:编程语言:Groovy
println '$str1:$str2' //结果:$str1:$str2
6、默认参数值
可以给方法指定默认参数值
def var = "不想听"
def repeat(var, time = 3){
for(i = 0;i < time;i++){
print(var)
println("$var:$i")
}
}
repeat(var)
结果:
不想听不想听:0
不想听不想听:1
不想听不想听:2
7、集合
Groovy支持最常见的两个java集合:java.util.Collection和java.util.Map
Collection集合
//1、定义
def collect = ["a","b","c"]
//2、增加
collect.add(1);
collect << "come on";
collect[collect.size()] = 100.0 //结果:[a, b, c, 1, come on, 100.0]
//3、索引
println collect[collect.size()-1] //结果:100.0
println collect //结果:[a, b, c, 1, come on, 100.0]
println collect.size() //结果:6
//4、负索引
println collect[-1] //结果:100.0
println collect[-2] //结果:come on
//5、运算:
collect=collect+5 //在集合中添加元素5
println collect[collect.size()-1] //答应最后一个元素
collect=collect-'a' //在集合中减去元素a(第1个)
println collect[0] //现在第1个元素变成b了
//6、往集合中添加另一个集合或删除一个集合:
collect=collect-collect[0..4] //把集合中的前5个元素去掉
println collect[0] //现在集合中仅有一个元素,即原来的最后一个元素
println collect[-1] //也可以用负索引,证明最后一个元素就是第一个元素
Map集合
Map是“键-值”对的集合,在groovy中,键不一定是String,可以是任何对象(实际上Groovy中的Map就是java.util.LinkedHashMap)。
//1、定义一个Map:
def map = ['name':'john','age':14,'sex':'boy']
println map //结果:[name:john, age:14, sex:boy]
//2、添加项:
map = map+['weight':25]
map.put('length',1.27)
map.father='Keller'
println map //结果:[name:john, age:14, sex:boy, weight:25, length:1.27, father:Keller]
//3、两种方式检索值:
println map['father'] //通过key作为下标索引
println map.length //通过key作为成员名索引
8、闭包(Closure)
闭包是用{符号括起来的代码块,它可以被单独运行或调用,也可以被命名。类似‘匿名类’或内联函数。
def map = ['name':'john','age':14,'sex':'boy']
map.each(
{key,value-> // key,value两个参数用于接受每个元素的键/值
println "$key:$value "})
println("------------------")
map.each{println it} //it是一个关键字,代表map集合的每个元素
println("------------------")
map.each({ println it.getKey()+"-->"+it.getValue()})
结果:
name:john
age:14
sex:boy
------------------
name=john
age=14
sex=boy
------------------
name-->john
age-->14
sex-->boy
Result: ['name':'john', 'age':14, 'sex':'boy']
//除了用于迭代之外,闭包也可以单独定义,例如定义一个必包:
def say={word->
println "Hi,$word!"
}
//调用:
say('groovy') //结果:Hi,groovy!
//call是必包的方法
say.call('groovy&grails') //结果:Hi,groovy&grails!
结果:
kk,20
gg,22
9、类
Groovy类和java类一样,你完全可以用标准java bean的语法定义一个groovy 类。但作为另一种语言,我们可以使用更groovy的方式定义和使用类,这样的好处是,你可以少写一半以上的javabean代码:
(1) 不需要public修饰符
如前面所言,groovy的默认访问修饰符就是public,如果你的groovy类成员需要public修饰,则你根本不用写它。
(2) 不需要类型说明
同样前面也说过,groovy也不关心变量和方法参数的具体类型。
(3) 不需要getter/setter方法
不要奇怪,在很多ide(如eclipse)早就可以为序员自动产生getter/setter方法了。在groovy中,则彻底不需要getter/setter方法——所有类成员(如果是默认的public)根本不用通过getter/setter方法引用它们(当然,如果你一定要通过get/set方法访问成员属性,groovy也提供了它们)。
(4) 不需要构造函数
不在需要程序员声明任何构造函数,因为groovy自动提供了足够你使用的构造函数。不用担心构造函数不够多,因为实际上只需要两个构造函数(1个不带参数的默认构造函数,1个只带一个map参数的构造函数—由于是map类型,通过这个参数你可以在构造对象时任意初始化它的成员变量)。
(5) 不需要return
Groovy中,方法不需要return来返回值吗?这个似乎很难理解。看后面的代码吧。
因此,groovy风格的类是这样的:
(6) 不需要()号
Groovy中方法调用可以省略()号(构造函数除外),也就是说下面两句是等同的:
class Person {
def name
def age
String toString(){ //注意方法的类型String,因为我们要覆盖的方法为String类型
"$name,$age"
}
}
// 我们可以使用默认构造方法实例化Person类:
def person1 = new Person()
person1.name='kk'
person1.age=20
println person1
// 也可以用groovy的风格做同样的事:
def person2 = new Person(['name':'gg','age':22]) //[]号可以省略
println person2
10、运算符
?运算符
java中:
if(rs!=null){
rs.next()
...
}
groovy中可以简化成:rs?.next()
三元运算符
通常形式:
String displayName = name != null ? name : "Unknown";
groovy中简化成:
String displayName = name ? name : "Unknown";
基于“不重复”的原则,可以使用elvis操作符再次简化为:
String displayName = name ?: "Unknown"
11、可变长参数
int sum(int... var) {
def total = 0
for (i in var)
total += i
return total
}
//我们可以在调用sum时使用任意个数的参数(1个,2个,3个……):
println sum(1)
println sum(1,2)
println sum(1,2,3)
println sum(1,2,9,10,55)
12、枚举
//1、定义一个enum:
enum Day {
SUNDAY, MONDAY, TUESDAY, WEDNESDAY,
THURSDAY, FRIDAY, SATURDAY
}
//2、然后我们在switch语句中使用他:
def today = Day.SATURDAY
switch (today) {
case [Day.SATURDAY, Day.SUNDAY]:
println "Weekends are cool"
break
case Day.MONDAY..Day.FRIDAY:
println "Boring work day"
break
default:
println "Are you sure this is a valid day?"
}
switch和case中可以使用任何对象,尤其是可以在case中使用List和范围,从而使分支满足多个条件 .
groovy支持带构造器、属性和方法的enum:
enum Planet {
MERCURY(3.303e+23, 2.4397e6),
VENUS(4.869e+24, 6.0518e6),
EARTH(5.976e+24, 6.37814e6),
MARS(6.421e+23, 3.3972e6),
JUPITER(1.9e+27,7.1492e7),
SATURN(5.688e+26, 6.0268e7),
URANUS(8.686e+25, 2.5559e7),
NEPTUNE(1.024e+26, 2.4746e7)
double mass
double radius
Planet(double mass, double radius) {
this.mass = mass;
this.radius = radius;
}
void printMe() {
println "${name()} has a mass of ${mass} " +
"and a radius of ${radius}"
}
}
Planet.EARTH.printMe() //结果:EARTH has a mass of 5.976E24 and a radius of 6378140.0
Planet.JUPITER.printMe() //结果:JUPITER has a mass of 1.9E27 and a radius of 7.1492E7
13、动态性
Groovy所有的对象都有一个元类metaClass,我们可以通过metaClass属性访问该元类。通过元类,可以为这个对象增加方法(在java中不可想象)!
//1、msg是一个String,通过元类,我们为msg增加了一个String 类中所没有的方法up
def msg = "Hello!"
println msg.metaClass
String.metaClass.up = { delegate.toUpperCase() }
println msg.up()
//2、通过元类,我们还可以检索对象所拥有的方法和属性(就象反射):
msg.metaClass.methods.each { println it.name }
msg.metaClass.properties.each { println it.name }
//3、甚至我们可以看到我们刚才添加的up方法。
//4、我们可以通过元类判断有没有一个叫up的方法,然后再调用它:
if (msg.metaClass.respondsTo(msg, 'up')) {
println msg.toUpperCase()
}
//5、当然,也可以推断它有没有一个叫bytes的属性:
if (msg.metaClass.hasProperty(msg, 'bytes')) {
println msg.bytes.encodeBase64()