数字三角形（顺推2维，逆推，顺推1维）

数字金字塔
Time Limit:1000MS  Memory Limit:65536K
Total Submit:403 Accepted:232
Description
你和权权是一对很好很好的朋友。有一天，你们无聊得很，便上网冲浪，突然在一个叫做USACO的网中找到了一个游戏：《数字金子塔》。游戏规则是这样的：求一个数字金字塔中从最高点开始在底部任意处结束的路径经过数字的和的最大，其中的每一步可以走到下方的点也可以到达右下方的点。例如在下面的例子中，从7 — 3 — 8 — 7 –- 5的路径产生了最大和：30。 
7 
3 8 
8 1 0 
2 7 4 4 
4 5 2 6 5 
你们便约定了谁能计算出最后的值便是赢者。你仰天（天花板）长叹：我能成为赢者吗，要知道权权可是很厉害的哦…… 
Input
第一行输入N（1<=N<=1000），表示数字金字塔行的数目。后面N输入这个数字金字塔，每个数字皆为整数(1<=x<=10000)，每2个整数之间有1个空格。
Output
单独一行输出最后得到的最大的和。
Sample Input
5
7
3 8
8 1 0
2 7 4 4
4 5 2 6 5
Sample Output
30

顺推2维：

var
 a,f:array[1..1000,1..1000]of longint;
 i,j,n,max,ans:longint;
function max1(a,b:longint):longint;
 begin
  if a>b then exit(a);
  exit(b);
 end;
begin
 readln(n);
 for i:=1 to n do
  for j:=1 to i do
  read(a[i,j]);
 f[1,1]:=a[1,1];
 for i:=2 to n do
 f[i,1]:=f[i-1,1]+a[i,1];
 for i:=2 to n do
  for j:=2 to i do
  f[i,j]:=max1(f[i-1,j],f[i-1,j-1])+a[i,j];
 for i:=1 to n do
  if f[n,i]>=max then max:=f[n,i];
  write(max);
end.

转移方程：f[i,j]:=max(f[i-1,j],f[i-1,j-1])+a[i,j];

逆推：

var
 a,f:array[1..1000,1..1000]of longint;
 i,j,n:longint;
function max(a,b:longint):longint;
 begin
  if a>b then exit(a);
  exit(b);
 end;
begin
 read(n);
 for i:=1 to n do
  for j:=1 to i do
  read(a[i,j]);
 for i:=1 to n do
  f[n,i]:=a[n,i];
 for i:=n-1 downto 1 do
  for j:=1 to i do
  f[i,j]:=max(f[i+1,j],f[i+1,j+1])+a[i,j];
 write(f[1,1]);
end.

转移方程:f[i,j]:=max(f[i+1,j],f[i+1,j+1])+a[i,j];

顺推1维:

var
 a:array[1..1000]of longint;
 f:array[1..1000]of longint;
 i,j,n,ans:longint;
function max(a,b:longint):longint;
 begin
  if a>b then exit(a);
  exit(b);
 end;
begin
 read(n);
 for i:=1 to n do
  begin
   for j:=1 to i do
    read(a[j]);
   for j:=i downto 2 do
   f[j]:=max(f[j-1],f[j])+a[j];
   f[1]:=f[1]+a[1];
  end;
 for i:=1 to n do
  if f[i]>=ans then ans:=f[i];
 write(ans);
end.
转移方程:f[j]:=max(f[j-1],f[j])+a[j];