Cortex-A9—U-Boot启动流程之链接脚本u-boot.lds详解

要分析 u-boot 的启动流程，首先要找到“入口”，找到第一行程序在哪里。整个程序的入口取决于链接脚本中ENTRY声明的地方(Ps:只有编译 u-boot 以后才会在根目录下出现 u-boot.lds 文件)。
打开 u-boot.lds，内容如下：

1 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
#指定输出可执行文件是32位ARM指令、小端模式的ELF格式。
2 OUTPUT_ARCH(arm)
#指定输出可执行文件的平台为ARM。
3 ENTRY(_start)
#代码入口点（整个u-boot的入口）为_start标号，_start在文件arch/arm/lib/vectors.S中有定义。
4 SECTIONS
#ELF文件由若干段组成。
5 {
6  . = 0x00000000;
#指定可执行image文件的全局入口点，通常在ROM（flash）0x0位置，“.”代表当前位置。
7  . = ALIGN(4);
#表示四字节对齐。
8 .text :
#代码段，上面三行标识是不占任何空间的。
9 {
10  *(.__image_copy_start)
#__image_copy_start被定义在arch/arm/lib/sections.c文件中，对应的头文件为include/asm-generic/sections.h，用零长数组来实现，不占用空间，相当于放了一个符号，u-boot重定位时就是从这个地址开始拷贝的。
#__image_copy_start为u-boot拷贝的首地址，“*”代表直接寻址。
#打开uboot内存映射文件u-boot.map，从该文件中看到某个文件或者函数链接到了哪个地址上。
11  *(.vectors)
# vectors段，位于arch/arm/lib/vectors.S，保存中断向量表。从上图中可以看出vectors段的起始地址也是0x17800000，说明整个uboot的起始地址就是0x17800000。
12  arch/arm/cpu/armv7/start.o (.text*)
#将arch/arm/cpu/armv7/start.s编译出来的代码放到中断向量表后面，*表示所有start.o文件中所有以text开头的段（文本段），这就相当于u-boot代码执行的开始了。
13  *(.text*)
#其他所有的代码段都以四字节对齐放在这里。
14 }
#在外层段.text（默认就有的段）中，第一个内层段是.__image_copy_start段（C源码中自定义的段），第二个内层段是.vectors，这个是上述汇编代码中定义的段，接下来第三个内存段是start.o文件的.text段，第四个是其他所有汇编文件、C文件中的.text段（文本段），其实.__image_copy_start段和.vectors段都不占空间，只是为了给汇编程序或者C程序提供源码的开头地址，然后将arch/arm/cpu/armv7/start.o文件中的文本段单独列出来，是为了将中断向量表放在整个代码的最开头，接下来才是其他所有文件的文本段。
15 . = ALIGN(4);
16 .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
#指定只读数据段。
17 . = ALIGN(4);
18 .data : {
19  *(.data*)
#指定读/写数据段。
20 }
21 . = ALIGN(4);
22 . = .;
23 . = ALIGN(4);
24 .u_boot_list : {
25  KEEP(*(SORT(.u_boot_list*)));
#这个段存放的是u-boot中定义的命令行对应的命令，以及实际执行的函数，详细可以参考U_BOOT_CMD宏定义，这个宏定义其实是定义一个全局结构体，并把全局结构体存放在以.u_boot_list开头的段中，最终这些段都如上述汇聚到.u_boot_list中，结构体中有命令行命令的字符串名字，函数指针，字符串帮助信息等。
26 }
27 . = ALIGN(4);
28 .image_copy_end :
29 {
30  *(.__image_copy_end)
31 }
#u-boot启动之后会将自己拷贝到DDR物理内存的结尾处，拷贝的内容到这个段结束，image_copy_end这个段其实不占用内存空间，只是为了传递拷贝的结束地址给汇编程序，或者C程序。
32 .rel_dyn_start :
33 {
34  *(.__rel_dyn_start)
35 }
36 .rel.dyn : {
37  *(.rel*)
38 }
39 .rel_dyn_end :
40 {
41  *(.__rel_dyn_end)
42 }
43 .end :
44 {
45  *(.__end)
46 }
47 _image_binary_end = .;
#.rel_dyn_start、.rel_dyn_end也是为了传递地址，不占用空间。.rel.dyn段和u-boot的相对地址有关系（uboot通过这个段来解决重定位问题的），u-boot中对函数的调用，以及对全局变量的访问都是通过地址偏移来实现的，u-boot在启动之后会调用relocate_code（汇编函数）把自己拷贝到DDR的靠结尾部分，为的是给linux内核腾出空间，这些都依赖于.rel.dyn段来完成，这个段有一个固定的格式，8个字节为一组，高4字节是一个固定的值0x17，表示存储的是全局变量的Label，如果不是0x17则无效。
#.end段表示的是整个镜像的end，这个段也是个空段，接下来定义的地址常量_image_binary_end也是同样的含义，表示整个uboot镜像的结束。
48 . = ALIGN(4096);
#指定4096扇区对齐（4k对齐）。一般扇区大小为512字节，4096/512=8扇区，也就是说任何8的整数倍的扇区个数都满足4K对齐。
49 .mmutable : {
50  *(.mmutable)
#存放mmu页表。
51 }
52 .bss_start __rel_dyn_start (OVERLAY) : {
#__rel_dyn_start是在C文件中定义的数组名，位于.__rel_dyn_start段，OVERLAY的含义是.__rel_dyn_start段和.bss段使用同一块内存空间，也就是这两个段在物理地址上是重叠的。
#.__rel_dyn_start段主要是u-boot拷贝自己的时候使用，参考u-boot源码可以发现，u-boot拷贝自己之前，基本上都是汇编语句，即使是调用了C函数也没有使用.bss段内的全局变量，唯一的全局结构体gd（也可能不是唯一的）的地址也是存放在r9寄存器中，所以拷贝之前是用不到.bss段的，要用.__rel_dyn_start段，而拷贝之后用不到.__rel_dyn_start段，要用.bss段，所以为了节省内存，这两个段是可以重合的。
53 KEEP(*(.__bss_start));
# __bss_start标号指向bss段的开始位置。
# .bss_start段可以看成一个外层的段，里面只放了一个内层的段，段名是.__bss_start，由于.__bss_start段没有内容，所以.bss_start也没有内容，只是为了在C文件中能过获取接下来的真正有用的段.bss段的起始地址。
54 __bss_base = .;
55 }
56 .bss __bss_base (OVERLAY) : {
57  *(.bss*)
# .bss段。BSS段（Block Started by Symbol）通常是指用于内存程序中未初始化的全局变量的一块内存区域，该段的变量在使用前由系统初始化为0，且该段不在镜像内。
# .bss段是和整个u-boot镜像一起的，gd结构体的mon_len成员（= __bss_start -__bss_end）记录的就是整个u-boot需要占用的内存空间，其中包括了.bss段。
58  . = ALIGN(4);
59  __bss_limit = .;
60 }
61 .bss_end __bss_limit (OVERLAY) : {
62  KEEP(*(.__bss_end));
# .bss_end段是空段，用来传递.bss段的结束地址。
63 }
# .bss_start和.bss_end都不占内存，空间排布上一个位于.bss段开头，一个位于.bss段结尾，作用是把.bss段的开始地址和结束地址传递给C程序。
64 .dynsym _image_binary_end : { *(.dynsym) }
65 .dynbss : { *(.dynbss) }
66 .dynstr : { *(.dynstr*) }
67 .dynamic : { *(.dynamic*) }
68 .plt : { *(.plt*) }
69 .interp : { *(.interp*) }
70 .gnu.hash : { *(.gnu.hash) }
71 .gnu : { *(.gnu*) }
72 .ARM.exidx : { *(.ARM.exidx*) }
73 .gnu.linkonce.armexidx : { *(.gnu.linkonce.armexidx.*) }
#上述是一些其他段。
74 }

u-boot.bin文件的段和实际在内存中的段以及几个地址常量的分布如下图所示：

u-boot相关变量的数值和描述如下表所示：

上表中的一些变量需要最终编译完成后才能确定，表中除了__image_copy_start以外，其他的变量值每次编译的时候可能会变化。