使用oracle发送电子邮件

 

使用oracle的存储过程，调用oracle的相关包，进行电子邮件的发送。实现将有关的信息发送给相关人员的目的。

SQL> exec procsendemail('hello','hello test oracle email','huangxc@hthorizon.com','hxcqu3000@hotmail.com','mail.hthorizon.com',25,1,'huangxc@hthorizon.com','mypassword','','bit 7');

PL/SQL procedure successfully completed

实现过程 PROCSENDEMAIL

CREATE OR REPLACE PROCEDURE PROCSENDEMAIL(P_TXT       VARCHAR2,
                                          P_SUB       VARCHAR2,
                                          P_SENDOR    VARCHAR2,
                                          P_RECEIVER  VARCHAR2,
                                          P_SERVER    VARCHAR2,
                                          P_PORT      NUMBER DEFAULT 25,
                                          P_NEED_SMTP INT DEFAULT 0,
                                          P_USER      VARCHAR2 DEFAULT NULL,
                                          P_PASS      VARCHAR2 DEFAULT NULL,
                                          P_FILENAME  VARCHAR2 DEFAULT NULL,
                                          P_ENCODE    VARCHAR2 DEFAULT 'bit 7')
  AUTHID CURRENT_USER IS
 

  L_CRLF VARCHAR2(2) := UTL_TCP.CRLF;
  L_SENDORADDRESS VARCHAR2(4000);
  L_SPLITE        VARCHAR2(10) := '++';
  BOUNDARY            CONSTANT VARCHAR2(256) := '-----BYSUK';
  FIRST_BOUNDARY      CONSTANT VARCHAR2(256) := '--' || BOUNDARY || L_CRLF;
  LAST_BOUNDARY       CONSTANT VARCHAR2(256) := '--' || BOUNDARY || '--' ||
                                                L_CRLF;
  MULTIPART_MIME_TYPE CONSTANT VARCHAR2(256) := 'multipart/mixed; boundary="' ||
                                                BOUNDARY || '"';
 
  L_FIL                 BFILE;
  L_FILE_LEN            NUMBER;
  L_MODULO              NUMBER;
  L_PIECES              NUMBER;
  L_FILE_HANDLE         UTL_FILE.FILE_TYPE;
  L_AMT                 BINARY_INTEGER := 672 * 3;
  L_FILEPOS             PLS_INTEGER := 1;
  L_CHUNKS              NUMBER;
  L_BUF                 RAW(2100);
  L_DATA                RAW(2100);
  L_MAX_LINE_WIDTH      NUMBER := 54;
  L_DIRECTORY_BASE_NAME VARCHAR2(100) := 'DIR_FOR_SEND_MAIL';
  L_LINE                VARCHAR2(1000);
  L_MESG                VARCHAR2(32767);
 

  TYPE ADDRESS_LIST IS TABLE OF VARCHAR2(100) INDEX BY BINARY_INTEGER;
  MY_ADDRESS_LIST ADDRESS_LIST;
  TYPE ACCT_LIST IS TABLE OF VARCHAR2(100) INDEX BY BINARY_INTEGER;
  MY_ACCT_LIST ACCT_LIST;
  -------------------------------------返回附件源文件所在目录或者名称---------------------------
  FUNCTION GET_FILE(P_FILE VARCHAR2,
                    P_GET  INT) RETURN VARCHAR2 IS   
    L_FILE VARCHAR2(1000);
  BEGIN
    IF INSTR(P_FILE, '/') > 0 THEN     
      IF P_GET = 1 THEN
        L_FILE := SUBSTR(P_FILE, 1, INSTR(P_FILE, '/', -1) - 1);
      ELSIF P_GET = 2 THEN
        L_FILE := SUBSTR(P_FILE, - (LENGTH(P_FILE) - INSTR(P_FILE, '/', -1)));
      END IF;
    ELSIF INSTR(P_FILE, '/') > 0 THEN  
      IF P_GET = 1 THEN
        L_FILE := SUBSTR(P_FILE, 1, INSTR(P_FILE, '/', -1) - 1);
      ELSIF P_GET = 2 THEN
        L_FILE := SUBSTR(P_FILE, - (LENGTH(P_FILE) - INSTR(P_FILE, '/', -1)));
      END IF;
    END IF;
    RETURN L_FILE;
  END;
  ---------------------------------------------删除directory------------------------------------
