批处理为文件修改系统属性和隐藏属性

方法一：为简单的修改一个文件的属性

1.我的电脑-工具-文件夹选项-查看-高级设置-显示所有文件和文件夹

 

方法二：为简单的修改顽固的系统属性

2.使用批处理命令。将以下代码复制至记事本，改后缀名txt为bat！

使用方法：将文件拖入本文件的图标，它就会自动运行了。

@echo off 
setlocal enabledelayedexpansion 
title 修改系统属性和隐藏属性 
color f0 
mode con: cols=50 lines=25 
if "%~1"=="" ( 
echo 你没有拖入任何磁盘或文件或文件夹 
echo 请把要处理的磁盘或文件或文件夹拖到批处理文件图标 
echo 不要双击启动批处理 
pause 
) 
:loop 
cls 
if "%~1"=="" goto :eof 
if not exist "%~1" (echo 路径不存在)&pause&shift&goto loop 
echo 当前处理的磁盘或文件或文件夹: 
echo %~1 
echo. 
echo 请选择要进行的操作，然后按回车 
echo. 
echo 加系统和隐藏属性……………………………1 
echo 减系统和隐藏属性……………………………2 
echo 不处理…………………………………………3 
echo. 
set /p "c1=选择 (1,2,3) (不输入为!c1!,默认为2):" 
if "!c1!"=="1" (set "d=+") else if "!c1!"=="3" (pause&shift&goto loop) else set "d=-" 
set "a=%~a1" 
if /i "!a:~0,1!"=="d" ( 
echo. 
echo 这是一个文件夹，请选择要进行的操作，然后按回车 
echo. 
echo 只对该文件夹本身……………………………1 
echo 只对该文件夹中的文件夹和文件……………2 
echo 对该目录下的一切的文件夹和文件…………3 
echo. 
set /p "c2=选择 (1,2,3) (不输入为!c2!,默认为1):" 
if "!c2!"=="2" ( 
pushd "%~1" 
for /f "delims=" %%i in ('dir /a /b "%~1"') do attrib.exe !d!s !d!h "%%i" 
popd 
) else if "!c2!"=="3" ( 
for /f "delims=" %%i in ('dir /a /b /s "%~1"') do attrib.exe !d!s !d!h "%%i" 
) else ( 
attrib.exe !d!s !d!h "%~1" 
) 
) else ( 
attrib.exe !d!s !d!h "%~1" 
) 
pause&shift&goto loop

方法三：是为批处理同文件夹下的所有文件的系统属性和隐藏属性

 

3、使用批处理命令。将以下代码复制至记事本，改后缀名txt为bat！

使用方法是：双击打开，按照提示操作。

@echo off 
title 修改文件系统属性和隐藏属性工具
color f0 
mode con: cols=41 lines=25 

:start 
cls 
ECHO ================================ 
ECHO 请选择要进行的操作，然后按回车 
ECHO ———————————————— 
echo 加系统和隐藏属性…………1 
echo. 
echo 减系统和隐藏属性…………2 
echo. 
echo 退出…………………………3 
echo. 
echo. 
@set /p UserSelection=选择 ( 1 , 2 ) 
if %UserSelection% LEQ 3 if %UserSelection% GEQ 1 goto selection 
goto start 

:selection 
@if "%UserSelection%"=="1" set selection=加 
@if "%UserSelection%"=="2" set selection=减 
@if "%UserSelection%"=="3" goto endall 


:name 
cls 
echo. 
echo. 
echo 同目录内所有文件%selection%属性…………回车键 
echo. 
echo 退出………………………………………q 
echo. 
echo 请输入要%selection%属性的文件全名（包括扩展名），如果不在同目录下请输入完整路径： 
set /p name= 
if "%name%"=="q" goto endall 
if not exist %name% goto none 
if "%UserSelection%"=="1" goto add 
if "%UserSelection%"=="2" goto minus 


:none 
cls 
echo. 
echo. 
echo 找不到%name%文件,请确认文件名或者路径正确 
echo. 
echo. 
pause 
goto name 


:add 
attrib -s -h %name% 
attrib +s +h %name% 
goto end 


:minus 
attrib -s -h %name% 

:end 
echo. 
echo 继续为其他文件修改属性…………y 
echo. 
echo. 
@set /p UserSelection2=继续为其他文件修改属性？（ y ，n） 
@if "%UserSelection2%"=="y" goto start 

:endall 
cls 
echo. 
echo. 
echo. 
echo. 
echo. 
echo. 
echo 请按任意键退出！ 
pause>nul

转自：http://hxbabylion.blog.hexun.com/42834787_d.html