源码分析tomcat的启动过程

源码分析tomcat的启动过程

1. 运行tomcat\bin\startup.bat脚本启动tomcat

@echo off

setlocal

rem Guess CATALINA_HOME if not defined
rem 设置一个变量叫CURRENT_DIR，%cd%代表运行当前bat脚本的目录
set "CURRENT_DIR=%cd%"
if not "%CATALINA_HOME%" == "" goto gotHome
set "CATALINA_HOME=%CURRENT_DIR%"
if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
cd ..
set "CATALINA_HOME=%cd%"
cd "%CURRENT_DIR%"
:gotHome
if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
echo The CATALINA_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program
goto end
:okHome
rem EXECUTABLE变量代表catalina.bat这个可执行的脚本文件
set "EXECUTABLE=%CATALINA_HOME%\bin\catalina.bat"

rem Check that target executable exists
if exist "%EXECUTABLE%" goto okExec
echo Cannot find "%EXECUTABLE%"
echo This file is needed to run this program
goto end
:okExec

rem Get remaining unshifted command line arguments and save them in the
set CMD_LINE_ARGS=
:setArgs
if ""%1""=="""" goto doneSetArgs
set CMD_LINE_ARGS=%CMD_LINE_ARGS% %1
shift
goto setArgs
:doneSetArgs

rem 以下这行代码相当于执行了tomcat的路径\bin\catalina.bat脚本，参数为start
call "%EXECUTABLE%" start %CMD_LINE_ARGS%

:end

2. startup.bat查找并调用catalina.bat，传递一个命令行参数start（在dos命令执行catalina.bat start中可以模拟该操作，也可以成功启动tomcat;同理，执行catalina.bat stop就可以关闭tomcat）

3. catalina.bat查找Java命令，用Java命令启动bootstrap.jar包

4.bootstrap.jar包中有org.apache.catalina.startup.Bootstrap主类