VBA之正则表达式（45）-- 提取SQL语句中的函数

实例需求：数据工程师或者DBA日常工作中大量使用SQL语句，有些语句（或者存储过程）行数非常多，现在需要提取其中的所有使用了函数的相关部分，对于如下语句，需要提取Mid([编号],2,4) AS [产品]和datediff("D",[购买日期],"2024-01-01") AS [日期]两个字符串。

SELECT "河北省" AS [省份], Mid([编号],2,4) AS [产品], [类别] AS [品类], [数量], datediff("D",[购买日期],"2024-01-01") AS [日期] FROM Table

示例代码如下。

Sub Demo()
    Dim objRegExp As Object, objMHs As Object, objMH As Object
    Dim sText As String
    sText = ActiveSheet.Range("A1")
    Set objRegExp = CreateObject("vbscript.regexp")
    objRegExp.IgnoreCase = True
    objRegExp.Global = True
    objRegExp.MultiLine = False
    objRegExp.Pattern = "SELECT|FROM.*"
    sText = objRegExp.Replace(sText, "")
    objRegExp.Pattern = "\s+(\w+\(.+?\)[^,]+)"
    Set objMHs = objRegExp.Execute(sText)
    For Each objMH In objMHs
        Debug.Print objMH
    Next
    Set objRegExp = Nothing
End Sub

【代码解析】
第4行代码从A1单元格读取SQL语句。
第5行代码创建正则对象。
第6行代码设置正则匹配忽略字符大小写。
第7行代码设置全局匹配。
第7行代码设置单行匹配。
第9行代码设置正则匹配模式。
第10行代码执行正则替换，只保留SELECT之后，FROM之前的字符串，这样可以使用简洁的匹配模式提取相关内容。
第11行代码设置正则匹配模式。

正则表达式	说明
\s+	匹配一个或者多个白字符
\w+	匹配一个或者多个英文字母或者数字
\(.+?\)	匹配圆括号包裹的任意多个字符
[^,]+	匹配不包含逗号的一个或者多个字符

运行代码，【立即窗口】中输出结果如下。

 Mid([编号],2,4) AS [产品]

 datediff("D",[购买日期],"2024-01-01") AS [日期] 

匹配结果如下图所示。