自已编写的批处理用于Win11系统右键菜单风格切换

直接使用命令切换

切换到经典右键菜单

以下是两条命令，请一条一条地复制到命令提示符里运行：

reg add "HKCU\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}\InprocServer32" /f /ve
taskkill /f /im explorer.exe & start explorer.exe

切换回 windows 11 风格的右键菜单

以下是两条命令，请一条一条地复制到命令提示符里运行：

reg delete "HKCU\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}" /f
taskkill /f /im explorer.exe & start explorer.exe 

批处理源码

以下源码为本人原创，网友们可以随意使用但不能主张原创权利。

将以下文本保存为纯文本文件，文件的扩展名为 .bat ，双击即可运行

@echo off
setlocal enabledelayedexpansion

reg query "HKCU\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}\InprocServer32" /ve > NUL 2>&1
if !errorlevel! neq 0 (
    echo 当前为新风格菜单，是否切换为经典风格？

    choice /c yn /n /m "输入 y 切换为经典风格，输入 n 直接退出"
    if !errorlevel! equ 1 (
        echo 将系统右键菜单改为经典风格
        reg add "HKCU\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}\InprocServer32" /f /ve
        taskkill /f /im explorer.exe & start explorer.exe
    ) else (
        goto :eof
    )
) else (
    echo 当前为经典风格菜单，是否切换为新风格？

    choice /c yn /n /m "输入 y 切换为新风格，输入 n 直接退出"
    if !errorlevel! equ 1 (
        echo 将系统右键菜单改为新风格
        reg delete "HKCU\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}" /f
        taskkill /f /im explorer.exe & start explorer.exe
    )  else (
        goto :eof
    )
)

pause
endlocal

windows 11 新风格的右键菜单

传统/经典风格的右键菜单

原理

就是如果存在注册表项 HKCU\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}\InprocServer32 windows 11 就会显示经典的右键菜单，否则就是新风格的右键菜单。

批处理就是使用 reg.exe 命令进行该注册表项的添加和删除来实现切换的。