Hive数据表操作(DDL)

一、创建表

1、建表语法

CREATE [EXTERNAL] TABLE [IF NOT EXISTS] table_name

[(col_name data_type [COMMENT col_comment], ...)]

[COMMENT table_comment]

[PARTITIONED BY (col_name data_type [COMMENT col_comment], ...)]

[CLUSTERED BY (col_name, col_name, ...)

[ROW FORMAT row_format]

[LOCATION hdfs_path]

2、字段说明

（1）CREATE TABLE 创建一个指定名字的表。如果相同名字的表已经存在，则抛出异常；用户可以用 IF NOT EXISTS 选项来忽略这个异常。

（2）EXTERNAL关键字可以让用户创建一个外部表，在建表的同时指定一个指向实际数据的路径（LOCATION），Hive创建内部表时，会将数据移动到数据仓库指向的路径；若创建外部表，仅记录数据所在的路径，不对数据的位置做任何改变。在删除表的时候，内部表的元数据和数据会被一起删除，而外部表只删除元数据，不删除数据。

（3）COMMENT：为表和列添加注释。

（4）PARTITIONED BY创建分区表

（5）CLUSTERED BY创建分桶表

（6）ROW FORMAT

DELIMITED [FIELDS TERMINATED BY char] [COLLECTION ITEMS TERMINATED BY char]

[MAP KEYS TERMINATED BY char] [LINES TERMINATED BY char]

在建表的时候，用户需要为表指定列，用户在指定表的列的同时也会指定分隔符，Hive通过分隔符确定表的具体的列的数据。

row format delimited fields terminated by ‘,’  — 列分隔符

collection items terminated by ‘_’   –MAP STRUCT 和 ARRAY 的分隔符

map keys terminated by ‘:’ — MAP中的key与value的分隔符

lines terminated by ‘\n’; — 行分隔符

（7）LOCATION ：指定表在HDFS上的存储位置。

二、管理表

1）理论

默认创建的表都是所谓的管理表，有时也被称为内部表。因为这种表，Hive会（或多或少地）控制着数据的生命周期。Hive默认情况下会将这些表的数据存储在由配置项hive.metastore.warehouse.dir(例如，/user/hive/warehouse)所定义的目录的子目录下。    当我们删除一个管理表时，Hive也会删除这个表中数据。管理表不适合和其他工具共享数据。

2）案例实操

（1）普通创建表

create table if not exists student(
id int, name string
)
row format delimited fields terminated by '\t';

（2）根据查询结果创建表（查询的结果会添加到新创建的表中）

create table if not exists student01
as select id, name from student;

（3）根据已经存在的表结构创建表

create table if not exists student2 like student;

（4）查询表的类型

desc formatted student2;

 数据上传与结果查询

load data local inpath '/usr/local/data/student.txt' into table student;

select * from student;

三、外部表

1）理论

因为表是外部表，所以Hive并非认为其完全拥有这份数据。删除该表并不会删除掉这份数据，不过描述表的元数据信息会被删除掉。

2）管理表和外部表的使用场景：

每天将收集到的网站日志定期流入HDFS文本文件。在外部表（原始日志表）的基础上做大量的统计分析，用到的中间表、结果表使用内部表存储，数据通过SELECT+INSERT进入内部表。

3）案例实操

分别创建部门和员工外部表，并向表中导入数据。

（1）原始数据

dept.txt、emp.txt

（2）建表语句

    创建部门表

create external table if not exists dept(
deptno int,
dname string,
loc string
)
row format delimited fields terminated by '\t';

创建员工表

create external table if not exists emp(
empno int,
ename string,
job string,
mgr int,
hiredate string,
sal double,
comm double,
deptno int)
row format delimited fields terminated by '\t';

（3）查看创建的表

show tables;

 （4）向外部表中导入数据

   导入数据

hive (default)> load data local inpath '/usr/local/data/dept.txt' into table dept;
hive (default)> load data local inpath '/usr/local/data/emp.txt' into table emp;

查询结果

hive (default)> select * from emp;
hive (default)> select * from dept;

（5）查看表数据

hive (default)> desc formatted dept;

四、分区表

分区表实际上就是对应一个HDFS文件系统上的独立的文件夹，该文件夹下是该分区所有的数据文件。Hive中的分区就是分目录，把一个大的数据集根据业务需要分割成小的数据集。在查询时通过WHERE子句中的表达式选择查询所需要的指定的分区，这样的查询效率会提高很多。

1、分区表基本操作

1）创建分区表语法   

create table phone_flow(
phone string, upflow string, downflow string
)
partitioned by (month string)
row format delimited fields terminated by '\t';

会在hdfs上产生如下目录：

/user/hive/warehouse/soft863db.db/phone_flow

2）加载数据到分区表中

load data local inpath '/usr/local/data/2019_06_07.txt' into table phone_flow partition(month='201906');
load data local inpath '/usr/local/data/2019_06_06.txt' into table phone_flow partition(month='201906');
load data local inpath '/usr/local/data/2019_05_31.txt' into table phone_flow partition(month='201905');

在/user/hive/warehouse/soft863db.db/phone_flow 下产生如下目录：

month=201906 目录下有这两个文件：

month=201905 目录下有这一个文件：

select * from phone_flow where month='201906';

4）查询分区表中数据

select * from phone_flow where month='201906';

5）增加分区

增加单个分区

alter table phone_flow add partition(month='201904') ;

可以看到增加了新的目录：month=201904

         增加分区后，可通过上面 load的方式添加数据到指定数分区；

         也可以直接把数据上传到分区所在目录（但这样需要知道 表所在hdfs路径，不太友好）；

         或者可以在添加分区时，通过 location的方式 指定要添加的数据所在的hdfs路径：

dfs -mkdir /data;
dfs -mkdir /data/201903;
dfs -put /usr/local/data/2019_03_08.txt /data/201903;
select * from phone_flow;

alter table phone_flow add partition(month='201903') location '/data/201903';

同时创建多个分区

alter table phone_flow add partition(month='201902') partition(month='201901');

6）删除分区

删除单个分区

alter table phone_flow drop partition (month='201901');

同时删除多个分区

alter table phone_flow drop partition (month='201902'), partition (month='201904');

7）查看分区表有多少分区

show partitions phone_flow;

2、二级分区表

1）创建二级分区表

create table phone_flow2(
phone string, upflow string, downflow string
)
partitioned by (month string, day string)
row format delimited fields terminated by '\t';

2）正常的加载数据     

（1）加载数据到二级分区表中

load data local inpath '/usr/local/data/2019_06_07.txt' into table phone_flow2 partition(month='201906', day='07');

目录结构为：

（2）查询分区数据

select * from phone_flow2 where month='201906' and day='07';

3）先把数据直接上传到分区目录上，然后让分区表和数据产生关联的两种方式

上传数据

dfs -mkdir -p /user/hive/warehouse/soft863db.db/phone_flow2/month=201906/day=06;
dfs -put /usr/local/data/2019_06_06.txt /user/hive/warehouse/soft863db.db/phone_flow2/month=201906/day=06;
select * from phone_flow2;

执行添加分区

alter table phone_flow2 add partition(month='201906', day='06');
select * from phone_flow2;

查询数据

hive (soft863db)> select * from phone_flow2 where month='201906' and day='06';

五、修改表

1、表重命名

（1）语法

ALTER TABLE table_name RENAME TO new_table_name

（2）实操案例

alter table phone_flow2 rename to phone_flow3;

2、增加/修改/替换列信息

实操案例

（1）查询表结构

desc phone_flow3;

（2）添加列

alter table phone_flow3 add columns(avgflow int);

（3）查询表结构

desc phone_flow3;

（4）更新列

alter table phone_flow3 change column avgflow flow string;

（5）查询表结构

desc phone_flow3;

（6）替换列（把原来的所有列替换为 指定的列）

alter table phone_flow3 replace columns(deptno string, dname string, loc string);

(7)查看表创建语句

show create table phone_flow3;

六、删除表

create table phone_flow4 like phone_flow3;
drop table phone_flow4;

如果删除表时候卡死，请检查配置

<property>
    <name>hive.metastore.schema.verification</name>
    <value>true</value>
</property>

七、清空表 

注意：Truncate只能删除管理表，不能删除外部表中数据

truncate table phone_flow3;