PROCEDURE DROP_DIRECTORY(P_DIRECTORY_NAME VARCHAR2) IS
 lc_errmsg varchar2(100);
BEGIN
 EXECUTE IMMEDIATE 'drop directory ' || P_DIRECTORY_NAME;
EXCEPTION WHEN OTHERS THEN
 lc_errmsg := substr(sqlerrm,1,100);
 null;
END;
  --------------------------------------------------创建directory-------------------------------
  PROCEDURE CREATE_DIRECTORY(P_DIRECTORY_NAME VARCHAR2,
                             P_DIR            VARCHAR2) IS
  BEGIN
    EXECUTE IMMEDIATE 'create directory ' || P_DIRECTORY_NAME || ' as ''' ||
                      P_DIR || '''';
    EXECUTE IMMEDIATE 'grant read,write on directory ' || P_DIRECTORY_NAME ||
                      ' to public';
    EXCEPTION
    WHEN OTHERS THEN
      RAISE;
  END;
  --------------------------------------------分割邮件地址或者附件地址-----------------------
  PROCEDURE P_SPLITE_STR(P_STR         VARCHAR2,
                         P_SPLITE_FLAG INT DEFAULT 1) IS
    L_ADDR VARCHAR2(254) := '';
    L_LEN  INT;
    L_STR  VARCHAR2(4000);
    J      INT := 0;
  BEGIN
    L_STR := TRIM(RTRIM(REPLACE(REPLACE(P_STR, ';', ','), ' ', ''), ','));
    L_LEN := LENGTH(L_STR);
    FOR I IN 1 .. L_LEN LOOP
      IF SUBSTR(L_STR, I, 1) <> ',' THEN
        L_ADDR := L_ADDR || SUBSTR(L_STR, I, 1);
      ELSE
        J := J + 1;
        IF P_SPLITE_FLAG = 1 THEN
          L_ADDR := '<' || L_ADDR || '>';
          MY_ADDRESS_LIST(J) := L_ADDR;
        ELSIF P_SPLITE_FLAG = 2 THEN
          MY_ACCT_LIST(J) := L_ADDR;
        END IF;
        L_ADDR := '';
      END IF;
      IF I = L_LEN THEN
        J := J + 1;
        IF P_SPLITE_FLAG = 1 THEN
          L_ADDR := '<' || L_ADDR || '>';
          MY_ADDRESS_LIST(J) := L_ADDR;
        ELSIF P_SPLITE_FLAG = 2 THEN
          MY_ACCT_LIST(J) := L_ADDR;
        END IF;
      END IF;
    END LOOP;
  END;
  ------------------------------------------------写邮件头和邮件内容-------------------------
  PROCEDURE WRITE_DATA(P_CONN   IN OUT NOCOPY UTL_SMTP.CONNECTION,
                       P_NAME   IN VARCHAR2,
                       P_VALUE  IN VARCHAR2,
                       P_SPLITE VARCHAR2 DEFAULT ':',
                       P_CRLF   VARCHAR2 DEFAULT L_CRLF) IS
  BEGIN
    UTL_SMTP.WRITE_RAW_DATA(P_CONN, UTL_RAW.CAST_TO_RAW(CONVERT(P_NAME ||
                                                         P_SPLITE ||
                                                         P_VALUE ||
                                                         P_CRLF, 'ZHS16GBK')));
  END;
  ----------------------------------------写MIME邮件尾部----------------------------------------

  PROCEDURE END_BOUNDARY(CONN IN OUT NOCOPY UTL_SMTP.CONNECTION,
                         LAST IN BOOLEAN DEFAULT FALSE) IS
  BEGIN
    UTL_SMTP.WRITE_DATA(CONN, UTL_TCP.CRLF);
    IF (LAST) THEN
      UTL_SMTP.WRITE_DATA(CONN, LAST_BOUNDARY);
    END IF;
  END;

  ----------------------------------------------发送附件-------------------------------------

PROCEDURE ATTACHMENT
(
 CONN         IN OUT NOCOPY UTL_SMTP.CONNECTION,
 MIME_TYPE    IN VARCHAR2 DEFAULT 'text/plain',
 INLINE       IN BOOLEAN DEFAULT TRUE,
 FILENAME     IN VARCHAR2 DEFAULT 't.txt',
 TRANSFER_ENC IN VARCHAR2 DEFAULT '7 bit',
 DT_NAME      IN VARCHAR2 DEFAULT '0'
) IS
 L_FILENAME VARCHAR2(1000);
 lc_errmsg varchar2(100);
BEGIN
 UTL_SMTP.WRITE_DATA(CONN, FIRST_BOUNDARY);
 WRITE_DATA(CONN, 'Content-Type', MIME_TYPE);
 DROP_DIRECTORY(DT_NAME);
 CREATE_DIRECTORY(DT_NAME, GET_FILE(FILENAME, 1));
 L_FILENAME := GET_FILE(FILENAME, 2);
 IF (INLINE) THEN
  WRITE_DATA(CONN, 'Content-Disposition', 'inline; filename="' || L_FILENAME || '"');
 ELSE
  WRITE_DATA(CONN, 'Content-Disposition', 'attachment; filename="' || L_FILENAME || '"');
 END IF;
 IF (TRANSFER_ENC IS NOT NULL) THEN
  WRITE_DATA(CONN, 'Content-Transfer-Encoding', TRANSFER_ENC);
 END IF;

 UTL_SMTP.WRITE_DATA(CONN, UTL_TCP.CRLF);
 IF TRANSFER_ENC = 'bit 7' THEN
  BEGIN
   L_FILE_HANDLE := UTL_FILE.FOPEN(DT_NAME, L_FILENAME, 'r');
    LOOP
    BEGIN
      UTL_FILE.GET_LINE(L_FILE_HANDLE, L_LINE);
     L_MESG := L_LINE || L_CRLF;
     WRITE_DATA(CONN, '', L_MESG, '', '');
    EXCEPTION WHEN OTHERS THEN
     EXIT;
    END;
   END LOOP;
   UTL_FILE.FCLOSE(L_FILE_HANDLE);
   END_BOUNDARY(CONN);
  EXCEPTION WHEN OTHERS THEN
   UTL_FILE.FCLOSE(L_FILE_HANDLE);
   END_BOUNDARY(CONN);
  END;
 ELSIF TRANSFER_ENC = 'base64' THEN
  BEGIN
   L_FILEPOS  := 1;
   L_FIL      := BFILENAME(DT_NAME, L_FILENAME);
   L_FILE_LEN := DBMS_LOB.GETLENGTH(L_FIL);
   L_MODULO   := MOD(L_FILE_LEN, L_AMT);
   L_PIECES   := TRUNC(L_FILE_LEN / L_AMT);
   IF (L_MODULO <> 0) THEN
    L_PIECES := L_PIECES + 1;
   END IF;
   DBMS_LOB.FILEOPEN(L_FIL, DBMS_LOB.FILE_READONLY);
   DBMS_LOB.READ(L_FIL, L_AMT, L_FILEPOS, L_BUF);
   L_DATA := NULL;
   FOR I IN 1 .. L_PIECES LOOP
    L_FILEPOS  := I * L_AMT + 1;
    L_FILE_LEN := L_FILE_LEN - L_AMT;
    L_DATA     := UTL_RAW.CONCAT(L_DATA, L_BUF);
    L_CHUNKS   := TRUNC(UTL_RAW.LENGTH(L_DATA) / L_MAX_LINE_WIDTH);
    IF (I <> L_PIECES) THEN
     L_CHUNKS := L_CHUNKS - 1;
    END IF;
    UTL_SMTP.WRITE_RAW_DATA(CONN, UTL_ENCODE.BASE64_ENCODE(L_DATA));
    L_DATA := NULL;
    IF (L_FILE_LEN < L_AMT AND L_FILE_LEN > 0) THEN
     L_AMT := L_FILE_LEN;
    END IF;
    DBMS_LOB.READ(L_FIL, L_AMT, L_FILEPOS, L_BUF);
   END LOOP;
   DBMS_LOB.FILECLOSE(L_FIL);
   END_BOUNDARY(CONN);
  EXCEPTION WHEN OTHERS THEN
   DBMS_LOB.FILECLOSE(L_FIL);
   END_BOUNDARY(CONN);
   RAISE;
  END;
 END IF;

 DROP_DIRECTORY(DT_NAME);
exception when others then
 lc_errmsg := substr(sqlerrm,1,100);
 null;
END;

  ---------------------------------------------真正发送过程-----------------------------
  PROCEDURE P_EMAIL(P_SENDORADDRESS2   VARCHAR2,
                    P_RECEIVERADDRESS2 VARCHAR2)
   IS
    L_CONN UTL_SMTP.CONNECTION;

    ln_temp  number;
    lc_delimiter char(1);
    lc_utl_file_dir varchar2(100);
  BEGIN
    L_CONN := UTL_SMTP.OPEN_CONNECTION(P_SERVER, P_PORT);
    UTL_SMTP.HELO(L_CONN, P_SERVER);
     IF P_NEED_SMTP = 1 THEN
      UTL_SMTP.COMMAND(L_CONN, 'AUTH LOGIN', '');
      UTL_SMTP.COMMAND(L_CONN, UTL_RAW.CAST_TO_VARCHAR2(UTL_ENCODE.BASE64_ENCODE(UTL_RAW.CAST_TO_RAW(P_USER))));
      UTL_SMTP.COMMAND(L_CONN, UTL_RAW.CAST_TO_VARCHAR2(UTL_ENCODE.BASE64_ENCODE(UTL_RAW.CAST_TO_RAW(P_PASS))));
    END IF;
   UTL_SMTP.MAIL(L_CONN, P_SENDORADDRESS2);
    UTL_SMTP.RCPT(L_CONN, P_RECEIVERADDRESS2);
   UTL_SMTP.OPEN_DATA(L_CONN);

    WRITE_DATA(L_CONN, 'Date', TO_CHAR(SYSDATE, 'yyyy-mm-dd hh24:mi:ss'));
    WRITE_DATA(L_CONN, 'From', P_SENDOR);
    WRITE_DATA(L_CONN, 'To', P_RECEIVER);
    WRITE_DATA(L_CONN, 'Subject', P_SUB);

    WRITE_DATA(L_CONN, 'Content-Type', MULTIPART_MIME_TYPE);
    UTL_SMTP.WRITE_DATA(L_CONN, UTL_TCP.CRLF);
    UTL_SMTP.WRITE_DATA(L_CONN, FIRST_BOUNDARY);
    WRITE_DATA(L_CONN, 'Content-Type', 'text/plain;charset=gb2312');
    UTL_SMTP.WRITE_DATA(L_CONN, UTL_TCP.CRLF);
    WRITE_DATA(L_CONN, '', REPLACE(REPLACE(P_TXT, L_SPLITE, CHR(10)), CHR(10), L_CRLF), '', '');
    END_BOUNDARY(L_CONN);
    IF (P_FILENAME IS NOT NULL) THEN
      P_SPLITE_STR(P_FILENAME, 2);
     select value into lc_utl_file_dir
      from V$PARAMETER
      where name='utl_file_dir';
    if instr(lc_utl_file_dir,'/') > 0 then
       lc_delimiter := '/';
      else
       lc_delimiter := '/';
      end if;

      ln_temp := MY_ACCT_LIST.COUNT;
      FOR K IN 1 .. MY_ACCT_LIST.COUNT LOOP
        ATTACHMENT
        (
         CONN => L_CONN,
         FILENAME => lc_utl_file_dir||lc_delimiter||MY_ACCT_LIST(K),
         TRANSFER_ENC => P_ENCODE, DT_NAME => L_DIRECTORY_BASE_NAME || TO_CHAR(K)
 );
      END LOOP;
    END IF;
   UTL_SMTP.CLOSE_DATA(L_CONN);
    UTL_SMTP.QUIT(L_CONN);
 EXCEPTION
    WHEN OTHERS THEN
      NULL;
      RAISE;

  END;

  ---------------------------------------------------主调过程------------------------------

BEGIN
  L_SENDORADDRESS := '<' || P_SENDOR || '>';
  P_SPLITE_STR(P_RECEIVER);
  FOR K IN 1 .. MY_ADDRESS_LIST.COUNT LOOP
    P_EMAIL(L_SENDORADDRESS, MY_ADDRESS_LIST(K));
  END LOOP;
 
EXCEPTION
  WHEN OTHERS THEN
    RAISE;
END;

 

______________________________________________________________________

转自：　　http://space.itpub.net/195785/viewspace-470387