【ANSYS命令流】通用后处理技术（三）：列表显示结果及输出TXT文本（实例）

列表显示结果

结构变形、应力应变等云图可通过上节图形显示命令实现，此外，ANSYS还支持列表显示结果，方便形成文本满足设计或分析使用。

列表显示结果的相关命令，如下图所示。

实例讲解

BEAM18x系列后处理示例

• 创建模型，定义截面

finish 
/clear 
/prep7
k,1
k,2,5
k,3,5,5
l,1,2
et,1,beam189
keyopt,1,4,2
mp,ex,1,2e11 
mp,prxy,1,0.3
sectype,1,beam,rect
secdata,0.24,0.3,2,2
latt,1,,1,,3,,1 
eno=20							! 定义长度，为变量长度做准备
lesize,all,,,eno
lmesh,all 
dk,1,all
fk,2,fy,-100000.0

• 绘图和列表显示栅格、栅点及积分点信息

secplot,1,1			! 绘制栅格
slist,1,1,,1,all		! 列表显示相关信息

• 求解并进入后处理

finish
/solu
solve 
/post1 				!进入后处理器
!
/eshape,1 		!使用实常数，截面定义或其他信息来形成适用元素的立体显示
plesol,s,eqv		! 单元等效应力
/pnum,sval,1	! 显示节点应力信息
plnsol,s,x  		! 节点x方向应力

prssol,s,comp		! 列出梁单元188/189单元刨面x，xz，xy应力分量
prssol,,prin			

• 获取各单元最大和最小应力值
  • *GET命令几乎可以提取ANSYS数据库中的任何数据，并赋值给全局变量。

*dim,v1,,eno    ! 定义一维数组v1，长度为eno=20
*dim,v2,,eno
*do,i,1,eno		! 开始循环，从1到20
*get,v1(i),secr,i,s,x,max		!赋值各单元最大应力值
*get,v2(i),secr,i,s,x,min
*enddo
!----------------------------------------------------

• 得到各单元各节点截面各角栅点的应力分量Sxx,Sxz,Sxy

csnnum=81
*dim,mysss,,eno,csnnum			! 定义矩阵mysss大小为20X81
*do,i,1,eno
*do,k,1,csnnum
etable,var%k%,ls,k						! 定义单元表以提取角删点结果
*enddo
*do,j,1,csnnum
*get,mysss(i,j),elem,i,etab,var%j%
*enddo
*enddo
!--------------------------------------------------------

• 输出到文件（必须用读入文件方式执行,即/input）
  • 下面命令必须放到txt文件夹中，再以读入的方式执行
    

*cfopen,myres,txt     ! 打开一个txt格式的命令文件为myres
*vwrite
('**********单元最大应力和最小应力---Sxx*********')
*vwrite
('单元号        最大应力          最小应力')
*do,i,1,eno
a1=v1(i)
a2=v2(i)
*vwrite,i,a1,a2
(f6.0,2x,e15.6,5x,e15.6)
*enddo
*vwrite
('**********各单元各节点截面各角栅点应力分量***************')
*do,i,1,eno
*vwrite,i
('单元编号=',f6.0)
*vwrite
('顺序号',8x,'应力')
*do,j,1,csnnum/3
a1=mysss(i,3*j-2)
a2=mysss(i,3*j-1)
a3=mysss(i,3*j)
*vwrite,j,a1,a2,a3
(f6.0,8x,e15.6,2x,e15.6,2x,e15.6)
*enddo
*enddo
*cfclose

---

参考文献

ANSYS命令流学习教程及书籍参考：ANSYS Workbench命令流