批处理扫描网段

记录一下批处理扫描网段的方法
先创建一个txt文件，将下面的代码粘贴到TXT文件，然后将文件后缀名改为.bat

@echo off
color F0
rem 設置視窗背景色為白色，文字顏色為黑色
title 批次處理掃網段(By TaoGe)
rem 設置視窗標題
echo.
echo 輸入你要掃描的IP段，直接按回車則為192.168.16：
set /p IpDuan=
rem 將使用者輸入賦值給IpDuan變數
if "%IpDuan%"=="" (set IpDuan=192.168.16)
rem 判斷IpDuan變數是否賦值，如果為空，則賦值為192.168.16
echo 輸入你要掃描的IP起始位元，直接按回車則為1：
set /p QiShi=
rem 將使用者輸入賦值給QiShi變數
if "%QiShi%"=="" (set QiShi=1)
rem 判斷QiShi變數是否賦值，如果為空，則賦值為1
echo 輸入你要掃描的IP結束位元，直接按回車則為255：
set /p JieShu=
rem 將使用者輸入賦值給JieShu變數
if "%JieShu%"=="" (set JieShu=255)
rem 判斷JieShu變數是否賦值，如果為空，則賦值為255
echo 起始IP：%IpDuan%.%QiShi%  
rem 顯示起始IP
echo 結束IP：%IpDuan%.%JieShu%  
rem 顯示結束IP
echo ======================================================= >>Ping-%IpDuan%.txt
rem 記錄分割線
echo 開始時間：%date%%time% >>Ping-%IpDuan%.txt
rem 記錄開始時間
echo 起始IP：%IpDuan%.%QiShi% >>Ping-%IpDuan%.txt  
rem 記錄起始IP
echo 結束IP：%IpDuan%.%JieShu% >>Ping-%IpDuan%.txt 
rem 記錄結束IP
echo 正在掃描，請等待...
echo 提前結束請直接關閉視窗
@for /l %%n in (%QiShi%,1,%JieShu%) do @ping -w 600 -n 1 %IpDuan%.%%n|find  /i "ttl" >>Ping-%IpDuan%.txt
rem 開始執行
echo 結束時間：%date% %time%  >>Ping-%IpDuan%.txt
rem 記錄結束時間
echo ======================================================= >>Ping-%IpDuan%.txt
rem 記錄分割線
echo 掃描完畢,按任意鍵退出...&pause>nul

双击.bat文件，运行如下：
根据自己的需求修改为想要扫描的网段，以192.168.2为例：扫描192.168.2.1到 192.168.2.35的IP段是否ping通，如图：

上图出现扫描完毕，就会创建下图的ping-192.168.2.txt文件夹，打开文件夹可查看ping通的IP。