FindWindow函数的用法

    

函数的声明：

 

Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

 

  这个函数有两个参数，第一个是要找的窗口的类，第二个是要找的窗口的标题。在搜索的时候不一定两者都知道，但至少要知道其中的一个。有的窗口的标题是比较容易得到的，如 " 计算器 " ，所以搜索时应使用标题进行搜索。但有的软件的标题不是固定的，如 " 记事本 " ，如果打开的文件不同，窗口标题也不同，这时使用窗口类搜索就比较方便。如果找到了满足条件的窗口，这个函数返回该窗口的句柄，否则返回 0 。

前面提到的 VB 的 FindWindow() 函数的声明将两个参数都定义为 String 类型，而在实际使用过程中，如果我们忽略某个参数就将该参数的定义又 As String 改为 As Any 。这里的 As Any 相当于 C 语言中的强制类型转换 。例如，如果我们忽略窗口的类，就将定义修改如下：

 

Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As Any, ByVal lpWindowName As String) As Long

 

然后，在调用时使用如下语句：

 

hwndCalc = FindWindow(0&, " 计算器 ")

 

这里的 0& 就表示忽略类名。需要注意的是 FindWindow(0&, " 计算器 ") 和 FindWindow("", " 计算器 ") 有两种完全不同的含义，前者表示忽略窗口的类，而后者表示窗口的类是个空串。类似的，我们也可以忽略标题而搜索指定的类。

从上面的讨论中可以看出，如果要搜索的外部程序的窗口标题比较容易得到，问题是比较简单的。可如果窗口的标题不固定或者根本就没有标题，怎么得到窗口的类呢？如果你安装了 Visual C++ ，你可以使用其中的 Spy++ ( 如果没有 VC++ ，在 VB 的盘上也可以找到 Spy) ，在 Spy++ 中有一个 FindWindow 工具，它允许你使用鼠标选择窗口，然后 Spy++ 会显示这个窗口的类。

 

在 Win32 API 中还有一个 FindWindowEx ，它非常适合寻找子窗口。

用法示例

 

Option Explicit

 

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" ( _

    ByVal lpClassName As String, _

    ByVal lpWindowName As String) As Long

 

Private Declare Function PostMessage Lib "user32" Alias "PostMessageA" ( _

    ByVal hWnd As Long, _

    ByVal wMsg As Long, _

    ByVal wParam As Long, lParam As Any) As Long

   

Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" ( _

    ByVal hWnd As Long, _

    ByVal lpClassName As String, _

    ByVal nMaxCount As Long) As Long

   

Private Declare Function ShowWindow Lib "user32" ( _

    ByVal hWnd As Long, _

    ByVal nCmdShow As Long) As Long

   

Const SW_SHOWNORMAL = 1

Const WM_CLOSE = &H10

 

 

Public Sub test()

    Dim hWnd As Long

   

    ' 不知道类名

    hWnd = FindWindow(vbNullString, " 计算器 ")

    Debug.Print hWnd

End Sub

 

Public Sub test2()

    Dim hWnd As Long

   

    ' 知道计算器窗口的类名是 : SciCalc

    hWnd = FindWindow("SciCalc", vbNullString)

    Debug.Print hWnd

End Sub

 

Public Sub Test3()

 

    Dim hWnd As Long

    Dim lpClassName As String

    Dim retVal As Long

   

    hWnd = FindWindow(vbNullString, " 计算器 ")

    If hWnd = 0 Then MsgBox "Couldn't find the window ...": Exit Sub

   

    'Show the window

    ShowWindow hWnd, SW_SHOWNORMAL

   

    'Create a buffer

    lpClassName = Space(256)

   

    'retrieve the class name

    retVal = GetClassName(hWnd, lpClassName, 256)

   

    'Show the classname

    Debug.Print "Classname: " + Left(lpClassName, retVal)

   

    'Post a message to the window to close it

    PostMessage hWnd, WM_CLOSE, 0&, 0&

End Sub