直接上实验,Bomb Lab的readme基本啥也没有,大概指示是有(6+1)(有一个隐藏的炸弹)个炸弹,看看bomb.c文件,几个函数之间基本没什么关联,这就很好,然后拆炸弹。
之前看了看相关的博客大概是需要汇编和反汇编的知识,之前也没有看过相关的东西,gdb调试好像也不咋会,不过没关系,learn by doing。(有时间专门发一篇博客整理一下做这个实验的学的一些gdb和linux的指令)
首先,将文件放进linux下,然后使用指令objdump –d bomb > bomblab.txt(大概意思是将bomb文件反汇编然后代码输出到bomblab.txt文件里),(这里捎带提一句,可以先cv大法试一下,大部分情况下都是没有问题的,一般不用共享,太麻烦)然后cv回来放进notepad++里,嗯,1700 lines,不慌,大部分都没用。
然后,我到底要干啥了哩?
这里要万分感谢不周山读厚csapp的博客,让我明白bomblab的具体情况,没办法太菜了。文档里又都没咋提及。
主要任务是“拆炸弹”。所谓炸弹,其实就是一个二进制的可执行文件,要求输入六个字符串,每个字符串对应一个phase。如果字符串输入错误,系统就会提示BOOM!!!。
第一关
首先第一个炸弹的代码反汇编如下:
callq 的两行就是调用 strings_not_equal 和 explode_bomb 这两个函数的,而这里 %esi 对应的是第二个参数,第一个参数呢?当然就是我们拆弹时需要输入的字符串了。之后的 test 是用来判断函数的返回值 %eax 是否为 0, 如果为 0 则进行跳转,否则炸弹爆炸,所以我们实际上要做的,就是看看 $0x402400 这个地址里对应存放的是什么字符串,也就是拆炸弹的关键了。(这里我们注意, strings_not_equal 顾名思义就是用来判断相等不相等的,然后大概函数返回了一个值,为0就会跳转,而非0就会通过explode_bomb这个函数来爆炸,发出boom信号。。。肯定不是把电脑炸了。。。)
这里采用了不周山的做法,(虽然好像稍微有点啰嗦,但是对我们初学者来真正了解一些反编译,单步调试的做法很有帮助)
大概是这样,接上文,我们找到了解开炸弹的关键,这里通过 break explode_bomb 和 break phase_1设置了这两个断点,然后通过run指令,随便输入一个密码,(我输入的是aabb),走到下一个断点,通过info registers看到寄存器内容如下
这里稍微注意一下,我们在看不到aabb,因为其实 eax 是 rax 的低位,我们可以直接利用 print $eax 把它打印出来,就会发现,是一个地址,我们再用 x/s $eax 就可以看到我们刚才输入的字符串了。之后单步调试,直到%esi被赋值以后,然后输出结果,见下图机
Border relations with Canada have never been better.(这个就是我的这一关的密码,好像每个人这一关的密码都不一样,这样,第一关就ok了)(注意quit后重新设置断点后输入)
第二关
同样,先给出反编译的代码
0000000000400efc <phase_2>:
400efc: 55 push %rbp
400efd: 53 push %rbx
400efe: 48 83 ec 28 sub $0x28,%rsp
400f02: 48 89 e6 mov %rsp,%rsi
400f05: e8 52 05 00 00 callq 40145c <read_six_numbers>
400f0a: 83 3c 24 01 cmpl $0x1,(%rsp)
400f0e: 74 20 je 400f30 <phase_2+0x34>
400f10: e8 25 05 00 00 callq 40143a <explode_bomb>
400f15: eb 19 jmp 400f30 <phase_2+0x34>
400f17: 8b 43 fc mov -0x4(%rbx),%eax
400f1a: 01 c0 add %eax,%eax
400f1c: 39 03 cmp %eax,(%rbx)
400f1e: 74 05 je 400f25 <phase_2+0x29>
400f20: e8 15 05 00 00 callq 40143a <explode_bomb>
400f25: 48 83 c3 04 add $0x4,%rbx
400f29: 48 39 eb cmp %rbp,%rbx
400f2c: 75 e9 jne 400f17 <phase_2+0x1b>
400f2e: eb 0c jmp 400f3c <phase_2+0x40>
400f30: 48 8d 5c 24 04 lea 0x4(%rsp),%rbx
400f35: 48 8d 6c 24 18 lea 0x18(%rsp),%rbp
400f3a: eb db jmp 400f17 <phase_2+0x1b>
400f3c: 48 83 c4 28 add $0x28,%rsp
400f40: 5b pop %rbx
400f41: 5d pop %rbp
400f42: c3 retq
从函数名可以得知,这一次要读入六个数字 read_six_numbers。
从 cmpl $0x1, (%rsp),看出第一个数字一定是 1,然后跳转到 +24 的位置,然后把 1 移动到 %ebx 中,跳转到 +57 的位置,然后和 5 进行比较,因为 1 比 5 小,所以会跳转到 +31 的位置。
接着是 movslq 语句,这个语句是带符号地把第一个寄存器扩展并复制到第二个寄存器中,所以现在 %rdx 的值也是 1。lea 之后 %eax 等于 0,然后用 cltq 扩展到 64 位(也就是 %rax 等于 0),接着的语句相当于是 %eax = (%rsp) + 4 * %rax 即 %eax 等于 1。然后与自己相加等于乘以 2,现在 %eax 等于 2,然后等于是判断第二个参数((%rsp, %rdx, 4))和 2 是否相等,所以第二个数字是 2。
然后进行循环的累加并返回到 +31 的位置,继续循环。接着就是类似的操作了,最后分析可以得到每次增大一倍,答案就是 1 2 4 8 16 32。(稍微注意一下sscanf函数,百度得知sscanf的参数顺序,然后我们依次用print命令输出调用sscanf()的参数是啥,可以发现最后这6个数依次被存储在了
%rsp, %rsp + 4, %rsp + 8, %rsp + 12, %rsp + 16, %rsp + 20
然后我们回到phase_2,按照流程走一遍(很简单,就在纸上写一下几个寄存器值的变化),题目答案就出来了。
)
这个题目整体还比较简单
第三关
0000000000400f43 <phase_3>:
400f43: 48 83 ec 18 sub $0x18,%rsp
400f47: 48 8d 4c 24 0c lea 0xc(%rsp),%rcx//先将第二个数压入栈中
400f4c: 48 8d 54 24 08 lea 0x8(%rsp),%rdx//再将第一个数压入栈中
400f51: be cf 25 40 00 mov $0x4025cf,%esi
400f56: b8 00 00 00 00 mov $0x0,%eax//这之前是构造栈的内容
400f5b: e8 90 fc ff ff callq 400bf0 <__isoc99_sscanf@plt>//这里调用函数sscanf,返回值放到%eax中
400f60: 83 f8 01 cmp $0x1,%eax//%eax-1
400f63: 7f 05 jg 400f6a <phase_3+0x27>//%eax要大于1,跳转到400f6a处
400f65: e8 d0 04 00 00 callq 40143a <explode_bomb>//这里不用多说调用炸弹函数
400f6a: 83 7c 24 08 07 cmpl $0x7,0x8(%rsp)//第一个参数与7比较
400f6f: 77 3c ja 400fad <phase_3+0x6a>//说明第一个参数小于7,大于7跳转到,400fad
400f71: 8b 44 24 08 mov 0x8(%rsp),%eax,赋值
400f75: ff 24 c5 70 24 40 00 jmpq *0x402470(,%rax,8)//注意这里就是跳转表了,注意基地址
400f7c: b8 cf 00 00 00 mov $0xcf,%eax
400f81: eb 3b jmp 400fbe <phase_3+0x7b>//跳转到400fbe
400f83: b8 c3 02 00 00 mov $0x2c3,%eax
400f88: eb 34 jmp 400fbe <phase_3+0x7b>//跳转到400fbe
400f8a: b8 00 01 00 00 mov $0x100,%eax
400f8f: eb 2d jmp 400fbe <phase_3+0x7b>
400f91: b8 85 01 00 00 mov $0x185,%eax
400f96: eb 26 jmp 400fbe <phase_3+0x7b>
400f98: b8 ce 00 00 00 mov $0xce,%eax
400f9d: eb 1f jmp 400fbe <phase_3+0x7b>
400f9f: b8 aa 02 00 00 mov $0x2aa,%eax
400fa4: eb 18 jmp 400fbe <phase_3+0x7b>
400fa6: b8 47 01 00 00 mov $0x147,%eax
400fab: eb 11 jmp 400fbe <phase_3+0x7b>
400fad: e8 88 04 00 00 callq 40143a <explode_bomb>
400fb2: b8 00 00 00 00 mov $0x0,%eax
400fb7: eb 05 jmp 400fbe <phase_3+0x7b>
400fb9: b8 37 01 00 00 mov $0x137,%eax
400fbe: 3b 44 24 0c cmp 0xc(%rsp),%eax//一个
400fc2: 74 05 je 400fc9 <phase_3+0x86>//相等返回,不等爆炸
400fc4: e8 71 04 00 00 callq 40143a <explode_bomb>
400fc9: 48 83 c4 18 add $0x18,%rsp
400fcd: c3 retq
这个题目需要具体对汇编出来的代码分析一下,具体见注释,
前面构造栈的时候要构造两个参数,0x4025cf这个地址比较奇怪,反汇编出来果然
暴露了我们密码的输入格式,需要输入两个整数,(关于栈帧,大部分的博客都是IA-32的代码,与我们x86-64的系统反编译出来的结果不一样,不过大概意思差不多),因为栈里面放参数都是反着放的,根据分析(具体见注释),我们知道大概,第一个参数(无符号整数)的范围是0-6,所以最后一输入共有7个结果,不过我就不一一列举了,当第一个参数输入的是0时,%eax为$0xcf,之后我们就输入与第二个参数相等的值就可以了,结果为0 207(一共六个结果,还比较好写)
七个结果如下
- 0 207
- 1 707
- 2 256
- 3 389
- 4 206
- 5 682
- 6 327
第四关
一样的开始,这次代码还会涉及到另一个函数func4,具体代码如下:
0000000000400fce <func4>:
400fce: 48 83 ec 08 sub $0x8,%rsp
400fd2: 89 d0 mov %edx,%eax
400fd4: 29 f0 sub %esi,%eax
400fd6: 89 c1 mov %eax,%ecx
400fd8: c1 e9 1f shr $0x1f,%ecx
400fdb: 01 c8 add %ecx,%eax
400fdd: d1 f8 sar %eax
400fdf: 8d 0c 30 lea (%rax,%rsi,1),%ecx
400fe2: 39 f9 cmp %edi,%ecx
400fe4: 7e 0c jle 400ff2 <func4+0x24>
400fe6: 8d 51 ff lea -0x1(%rcx),%edx
400fe9: e8 e0 ff ff ff callq 400fce <func4>
400fee: 01 c0 add %eax,%eax
400ff0: eb 15 jmp 401007 <func4+0x39>
400ff2: b8 00 00 00 00 mov $0x0,%eax
400ff7: 39 f9 cmp %edi,%ecx
400ff9: 7d 0c jge 401007 <func4+0x39>
400ffb: 8d 71 01 lea 0x1(%rcx),%esi
400ffe: e8 cb ff ff ff callq 400fce <func4>
401003: 8d 44 00 01 lea 0x1(%rax,%rax,1),%eax
401007: 48 83 c4 08 add $0x8,%rsp
40100b: c3 retq
而phase_4代码如下:
000000000040100c <phase_4>:
40100c: 48 83 ec 18 sub $0x18,%rsp
401010: 48 8d 4c 24 0c lea 0xc(%rsp),%rcx
401015: 48 8d 54 24 08 lea 0x8(%rsp),%rdx
40101a: be cf 25 40 00 mov $0x4025cf,%esi
40101f: b8 00 00 00 00 mov $0x0,%eax
401024: e8 c7 fb ff ff callq 400bf0 <__isoc99_sscanf@plt>
401029: 83 f8 02 cmp $0x2,%eax
40102c: 75 07 jne 401035 <phase_4+0x29>//这是输入检测,不相等就爆炸,跳转到401035
40102e: 83 7c 24 08 0e cmpl $0xe,0x8(%rsp)//第一个参数小于等于14,不然爆炸
401033: 76 05 jbe 40103a <phase_4+0x2e>//小于等于跳转到40103a
401035: e8 00 04 00 00 callq 40143a <explode_bomb>
40103a: ba 0e 00 00 00 mov $0xe,%edx
40103f: be 00 00 00 00 mov $0x0,%esi
401044: 8b 7c 24 08 mov 0x8(%rsp),%edi
401048: e8 81 ff ff ff callq 400fce <func4>//调用函数
40104d: 85 c0 test %eax,%eax
40104f: 75 07 jne 401058 <phase_4+0x4c>//不等于0爆炸
401051: 83 7c 24 0c 00 cmpl $0x0,0xc(%rsp)//判断第二个参数
401056: 74 05 je 40105d <phase_4+0x51>//这个时候第二个参数必须为0
401058: e8 dd 03 00 00 callq 40143a <explode_bomb>
40105d: 48 83 c4 18 add $0x18,%rsp
401061: c3 retq
第四关的情况和第三关的情况相似
有了上一关的经验,这一关卡就比较好弄了,通过反编译还是要输入两个数字,对输入的两个数进行边界的判断,之后我们看到,这个代码关键是fun的返回值,将fun转换为c语言代码得到:
void func4(int x,int y,int z)
{//x in %rdi,y in %rsi,z in %rdx,t in %rax,k in %ecx
//y的初始值为0,z的初始值为14
int t=z-y;
int k=t>>31;
t=(t+k)>>1;
k=t+y;
if(k>x)
{
z=k-1;
func4(x,y,z);
t=2t;
return;
}
else
{
t=0;
if(k<x)
{
y=k+1;
func4(x,y,z);
t=2*t+1;
return;
}
else
{
return;
}
}
}
这个时候我们带入分析一下第一个参数7是可以的,不过是不是还有别的解,并没有细看,结果如下,
第五关
继续,phase_5的反编译的代码:
401062: 53 push %rbx
401063: 48 83 ec 20 sub $0x20,%rsp
401067: 48 89 fb mov %rdi,%rbx
40106a: 64 48 8b 04 25 28 00 mov %fs:0x28,%rax
401071: 00 00
401073: 48 89 44 24 18 mov %rax,0x18(%rsp)
401078: 31 c0 xor %eax,%eax//%eax求异或,将%eax的值变成0
40107a: e8 9c 02 00 00 callq 40131b <string_length>//这里调用字符串长度的计算函数
40107f: 83 f8 06 cmp $0x6,%eax//这里说明字符串的长度是6
401082: 74 4e je 4010d2 <phase_5+0x70>// 相等跳转到4010d2,不等则爆炸
401084: e8 b1 03 00 00 callq 40143a <explode_bomb>
401089: eb 47 jmp 4010d2 <phase_5+0x70>
40108b: 0f b6 0c 03 movzbl (%rbx,%rax,1),%ecx//此时%rax为0,(%rbx)零扩展到%ecx
40108f: 88 0c 24 mov %cl,(%rsp)//这里%cl是%rcx最低位寄存器传给%rsp
401092: 48 8b 14 24 mov (%rsp),%rdx//传给%rdx
401096: 83 e2 0f and $0xf,%edx//用&析取出cl的值
401099: 0f b6 92 b0 24 40 00 movzbl 0x4024b0(%rdx),%edx//之后再加偏移量之后零扩展
4010a0: 88 54 04 10 mov %dl,0x10(%rsp,%rax,1)//这里%dl是%rdx的最低位寄存器
4010a4: 48 83 c0 01 add $0x1,%rax//一开始为零,一直到6
4010a8: 48 83 f8 06 cmp $0x6,%rax
4010ac: 75 dd jne 40108b <phase_5+0x29>
4010ae: c6 44 24 16 00 movb $0x0,0x16(%rsp)
4010b3: be 5e 24 40 00 mov $0x40245e,%esi//注意这里,将这里的数据看一看发现
4010b8: 48 8d 7c 24 10 lea 0x10(%rsp),%rdi
4010bd: e8 76 02 00 00 callq 401338 <strings_not_equal>//这里是关键,看字符串是否相等
4010c2: 85 c0 test %eax,%eax//看是否为0
4010c4: 74 13 je 4010d9 <phase_5+0x77>
4010c6: e8 6f 03 00 00 callq 40143a <explode_bomb>
4010cb: 0f 1f 44 00 00 nopl 0x0(%rax,%rax,1)//查资料以后,发现是空指令
4010d0: eb 07 jmp 4010d9 <phase_5+0x77>
4010d2: b8 00 00 00 00 mov $0x0,%eax
4010d7: eb b2 jmp 40108b <phase_5+0x29>//跳转到40108b处
4010d9: 48 8b 44 24 18 mov 0x18(%rsp),%rax
4010de: 64 48 33 04 25 28 00 xor %fs:0x28,%rax
4010e5: 00 00
4010e7: 74 05 je 4010ee <phase_5+0x8c>
4010e9: e8 42 fa ff ff callq 400b30 <__stack_chk_fail@plt>
4010ee: 48 83 c4 20 add $0x20,%rsp
4010f2: 5b pop %rbx
4010f3: c3 retq
连续做了几个关卡,确实比较劳累。
但是准备一鼓作气,直接写完这一部分。
分析以后,大概要输入一个字符串,判断是否相等,然后注意到4010bd处调用了判断字符串是否相等的函数,然后这一段复杂的跳转整的自己头有点晕,看了看大概是用低位寄存器的数值,我们单列出一个代码,是比较难以理解和而又比较重要的代码
movzbl (%rbx,%rax,1),%ecx
大概意思是取内存的这个位置的一个字节,然后零拓展到32位,存储到%ecx寄存器里去。
此时根据第二题的经验,%rbx存放的应该是我们input的起始位置(也可以验证一下,问题不大)
0x0000000000401096 <+52>: and $0xf,%edx
把%edx寄存器的高28位清0,只保留低4位。考虑到%edx里存储的是一个字符的ASCII码,我们得到的是这个ASCII码的低4位
然后就是movzbl 0x4024b0(%rdx),%edx
我们反编译的0x4024b0的结果是一个字符串"maduiersnfotvbylSo you think you can stop the bomb with ctrl-c, do you?"
那么思路就清晰了,phase_5接受由六个字符组成的字符串,根据获得每个字符串二进制表示的后半截,以此作为偏移量从0x4024b0处的字符串中获得对应的字母。将这些字母构成的字符串与0x40245e处的字符串(反编译出来是flyers)相比较,如果相等则拆弹成功。剩下的就是查ASCII码表来凑结果了。本人使用了IONEFG,结果如下,
第六关
来到了BOSS关(明面上的boss关),这次的代码巨长
00000000004010f4 <phase_6>:
4010f4: 41 56 push %r14
4010f6: 41 55 push %r13
4010f8: 41 54 push %r12
4010fa: 55 push %rbp
4010fb: 53 push %rbx//将5个寄存器压栈
4010fc: 48 83 ec 50 sub $0x50,%rsp
401100: 49 89 e5 mov %rsp,%r13//注意一开始r13里放的是第一个数字,
401103: 48 89 e6 mov %rsp,%rsi
401106: e8 51 03 00 00 callq 40145c <read_six_numbers>
40110b: 49 89 e6 mov %rsp,%r14//这时放的也是第一个数字
40110e: 41 bc 00 00 00 00 mov $0x0,%r12d
401114: 4c 89 ed mov %r13,%rbp
401117: 41 8b 45 00 mov 0x0(%r13),%eax
40111b: 83 e8 01 sub $0x1,%eax
40111e: 83 f8 05 cmp $0x5,%eax
401121: 76 05 jbe 401128 <phase_6+0x34>
401123: e8 12 03 00 00 callq 40143a <explode_bomb>//不小于等于6就爆炸
401128: 41 83 c4 01 add $0x1,%r12d//r12d里放的是循环计数变量
40112c: 41 83 fc 06 cmp $0x6,%r12d
401130: 74 21 je 401153 <phase_6+0x5f>//相等则跳转
401132: 44 89 e3 mov %r12d,%ebx
401135: 48 63 c3 movslq %ebx,%rax
401138: 8b 04 84 mov (%rsp,%rax,4),%eax
40113b: 39 45 00 cmp %eax,0x0(%rbp)
40113e: 75 05 jne 401145 <phase_6+0x51>//后面的每个数都不能和前面的数相等,
401140: e8 f5 02 00 00 callq 40143a <explode_bomb>
401145: 83 c3 01 add $0x1,%ebx
401148: 83 fb 05 cmp $0x5,%ebx//这里把比较的基准改变了,最终实现了个数互相之间都不相等
40114b: 7e e8 jle 401135 <phase_6+0x41>//跳转回上面变成了双重循环
40114d: 49 83 c5 04 add $0x4,%r13
401151: eb c1 jmp 401114 <phase_6+0x20>//再次跳转
//注意我看的那个人在这里进行了分块处理
401153: 48 8d 74 24 18 lea 0x18(%rsp),%rsi//这里注意一下,代码运行到这里的时候,已经全部输入完毕
//并且这是第6个数,哦,恍然大悟
401158: 4c 89 f0 mov %r14,%rax
40115b: b9 07 00 00 00 mov $0x7,%ecx
401160: 89 ca mov %ecx,%edx
401162: 2b 10 sub (%rax),%edx
401164: 89 10 mov %edx,(%rax)
401166: 48 83 c0 04 add $0x4,%rax
40116a: 48 39 f0 cmp %rsi,%rax
40116d: 75 f1 jne 401160 <phase_6+0x6c>
40116f: be 00 00 00 00 mov $0x0,%esi
401174: eb 21 jmp 401197 <phase_6+0xa3>
401176: 48 8b 52 08 mov 0x8(%rdx),%rdx//这个玩意就是单链表的形成方式
40117a: 83 c0 01 add $0x1,%eax
40117d: 39 c8 cmp %ecx,%eax
40117f: 75 f5 jne 401176 <phase_6+0x82>
401181: eb 05 jmp 401188 <phase_6+0x94>
401183: ba d0 32 60 00 mov $0x6032d0,%edx//注意这东西很奇怪,0x6032d0的结果看一下
401188: 48 89 54 74 20 mov %rdx,0x20(%rsp,%rsi,2)
40118d: 48 83 c6 04 add $0x4,%rsi//第二个参数
401191: 48 83 fe 18 cmp $0x18,%rsi//和最后一个参数
401195: 74 14 je 4011ab <phase_6+0xb7>
401197: 8b 0c 34 mov (%rsp,%rsi,1),%ecx
40119a: 83 f9 01 cmp $0x1,%ecx
40119d: 7e e4 jle 401183 <phase_6+0x8f>
40119f: b8 01 00 00 00 mov $0x1,%eax
4011a4: ba d0 32 60 00 mov $0x6032d0,%edx//注意这东西很奇怪,0x6032d0的结果看一下
4011a9: eb cb jmp 401176 <phase_6+0x82>
4011ab: 48 8b 5c 24 20 mov 0x20(%rsp),%rbx//
4011b0: 48 8d 44 24 28 lea 0x28(%rsp),%rax//
4011b5: 48 8d 74 24 50 lea 0x50(%rsp),%rsi//
4011ba: 48 89 d9 mov %rbx,%rcx
4011bd: 48 8b 10 mov (%rax),%rdx
4011c0: 48 89 51 08 mov %rdx,0x8(%rcx)
4011c4: 48 83 c0 08 add $0x8,%rax
4011c8: 48 39 f0 cmp %rsi,%rax
4011cb: 74 05 je 4011d2 <phase_6+0xde>
4011cd: 48 89 d1 mov %rdx,%rcx
4011d0: eb eb jmp 4011bd <phase_6+0xc9>
4011d2: 48 c7 42 08 00 00 00 movq $0x0,0x8(%rdx)
4011d9: 00
4011da: bd 05 00 00 00 mov $0x5,%ebp
4011df: 48 8b 43 08 mov 0x8(%rbx),%rax
4011e3: 8b 00 mov (%rax),%eax
4011e5: 39 03 cmp %eax,(%rbx)
4011e7: 7d 05 jge 4011ee <phase_6+0xfa>
4011e9: e8 4c 02 00 00 callq 40143a <explode_bomb>
4011ee: 48 8b 5b 08 mov 0x8(%rbx),%rbx
4011f2: 83 ed 01 sub $0x1,%ebp
4011f5: 75 e8 jne 4011df <phase_6+0xeb>
4011f7: 48 83 c4 50 add $0x50,%rsp
4011fb: 5b pop %rbx
4011fc: 5d pop %rbp
4011fd: 41 5c pop %r12
4011ff: 41 5d pop %r13
401201: 41 5e pop %r14
401203: c3 retq
看到了读进来6个数,然后疯狂操作,这题代码量简直要疯掉。读进来六个数以后,我们的数存储在%rsp, %rsp + 4,%rsp + 8, %rsp + 12, %rsp + 16, %rsp + 20,设为a1,a2,a3,a4,a5,a6,接着我们逐指令执行,发现之后的代码依次保证了如下的条件,如果不满足就引爆炸弹:
a1 <= 6; a1 != a2; a1 != a3; a1 != a4; a1 != a5; a1 != a6
然后我们会发现第二次执行和之前差不多,只是条件改成了
a2 <= 6; a2 != a3; a2 != a4; a2 != a5; a2 != a6 ;
所以这一段代码的意思是所有输入的数不能相同,并且都小于等于6.(这个实现的相当漂亮)
然后就基本没有看懂的东西了,代码写了好几张草稿纸,依旧没有什么思路,后面看了看其他人的博客,大概mov 0x8(%rdx),%rdx
在别人的提示下,发现这个玩意好像是个链表
Node* ptr = &A;
ptr = ptr -> next;
大概类似这样的东西,这之后借鉴了别人的博客,看了看大佬们的分块的做法,(上面我写的那部分大概是第一块)
第二块:
401153: 48 8d 74 24 18 lea 0x18(%rsp),%rsi
401158: 4c 89 f0 mov %r14,%rax
40115b: b9 07 00 00 00 mov $0x7,%ecx
401160: 89 ca mov %ecx,%edx
401162: 2b 10 sub (%rax),%edx
401164: 89 10 mov %edx,(%rax)
401166: 48 83 c0 04 add $0x4,%rax
40116a: 48 39 f0 cmp %rsi,%rax
40116d: 75 f1 jne 401160 <phase_6+0x6c>
这一部分原本看的比较迷,但是看了看博客,发现大概这部分是用7减去数组中的值并替换原来的值。(这个时候,我们可以仔细观察一下,这个时候%rsi放最后一个数,然后从第一个数开始进行变化,反复跳转)
然后就是第三部分了,也是问题的关键和异常难以理解的部分
40116f: be 00 00 00 00 mov $0x0,%esi //%esi=0
401174: eb 21 jmp 401197 <phase_6+0xa3>
401176: 48 8b 52 08 mov 0x8(%rdx),%rdx //%rdx=%rdx->next,这里就提示链表节点的问题了
40117a: 83 c0 01 add $0x1,%eax //%eax++
40117d: 39 c8 cmp %ecx,%eax //if %eax=%ecx?
40117f: 75 f5 jne 401176 <phase_6+0x82>//after loop,%rdx=&node(value of input array's element)
401181: eb 05 jmp 401188 <phase_6+0x94>
401183: ba d0 32 60 00 mov $0x6032d0,%edx
401188: 48 89 54 74 20 mov %rdx,0x20(%rsp,%rsi,2)//注意这个时候%rsp已经作为下标了
40118d: 48 83 c6 04 add $0x4,%rsi//自下而上,从1到6
401191: 48 83 fe 18 cmp $0x18,%rsi
401195: 74 14 je 4011ab <phase_6+0xb7>
401197: 8b 0c 34 mov (%rsp,%rsi,1),%ecx //%rsi 作为数组下标存在
40119a: 83 f9 01 cmp $0x1,%ecx
40119d: 7e e4 jle 401183 <phase_6+0x8f>//大于等于1跳转
40119f: b8 01 00 00 00 mov $0x1,%eax //0x1给%eax
4011a4: ba d0 32 60 00 mov $0x6032d0,%edx //看了看0x6032d0,这句好像就给出了数组首地址
4011a9: eb cb jmp 401176 <phase_6+0x82>
按照做了这么多题目的尿性,看一看 0x6032d0,发现简直了
所以这一步的关键目的在于根据输入数组中元素的值取合适的node地址放在%rsp+0x20的一段内存中,所以我们输入6个数,这六个数会构成6个节点,节点序号为1-6.
第四部分这一部分也不太好理解哈
4011ab: 48 8b 5c 24 20 mov 0x20(%rsp),%rbx //存首地址
4011b0: 48 8d 44 24 28 lea 0x28(%rsp),%rax //存次地址
4011b5: 48 8d 74 24 50 lea 0x50(%rsp),%rsi //存尾地址
4011ba: 48 89 d9 mov %rbx,%rcx
4011bd: 48 8b 10 mov (%rax),%rdx // rdx=rax;
4011c0: 48 89 51 08 mov %rdx,0x8(%rcx) // rcx->next=rdx;
4011c4: 48 83 c0 08 add $0x8,%rax//rax=rax->next;
4011c8: 48 39 f0 cmp %rsi,%rax
4011cb: 74 05 je 4011d2 <phase_6+0xde>
4011cd: 48 89 d1 mov %rdx,%rcx
4011d0: eb eb jmp 4011bd <phase_6+0xc9>
这一步骤是在修改%rsp+0x20到%rsp+0x48各个节点的next域,将它们“连”起来。
具体实现就是 值存放地址,重点可以转换成下面的三个C语言代码:
rdx=rax;
rcx->next=rdx;
rax=rax->next;
第五部分(最后一部分)
4011d2: 48 c7 42 08 00 00 00 movq $0x0,0x8(%rdx) //最后一个的next应该为null
4011d9: 00
4011da: bd 05 00 00 00 mov $0x5,%ebp
4011df: 48 8b 43 08 mov 0x8(%rbx),%rax //%rax=%rbx->next
4011e3: 8b 00 mov (%rax),%eax //比较结构体node中第一个值的大小
4011e5: 39 03 cmp %eax,(%rbx)//第二个大于等于第一个
4011e7: 7d 05 jge 4011ee <phase_6+0xfa>//必须大于等于
4011e9: e8 4c 02 00 00 callq 40143a <explode_bomb>
4011ee: 48 8b 5b 08 mov 0x8(%rbx),%rbx
4011f2: 83 ed 01 sub $0x1,%ebp
4011f5: 75 e8 jne 4011df <phase_6+0xeb>
4011f7: 48 83 c4 50 add $0x50,%rsp
4011fb: 5b pop %rbx
4011fc: 5d pop %rbp
4011fd: 41 5c pop %r12
4011ff: 41 5d pop %r13
401201: 41 5e pop %r14
401203: c3 retq
这一部分讲的是把节点按照递减的顺序排列下来,(大致是第二个大于等于第一个,第三个大于等于第二个,依次类推,不满足就爆炸)(这里要万分注意一个情况,node的顺序和我们输入的顺序是相反的)
node3(924)->node4(691)->node5(477)->node6(443)->node1(332)->node2(168)
而我们应该输入4 3 2 1 6 5
第七关(secret_phase)
这个关卡好像已经不算秘密了哈,反编译出来的结果有这部分函数提示,还有不周山的博客提示,所以基本算是众所周知了。话不多说,那么。。。咋进去了哩?
首先放一下secrect的代码
0000000000401242 <secret_phase>:
401242: 53 push %rbx
401243: e8 56 02 00 00 callq 40149e <read_line>//读入函数
401248: ba 0a 00 00 00 mov $0xa,%edx
40124d: be 00 00 00 00 mov $0x0,%esi
401252: 48 89 c7 mov %rax,%rdi
401255: e8 76 f9 ff ff callq 400bd0 <strtol@plt>//将字符串转化为数字
40125a: 48 89 c3 mov %rax,%rbx//rax处存放输入的数字
40125d: 8d 40 ff lea -0x1(%rax),%eax//
401260: 3d e8 03 00 00 cmp $0x3e8,%eax//也就是 1000
401265: 76 05 jbe 40126c <secret_phase+0x2a>//必须跳转,小于等于
401267: e8 ce 01 00 00 callq 40143a <explode_bomb>
40126c: 89 de mov %ebx,%esi
40126e: bf f0 30 60 00 mov $0x6030f0,%edi//gdb查看一下此处的值
401273: e8 8c ff ff ff callq 401204 <fun7>//调用函数
401278: 83 f8 02 cmp $0x2,%eax//结果必须等于2
40127b: 74 05 je 401282 <secret_phase+0x40>
40127d: e8 b8 01 00 00 callq 40143a <explode_bomb>
401282: bf 38 24 40 00 mov $0x402438,%edi//后面没有用gdb查看了,但大概就是一些字符串的输出了
401287: e8 84 f8 ff ff callq 400b10 <puts@plt>
40128c: e8 33 03 00 00 callq 4015c4 <phase_defused>
401291: 5b pop %rbx
401292: c3 retq
401293: 90 nop
401294: 90 nop
401295: 90 nop
401296: 90 nop
401297: 90 nop
401298: 90 nop
401299: 90 nop
40129a: 90 nop
40129b: 90 nop
40129c: 90 nop
40129d: 90 nop
40129e: 90 nop
40129f: 90 nop
整体代码不长,尤其还有一堆nop,应该说代码比较精悍。
那么我们怎么进去那?
首先,从前文用objdumb反汇编的TXT文档中,寻找到唯一提到进入秘密关卡的<phase_defused>函数,代码如下:
00000000004015c4 <phase_defused>:
4015c4: 48 83 ec 78 sub $0x78,%rsp
4015c8: 64 48 8b 04 25 28 00 mov %fs:0x28,%rax
4015cf: 00 00
4015d1: 48 89 44 24 68 mov %rax,0x68(%rsp)
4015d6: 31 c0 xor %eax,%eax
4015d8: 83 3d 81 21 20 00 06 cmpl $0x6,0x202181(%rip)//这里说明只有解开6个炸弹以后,才能打开隐藏函数 # 603760 <num_input_strings>
4015df: 75 5e jne 40163f <phase_defused+0x7b>
4015e1: 4c 8d 44 24 10 lea 0x10(%rsp),%r8
4015e6: 48 8d 4c 24 0c lea 0xc(%rsp),%rcx
4015eb: 48 8d 54 24 08 lea 0x8(%rsp),%rdx
4015f0: be 19 26 40 00 mov $0x402619,%esi//gdb以后发现是%d %d %s
4015f5: bf 70 38 60 00 mov $0x603870,%edi//7 0
4015fa: e8 f1 f5 ff ff callq 400bf0 <__isoc99_sscanf@plt>
4015ff: 83 f8 03 cmp $0x3,%eax//这里还缺少一个字符串
401602: 75 31 jne 401635 <phase_defused+0x71>
401604: be 22 26 40 00 mov $0x402622,%esi//gdb以后发现是"DrEvil"
401609: 48 8d 7c 24 10 lea 0x10(%rsp),%rdi
40160e: e8 25 fd ff ff callq 401338 <strings_not_equal>//看这两个判断就可以直接猜测是在7 0之后加一个DrEvil进入隐藏关卡
401613: 85 c0 test %eax,%eax
401615: 75 1e jne 401635 <phase_defused+0x71>
401617: bf f8 24 40 00 mov $0x4024f8,%edi
40161c: e8 ef f4 ff ff callq 400b10 <puts@plt>
401621: bf 20 25 40 00 mov $0x402520,%edi
401626: e8 e5 f4 ff ff callq 400b10 <puts@plt>
40162b: b8 00 00 00 00 mov $0x0,%eax
401630: e8 0d fc ff ff callq 401242 <secret_phase>
401635: bf 58 25 40 00 mov $0x402558,%edi
40163a: e8 d1 f4 ff ff callq 400b10 <puts@plt>
40163f: 48 8b 44 24 68 mov 0x68(%rsp),%rax
401644: 64 48 33 04 25 28 00 xor %fs:0x28,%rax
40164b: 00 00
40164d: 74 05 je 401654 <phase_defused+0x90>
40164f: e8 dc f4 ff ff callq 400b30 <__stack_chk_fail@plt>
401654: 48 83 c4 78 add $0x78,%rsp
401658: c3 retq
401659: 90 nop
40165a: 90 nop
40165b: 90 nop
40165c: 90 nop
40165d: 90 nop
40165e: 90 nop
40165f: 90 nop
根据注释,使用gdb查看了一些地址,如下图
由此我们知道了大致知道了进隐藏关卡的方式,回顾6个炸弹,发现第3、4、5关均调用了这个__isoc99_sscanf@plt函数。而且这几关关的答案 也为两个数字,不多想,直接暴力法测试,发现实际上是通过第四关进入。
而后我们重新关注一下隐藏关卡的代码,发现一开始就调用 read_line,然后会把内容用 strtol 转成十进制整数然后和 0x3e8(也就是 1000)进行比较,如果小于等于的话就执行 fun7,然后返回值需要等于 2,于是问题就变成,给定一个值,让 fun7 的输出为 2。我们就先来看看 fun7 具体做了什么。
0000000000401204 <fun7>:
401204: 48 83 ec 08 sub $0x8,%rsp
401208: 48 85 ff test %rdi,%rdi
40120b: 74 2b je 401238 <fun7+0x34>//等于0跳转
40120d: 8b 17 mov (%rdi),%edx
40120f: 39 f2 cmp %esi,%edx
401211: 7e 0d jle 401220 <fun7+0x1c>//小于等于跳转,下面的是大于等于
401213: 48 8b 7f 08 mov 0x8(%rdi),%rdi//
401217: e8 e8 ff ff ff callq 401204 <fun7>
40121c: 01 c0 add %eax,%eax//返回值*2
40121e: eb 1d jmp 40123d <fun7+0x39>//结束
401220: b8 00 00 00 00 mov $0x0,%eax
401225: 39 f2 cmp %esi,%edx
401227: 74 14 je 40123d <fun7+0x39>
401229: 48 8b 7f 10 mov 0x10(%rdi),%rdi
40122d: e8 d2 ff ff ff callq 401204 <fun7>
401232: 8d 44 00 01 lea 0x1(%rax,%rax,1),%eax
401236: eb 05 jmp 40123d <fun7+0x39>
401238: b8 ff ff ff ff mov $0xffffffff,%eax
40123d: 48 83 c4 08 add $0x8,%rsp
401241: c3 retq
这大概是一个递归函数,最后表达的大概是这么一个意思
void fun7(Node* node,int value)
{//node in %rdi,value in %rsi,return_value in %eax
//require %eax to be 2(Very important)
int t=node->val;
if(t>value)
{
node=node->left;
fun7(node,value);
return_value=2*return_value;
return;
}
else
{
if(value==t)
{
return;
}
node=node->right;
fun7(node,value);
return_value=0x1+2*return_value;
return;
}
}
或者说,看一下不周山的写法更明确
struct treeNode
{
int data;
struct treeNode* leftChild;
struct treeNode* rightChild;
};
int fun7(struct treeNode* p, int v)
{
if (p == NULL)
return -1;
else if (v < p->data)
return 2 * fun7(p->leftChild, v);
else if (v == p->data)
return 0;
else
return 2 * fun7(p->rightChild, v) + 1;
}
注意通过两个函数可以看到传参数,传递了两个参数,一个数是二叉树的节点,一个是关键的数(我们要输入的数),通过这两个参数来控制递归的结束条件,换句话说,通过gdb看好相应的节点的值,凑好返回2时所需要的递归次数,找到相应的节点,最后得到相应的值。
这里表示的是一个二叉树,其中n1为根节点,nxy为第x层第y个节点。
在这里我们要是想返回值是2,必须通过2*(1+2*0),所以输入的数字须得等于n32节点中的值0x16(22)。
通关!!!
这个实验连续写了几天,几乎是一直在想,一有时间就会去写它,终于在深夜完成了,(最后一点小修小补放在了第二天),通过这个实验,确实看到了自己有很多不足,当然也学到了很多东西,让我确确实实在忙完了其他事情之后真正沉下心来,花了几天做了这个两个实验(也包括上一个哈),当然,这件事的完成也标志着5月的事情已经忙完,(当然5月也过完了),5月很忙,但是所有的任务完成了,(具体质量怎么样还没出结果,当然有些事情心里基本有底了),这个实验的博客让我明白不能有畏难情绪,(一开始没打算写完bomblab,但是最后居然花费了大量时间写完了),当然也有花了几个小时跑出结果的痛快感觉,与A掉算法题的感觉类似,与建模的感觉也类似,说了好多废话哈,华为最近的情况也让我感慨,所谓的开源和科学无国界了,自一开始接触觉得这是世界上最伟大的发明,到现在能够理智地看待一些问题了,这也是进步的体现。
好了,不扯了,空虚感转瞬即逝,英语四级马上来了,gg,还没怎么准备,接下来的时间估计要突击了,之后就是考试周,代码和博客的更新估计都要停掉了,(acm校赛肯定也要准备一下,但还是优先四级和期末考试吧),下次更新估计在暑假了。
革命尚未成功,同志仍需努力。