产生数

2002年分区联赛普级组之三 产生数

Time Limit:1000MS  Memory Limit:65536K
Total Submit:55 Accepted:27

Description

给出一个整数 n（n<10^30) 和 k 个变换规则（k<=15）。 
　　规则： 
　　　一位数可变换成另一个一位数： 
　　　规则的右部不能为零。 
　　例如：n=234。有规则（k＝2）： 
　　　　2－> 5 
　　　　3－> 6 
　　上面的整数 234 经过变换后可能产生出的整数为（包括原数）: 
　　　234 
　　　534 
　　　264 
　　　564 
　　共 4 种不同的产生数 
问题： 
　　给出一个整数 n 和 k 个规则。 
求出： 
　　经过任意次的变换（0次或多次），能产生出多少个不同整数。 
　　仅要求输出个数。 

Input

键盘输人，格式为： 
　　n k 
　　x1 y1 
　　x2 y2 
　　... ... 
　　xn yn 

Output

　一个整数（满足条件的个数）：

Sample Input

234 2
2 5
3 6

Sample Output

4

var
 b:array[0..9,0..9]of boolean;
 a:array[0..9]of longint;
 ans:array[0..100]of longint;
 i,j,k,n,x,y,z,m,max:longint;
 s:ansistring;
procedure gj(x:longint);//要用高精度*单精度
 var i,g,s:longint;
 begin
  g:=0;
   for i:=100 downto 1 do
    begin
     s:=ans[i]*x+g;
     ans[i]:=s mod 10;
     g:=s div 10;
    end;
 end;
begin
 readln(s);
 z:=pos(' ',s);
 val(copy(s,z,length(s)-z+1),m);
 delete(s,z,length(s)-z+1);
 fillchar(b,sizeof(b),false);
 for i:=1 to m do
  begin
   readln(x,y);
   b[x,y]:=true;//这是有向图
  end;
 for k:=0 to 9 do//数据不大所以用Floyd算法
  for i:=0 to 9 do
   for j:=0 to 9 do
    if (b[i,k] and b[k,j]) then
     b[i,j]:=true;
 for i:=0 to 9 do
  b[i,i]:=true;//自己可以到自己
 for i:=0 to 9 do
  for j:=0 to 9 do
   if (b[i,j]) then inc(a[i]);//增加从i到j的方法总数
 ans[100]:=1;//出始化
 for i:=1 to length(s) do
  if a[ord(s[i])-48]<>0 then//这句非常重要
   gj(a[ord(s[i])-48]);
 i:=0;
 while (ans[i]=0) do
  inc(i);
 for j:=i to 100 do
  write(ans[j]);
end.