VBA之正则表达式（20）-- 规格数据（正负偏差）拆分

实例需求：规格数据保存在第一列，其中包含多种不同格式，现在需要拆分为三列：主尺寸、负偏差和正偏差。

• 无偏差数据的填入0
• 负偏差列加入负号
• 偏差数据为简写小数需要补全小数点之前的零（A6和A7）
• ±偏差数据分别写入负偏差和正偏差列
• 对于正负偏差分别给出的数据，需要符合负偏差在前，正偏差在后的形式

示例代码如下：

Sub Demo()
    Dim regExp As Object, aRes
    Set regExp = CreateObject("vbscript.regExp")
    regExp.Global = True
    regExp.Pattern = "^([\d.]+)(?:\-([\d.]+))?(?:\+([\d.]+))?(?:±([\d.]+))?"
    arr = [a1].CurrentRegion.Value
    For i = 2 To UBound(arr)
        aRes = Split(regExp.Replace(arr(i, 1), "$1 -0$2$4 0$3$4"))
        For j = 0 To 2
            arr(i, j + 2) = aRes(j)
        Next
    Next
    [a1].CurrentRegion.Value = arr
    Set regExp = Nothing
End Sub

【代码解析】
第3行代码创建正则表达式对象。
第5行代码设置匹配模式。

正则表达式	说明
^([\d.]+)	匹配开始位置的数字和小数点组成的一位或者多位数字，即主尺寸数据为第一个捕获组
\-([\d.]+)	用于匹配负偏差，第二个捕获组只包含负偏差的数字部分，不包含负号
(?:\-([\d.]+))?	设置非捕获分组，末尾的问号说明负偏差可以省略
(?:\+([\d.]+))?	设置非捕获分组，用于匹配正偏差，其中([\d.]+))提取第三个捕获组
(?:±([\d.]+))?	设置非捕获分组，用于匹配正负偏差，其中([\d.]+))提取第四个捕获组

第6行代码将数据表加载至数组中。
第7~12行代码循环处理规格数据。
第8行代码使用正则替换，然后利用SPLIT函数进行拆分。

正则表达式	说明
$1	主尺寸
-0$2$4	负偏差，增加负号和小数点之前补零
0$3$4	正偏差，小数点之前补零

此示例正则规则的几个需要注意的要点如下：

• 由于正负偏差不会和单独的正偏差或者负偏差同时存在，所以$3$4并不会导出偏差数据重复。
• 正则替换时捕获组可以多次使用，如$4
• 在正则替换时添加负偏差的负号，而不是在提取捕获组时获取（(?:(\-[\d.]+))?），是为了能够正确处理如A7数据的83-.3，否则替换后负偏差的结果将变为0-.3.
• 替换的结果，三部分数据使用空格分隔，以便于使用SPLIT函数进行拆分。

第9~11行代码将拆分结果写入数组中。
第13行代码将结果回写到工作表中。
第14行代码清空对象变量，释放系统资源。